1" Test for v:hlsearch
2
3func Test_hlsearch()
4  new
5  call setline(1, repeat(['aaa'], 10))
6  set hlsearch nolazyredraw
7  " redraw is needed to make hlsearch highlight the matches
8  exe "normal! /aaa\<CR>" | redraw
9  let r1 = screenattr(1, 1)
10  nohlsearch | redraw
11  call assert_notequal(r1, screenattr(1,1))
12  let v:hlsearch=1 | redraw
13  call assert_equal(r1, screenattr(1,1))
14  let v:hlsearch=0 | redraw
15  call assert_notequal(r1, screenattr(1,1))
16  set hlsearch | redraw
17  call assert_equal(r1, screenattr(1,1))
18  let v:hlsearch=0 | redraw
19  call assert_notequal(r1, screenattr(1,1))
20  exe "normal! n" | redraw
21  call assert_equal(r1, screenattr(1,1))
22  let v:hlsearch=0 | redraw
23  call assert_notequal(r1, screenattr(1,1))
24  exe "normal! /\<CR>" | redraw
25  call assert_equal(r1, screenattr(1,1))
26  set nohls
27  exe "normal! /\<CR>" | redraw
28  call assert_notequal(r1, screenattr(1,1))
29  call assert_fails('let v:hlsearch=[]', 'E745')
30  call garbagecollect(1)
31  call getchar(1)
32  enew!
33endfunc
34
35func Test_hlsearch_hangs()
36  if !has('reltime') || !has('float')
37    return
38  endif
39
40  " This pattern takes a long time to match, it should timeout.
41  new
42  call setline(1, ['aaa', repeat('abc ', 1000), 'ccc'])
43  let start = reltime()
44  set hlsearch nolazyredraw redrawtime=101
45  let @/ = '\%#=1a*.*X\@<=b*'
46  redraw
47  let elapsed = reltimefloat(reltime(start))
48  call assert_true(elapsed > 0.1)
49  call assert_true(elapsed < 1.0)
50  set nohlsearch redrawtime&
51  bwipe!
52endfunc
53
54func Test_hlsearch_eol_highlight()
55  new
56  call append(1, repeat([''], 9))
57  set hlsearch nolazyredraw
58  exe "normal! /$\<CR>" | redraw
59  let attr = screenattr(1, 1)
60  for row in range(2, 10)
61    call assert_equal(attr, screenattr(row, 1), 'in line ' . row)
62  endfor
63  set nohlsearch
64  bwipe!
65endfunc
66