xref: /vim-8.2.3635/runtime/syntax/eruby.vim (revision d09091d4) 
1" Vim syntax file
2" Language:		eRuby
3" Maintainer:		Tim Pope <[email protected]>
4" URL:			https://github.com/vim-ruby/vim-ruby
5" Release Coordinator:	Doug Kearns <[email protected]>
6" Last Change:		2018 Jul 04
7
8if &syntax !~# '\<eruby\>' || get(b:, 'current_syntax') =~# '\<eruby\>'
9  finish
10endif
11
12if !exists("main_syntax")
13  let main_syntax = 'eruby'
14endif
15
16if !exists("g:eruby_default_subtype")
17  let g:eruby_default_subtype = "html"
18endif
19
20if &filetype =~ '^eruby\.'
21  let b:eruby_subtype = matchstr(&filetype,'^eruby\.\zs\w\+')
22elseif &filetype =~ '^.*\.eruby\>'
23  let b:eruby_subtype = matchstr(&filetype,'^.\{-\}\ze\.eruby\>')
24elseif !exists("b:eruby_subtype") && main_syntax == 'eruby'
25  let s:lines = getline(1)."\n".getline(2)."\n".getline(3)."\n".getline(4)."\n".getline(5)."\n".getline("$")
26  let b:eruby_subtype = matchstr(s:lines,'eruby_subtype=\zs\w\+')
27  if b:eruby_subtype == ''
28    let b:eruby_subtype = matchstr(substitute(expand("%:t"),'\c\%(\.erb\|\.eruby\|\.erubis\|\.example\)\+$','',''),'\.\zs\w\+\%(\ze+\w\+\)\=$')
29  endif
30  if b:eruby_subtype == 'rhtml'
31    let b:eruby_subtype = 'html'
32  elseif b:eruby_subtype == 'rb'
33    let b:eruby_subtype = 'ruby'
34  elseif b:eruby_subtype == 'yml'
35    let b:eruby_subtype = 'yaml'
36  elseif b:eruby_subtype == 'js'
37    let b:eruby_subtype = 'javascript'
38  elseif b:eruby_subtype == 'txt'
39    " Conventional; not a real file type
40    let b:eruby_subtype = 'text'
41  elseif b:eruby_subtype == ''
42    let b:eruby_subtype = g:eruby_default_subtype
43  endif
44endif
45
46if !exists("b:eruby_nest_level")
47  if &syntax =~# '\<eruby\.eruby\>'
48    let b:eruby_nest_level = strlen(substitute(substitute(&filetype,'\C\<eruby\>','@','g'),'[^@]','','g'))
49  else
50    let b:eruby_nest_level = strlen(substitute(substitute(substitute(expand("%:t"),'@','','g'),'\c\.\%(erb\|rhtml\)\>','@','g'),'[^@]','','g'))
51  endif
52endif
53if !b:eruby_nest_level
54  let b:eruby_nest_level = 1
55endif
56
57if get(b:, 'eruby_subtype', '') !~# '^\%(eruby\)\=$' && &syntax =~# '^eruby\>'
58  exe "runtime! syntax/".b:eruby_subtype.".vim"
59endif
60unlet! b:current_syntax
61syn include @rubyTop syntax/ruby.vim
62
63syn cluster erubyRegions contains=erubyOneLiner,erubyBlock,erubyExpression,erubyComment
64
65exe 'syn region  erubyOneLiner   matchgroup=erubyDelimiter start="^%\{1,'.b:eruby_nest_level.'\}%\@!"    end="$"     contains=@rubyTop	     containedin=ALLBUT,@erubyRegions keepend oneline'
66exe 'syn region  erubyBlock      matchgroup=erubyDelimiter start="<%\{1,'.b:eruby_nest_level.'\}%\@!-\=" end="[=-]\=%\@<!%\{1,'.b:eruby_nest_level.'\}>" contains=@rubyTop  containedin=ALLBUT,@erubyRegions keepend'
67exe 'syn region  erubyExpression matchgroup=erubyDelimiter start="<%\{1,'.b:eruby_nest_level.'\}=\{1,4}" end="[=-]\=%\@<!%\{1,'.b:eruby_nest_level.'\}>" contains=@rubyTop  containedin=ALLBUT,@erubyRegions keepend'
68exe 'syn region  erubyComment    matchgroup=erubyDelimiter start="<%\{1,'.b:eruby_nest_level.'\}-\=#"    end="[=-]\=%\@<!%\{1,'.b:eruby_nest_level.'\}>" contains=rubyTodo,@Spell containedin=ALLBUT,@erubyRegions keepend'
69
70" Define the default highlighting.
71
72hi def link erubyDelimiter		PreProc
73hi def link erubyComment		Comment
74
75let b:current_syntax = matchstr(&syntax, '^.*\<eruby\>')
76
77if main_syntax == 'eruby'
78  unlet main_syntax
79endif
80
81" vim: nowrap sw=2 sts=2 ts=8:
82