1" Test for shortpathname ':8' extension.
2" Only for use on Win32 systems!
3
4set encoding=utf-8
5scriptencoding utf-8
6
7source check.vim
8CheckMSWindows
9
10func TestIt(file, bits, expected)
11  let res = fnamemodify(a:file, a:bits)
12  if a:expected != ''
13    call assert_equal(substitute(a:expected, '/', '\\', 'g'),
14		\ substitute(res, '/', '\\', 'g'),
15		\ "'" . a:file . "'->(" . a:bits . ")->'" . res . "'")
16  endif
17endfunc
18
19func Test_ColonEight()
20  let save_dir = getcwd()
21
22  " This could change for CygWin to //cygdrive/c
23  let dir1 = 'c:/x.x.y'
24  if filereadable(dir1) || isdirectory(dir1)
25    call assert_report("Fatal: '" . dir1 . "' exists, cannot run test")
26    return
27  endif
28
29  let file1 = dir1 . '/zz.y.txt'
30  let nofile1 = dir1 . '/z.y.txt'
31  let dir2 = dir1 . '/VimIsTheGreatestSinceSlicedBread'
32  let file2 = dir2 . '/z.txt'
33  let nofile2 = dir2 . '/zz.txt'
34
35  call mkdir(dir1)
36  let resdir1 = substitute(fnamemodify(dir1, ':p:8'), '/$', '', '')
37  call assert_match('\V\^c:/XX\x\x\x\x~1.Y\$', resdir1)
38
39  let resfile1 = resdir1 . '/ZZY~1.TXT'
40  let resnofile1 = resdir1 . '/z.y.txt'
41  let resdir2 = resdir1 . '/VIMIST~1'
42  let resfile2 = resdir2 . '/z.txt'
43  let resnofile2 = resdir2 . '/zz.txt'
44
45  call mkdir(dir2)
46  call writefile([], file1)
47  call writefile([], file2)
48
49  call TestIt(file1, ':p:8', resfile1)
50  call TestIt(nofile1, ':p:8', resnofile1)
51  call TestIt(file2, ':p:8', resfile2)
52  call TestIt(nofile2, ':p:8', resnofile2)
53  call TestIt(nofile2, ':p:8:h', fnamemodify(resnofile2, ':h'))
54  call chdir(dir1)
55  call TestIt(file1, ':.:8', strpart(resfile1, strlen(resdir1)+1))
56  call TestIt(nofile1, ':.:8', strpart(resnofile1, strlen(resdir1)+1))
57  call TestIt(file2, ':.:8', strpart(resfile2, strlen(resdir1)+1))
58  call TestIt(nofile2, ':.:8', strpart(resnofile2, strlen(resdir1)+1))
59  let $HOME=dir1
60  call TestIt(file1, ':~:8', '~' . strpart(resfile1, strlen(resdir1)))
61  call TestIt(nofile1, ':~:8', '~' . strpart(resnofile1, strlen(resdir1)))
62  call TestIt(file2, ':~:8', '~' . strpart(resfile2, strlen(resdir1)))
63  call TestIt(nofile2, ':~:8', '~' . strpart(resnofile2, strlen(resdir1)))
64
65  cd c:/
66  call delete(file2)
67  call delete(file1)
68  call delete(dir2, 'd')
69  call delete(dir1, 'd')
70
71  call chdir(save_dir)
72endfunc
73
74func Test_ColonEight_MultiByte()
75  let dir = 'Xtest'
76
77  let file = dir . '/日本語のファイル.txt'
78
79  call mkdir(dir)
80  call writefile([], file)
81
82  let sfile = fnamemodify(file, ':8')
83
84  call assert_notequal(file, sfile)
85  call assert_match('\~', sfile)
86
87  call delete(file)
88  call delete(dir, 'd')
89endfunc
90
91" vim: shiftwidth=2 sts=2 expandtab
92