1" Test for v:hlsearch
2
3source check.vim
4
5func Test_hlsearch()
6  new
7  call setline(1, repeat(['aaa'], 10))
8  set hlsearch nolazyredraw
9  " redraw is needed to make hlsearch highlight the matches
10  exe "normal! /aaa\<CR>" | redraw
11  let r1 = screenattr(1, 1)
12  nohlsearch | redraw
13  call assert_notequal(r1, screenattr(1,1))
14  let v:hlsearch=1 | redraw
15  call assert_equal(r1, screenattr(1,1))
16  let v:hlsearch=0 | redraw
17  call assert_notequal(r1, screenattr(1,1))
18  set hlsearch | redraw
19  call assert_equal(r1, screenattr(1,1))
20  let v:hlsearch=0 | redraw
21  call assert_notequal(r1, screenattr(1,1))
22  exe "normal! n" | redraw
23  call assert_equal(r1, screenattr(1,1))
24  let v:hlsearch=0 | redraw
25  call assert_notequal(r1, screenattr(1,1))
26  exe "normal! /\<CR>" | redraw
27  call assert_equal(r1, screenattr(1,1))
28  set nohls
29  exe "normal! /\<CR>" | redraw
30  call assert_notequal(r1, screenattr(1,1))
31  call assert_fails('let v:hlsearch=[]', 'E745:')
32  call garbagecollect(1)
33  call getchar(1)
34  enew!
35endfunc
36
37func Test_hlsearch_hangs()
38  CheckFunction reltimefloat
39
40  " This pattern takes a long time to match, it should timeout.
41  new
42  call setline(1, ['aaa', repeat('abc ', 1000), 'ccc'])
43  let start = reltime()
44  set hlsearch nolazyredraw redrawtime=101
45  let @/ = '\%#=1a*.*X\@<=b*'
46  redraw
47  let elapsed = reltimefloat(reltime(start))
48  call assert_true(elapsed > 0.1)
49  call assert_true(elapsed < 1.0)
50  set nohlsearch redrawtime&
51  bwipe!
52endfunc
53
54func Test_hlsearch_eol_highlight()
55  new
56  call append(1, repeat([''], 9))
57  set hlsearch nolazyredraw
58  exe "normal! /$\<CR>" | redraw
59  let attr = screenattr(1, 1)
60  for row in range(2, 10)
61    call assert_equal(attr, screenattr(row, 1), 'in line ' . row)
62  endfor
63  set nohlsearch
64  bwipe!
65endfunc
66
67" vim: shiftwidth=2 sts=2 expandtab
68