xref: /sqlite-3.40.0/tool/mksqlite3h.tcl (revision 24aee8af) 
1#!/usr/bin/tclsh
2#
3# This script constructs the "sqlite3.h" header file from the following
4# sources:
5#
6#   1) The src/sqlite.h.in source file.  This is the template for sqlite3.h.
7#   2) The VERSION file containing the current SQLite version number.
8#   3) The manifest file from the fossil SCM.  This gives use the date.
9#   4) The manifest.uuid file from the fossil SCM.  This gives the SHA1 hash.
10#
11# Run this script by specifying the root directory of the source tree
12# on the command-line.
13#
14# This script performs processing on src/sqlite.h.in. It:
15#
16#   1) Adds SQLITE_EXTERN in front of the declaration of global variables,
17#   2) Adds SQLITE_API in front of the declaration of API functions,
18#   3) Replaces the string --VERS-- with the current library version,
19#      formatted as a string (e.g. "3.6.17"), and
20#   4) Replaces the string --VERSION-NUMBER-- with current library version,
21#      formatted as an integer (e.g. "3006017").
22#   5) Replaces the string --SOURCE-ID-- with the date and time and sha1
23#      hash of the fossil-scm manifest for the source tree.
24#   6) Adds the SQLITE_CALLBACK calling convention macro in front of all
25#      callback declarations.
26#
27# This script outputs to stdout.
28#
29# Example usage:
30#
31#   tclsh mksqlite3h.tcl ../sqlite >sqlite3.h
32#
33
34
35# Get the source tree root directory from the command-line
36#
37set TOP [lindex $argv 0]
38
39# Enable use of SQLITE_APICALL macros at the right points?
40#
41set useapicall 0
42
43if {[lsearch -regexp [lrange $argv 1 end] {^-+useapicall}] != -1} {
44  set useapicall 1
45}
46
47# Get the SQLite version number (ex: 3.6.18) from the $TOP/VERSION file.
48#
49set in [open $TOP/VERSION]
50set zVersion [string trim [read $in]]
51close $in
52set nVersion [eval format "%d%03d%03d" [split $zVersion .]]
53
54# Get the source-id
55#
56set PWD [pwd]
57cd $TOP
58set zSourceId [exec $PWD/mksourceid manifest]
59cd $PWD
60
61# Set up patterns for recognizing API declarations.
62#
63set varpattern {^[a-zA-Z][a-zA-Z_0-9 *]+sqlite3_[_a-zA-Z0-9]+(\[|;| =)}
64set declpattern1 {^ *([a-zA-Z][a-zA-Z_0-9 ]+ \**)(sqlite3_[_a-zA-Z0-9]+)(\(.*)$}
65
66set declpattern2 \
67    {^ *([a-zA-Z][a-zA-Z_0-9 ]+ \**)(sqlite3session_[_a-zA-Z0-9]+)(\(.*)$}
68
69set declpattern3 \
70    {^ *([a-zA-Z][a-zA-Z_0-9 ]+ \**)(sqlite3changeset_[_a-zA-Z0-9]+)(\(.*)$}
71
72set declpattern4 \
73    {^ *([a-zA-Z][a-zA-Z_0-9 ]+ \**)(sqlite3changegroup_[_a-zA-Z0-9]+)(\(.*)$}
74
75set declpattern5 \
76    {^ *([a-zA-Z][a-zA-Z_0-9 ]+ \**)(sqlite3rebaser_[_a-zA-Z0-9]+)(\(.*)$}
77
78# Force the output to use unix line endings, even on Windows.
79fconfigure stdout -translation lf
80
81set filelist [subst {
82  $TOP/src/sqlite.h.in
83  $TOP/ext/rtree/sqlite3rtree.h
84  $TOP/ext/session/sqlite3session.h
85  $TOP/ext/fts5/fts5.h
86}]
87
88# These are the functions that accept a variable number of arguments.  They
89# always need to use the "cdecl" calling convention even when another calling
90# convention (e.g. "stcall") is being used for the rest of the library.
91set cdecllist {
92  sqlite3_config
93  sqlite3_db_config
94  sqlite3_log
95  sqlite3_mprintf
96  sqlite3_snprintf
97  sqlite3_test_control
98  sqlite3_vtab_config
99}
100
101# Process the source files.
102#
103foreach file $filelist {
104  set in [open $file]
105  if {![regexp {sqlite\.h\.in} $file]} {
106    puts "/******** Begin file [file tail $file] *********/"
107  }
108  while {![eof $in]} {
109
110    set line [string trimright [gets $in]]
111
112    # File sqlite3rtree.h contains a line "#include <sqlite3.h>". Omit this
113    # line when copying sqlite3rtree.h into sqlite3.h.
114    #
115    if {[string match {*#include*[<"]sqlite3.h[>"]*} $line]} continue
116
117    regsub -- --VERS--           $line $zVersion line
118    regsub -- --VERSION-NUMBER-- $line $nVersion line
119    regsub -- --SOURCE-ID--      $line "$zSourceId" line
120
121    if {[regexp $varpattern $line] && ![regexp {^ *typedef} $line]} {
122      set line "SQLITE_API $line"
123    } else {
124      if {[regexp $declpattern1 $line all rettype funcname rest] || \
125          [regexp $declpattern2 $line all rettype funcname rest] || \
126          [regexp $declpattern3 $line all rettype funcname rest] || \
127          [regexp $declpattern4 $line all rettype funcname rest] || \
128          [regexp $declpattern5 $line all rettype funcname rest]} {
129        set line SQLITE_API
130        append line " " [string trim $rettype]
131        if {[string index $rettype end] ne "*"} {
132          append line " "
133        }
134        if {$useapicall} {
135          if {[lsearch -exact $cdecllist $funcname] >= 0} {
136            append line SQLITE_CDECL " "
137          } else {
138            append line SQLITE_APICALL " "
139          }
140        }
141        append line $funcname $rest
142      }
143    }
144    if {$useapicall} {
145      set line [string map [list (*sqlite3_syscall_ptr) \
146          "(SQLITE_SYSAPI *sqlite3_syscall_ptr)"] $line]
147      regsub {\(\*} $line {(SQLITE_CALLBACK *} line
148    }
149    puts $line
150  }
151  close $in
152  if {![regexp {sqlite\.h\.in} $file]} {
153    puts "/******** End of [file tail $file] *********/"
154  }
155}
156