xref: /oneTBB/cmake/compilers/Clang.cmake (revision 952845af) 
1# Copyright (c) 2020-2021 Intel Corporation
2#
3# Licensed under the Apache License, Version 2.0 (the "License");
4# you may not use this file except in compliance with the License.
5# You may obtain a copy of the License at
6#
7#     http://www.apache.org/licenses/LICENSE-2.0
8#
9# Unless required by applicable law or agreed to in writing, software
10# distributed under the License is distributed on an "AS IS" BASIS,
11# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
12# See the License for the specific language governing permissions and
13# limitations under the License.
14
15if (MINGW)
16    set(TBB_LINK_DEF_FILE_FLAG "")
17    set(TBB_DEF_FILE_PREFIX "")
18elseif (APPLE)
19    set(TBB_LINK_DEF_FILE_FLAG -Wl,-exported_symbols_list,)
20    set(TBB_DEF_FILE_PREFIX mac${TBB_ARCH})
21
22    # For correct ucontext.h structures layout
23    set(TBB_COMMON_COMPILE_FLAGS ${TBB_COMMON_COMPILE_FLAGS} -D_XOPEN_SOURCE)
24elseif (MSVC)
25    include(${CMAKE_CURRENT_LIST_DIR}/MSVC.cmake)
26    return()
27else()
28    set(TBB_LINK_DEF_FILE_FLAG -Wl,--version-script=)
29    set(TBB_DEF_FILE_PREFIX lin${TBB_ARCH})
30endif()
31
32# Depfile options (e.g. -MD) are inserted automatically in some cases.
33# Don't add -MMD to avoid conflicts in such cases.
34if (NOT CMAKE_GENERATOR MATCHES "Ninja" AND NOT CMAKE_CXX_DEPENDS_USE_COMPILER)
35    set(TBB_MMD_FLAG -MMD)
36endif()
37
38set(TBB_WARNING_LEVEL -Wall -Wextra $<$<BOOL:${TBB_STRICT}>:-Werror>)
39set(TBB_TEST_WARNING_FLAGS -Wshadow -Wcast-qual -Woverloaded-virtual -Wnon-virtual-dtor)
40
41# Ignore -Werror set through add_compile_options() or added to CMAKE_CXX_FLAGS if TBB_STRICT is disabled.
42if (NOT TBB_STRICT AND COMMAND tbb_remove_compile_flag)
43    tbb_remove_compile_flag(-Werror)
44endif()
45
46# Enable Intel(R) Transactional Synchronization Extensions (-mrtm) and WAITPKG instructions support (-mwaitpkg) on relevant processors
47if (CMAKE_SYSTEM_PROCESSOR MATCHES "(AMD64|amd64|i.86|x86)")
48    set(TBB_COMMON_COMPILE_FLAGS ${TBB_COMMON_COMPILE_FLAGS} -mrtm $<$<NOT:$<VERSION_LESS:${CMAKE_CXX_COMPILER_VERSION},12.0>>:-mwaitpkg>)
49endif()
50
51set(TBB_COMMON_LINK_LIBS ${CMAKE_DL_LIBS})
52
53if (ANDROID_PLATFORM)
54    set(TBB_COMMON_COMPILE_FLAGS ${TBB_COMMON_COMPILE_FLAGS} $<$<NOT:$<CONFIG:Debug>>:-D_FORTIFY_SOURCE=2>)
55endif()
56
57if (MINGW)
58    list(APPEND TBB_COMMON_COMPILE_FLAGS -U__STRICT_ANSI__)
59endif()
60
61set(TBB_IPO_COMPILE_FLAGS $<$<NOT:$<CONFIG:Debug>>:-flto>)
62set(TBB_IPO_LINK_FLAGS $<$<NOT:$<CONFIG:Debug>>:-flto>)
63
64# TBB malloc settings
65set(TBBMALLOC_LIB_COMPILE_FLAGS -fno-rtti -fno-exceptions)
66