xref: /oneTBB/cmake/compilers/Clang.cmake (revision fabaaa65) 
1# Copyright (c) 2020-2024 Intel Corporation
2#
3# Licensed under the Apache License, Version 2.0 (the "License");
4# you may not use this file except in compliance with the License.
5# You may obtain a copy of the License at
6#
7#     http://www.apache.org/licenses/LICENSE-2.0
8#
9# Unless required by applicable law or agreed to in writing, software
10# distributed under the License is distributed on an "AS IS" BASIS,
11# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
12# See the License for the specific language governing permissions and
13# limitations under the License.
14
15if (EMSCRIPTEN)
16  set(TBB_EMSCRIPTEN 1)
17  set(TBB_COMMON_COMPILE_FLAGS ${TBB_COMMON_COMPILE_FLAGS} -fexceptions)
18  set(TBB_TEST_LINK_FLAGS  ${TBB_COMMON_LINK_FLAGS} -fexceptions -sINITIAL_MEMORY=65536000 -sALLOW_MEMORY_GROWTH=1 -sEXIT_RUNTIME=1)
19  if (NOT EMSCRIPTEN_WITHOUT_PTHREAD)
20      set_property(TARGET Threads::Threads PROPERTY INTERFACE_LINK_LIBRARIES "-pthread")
21  endif()
22endif()
23
24if (MINGW)
25    set(TBB_LINK_DEF_FILE_FLAG "")
26    set(TBB_DEF_FILE_PREFIX "")
27elseif (APPLE)
28    set(TBB_LINK_DEF_FILE_FLAG -Wl,-exported_symbols_list,)
29    set(TBB_DEF_FILE_PREFIX mac${TBB_ARCH})
30
31    # For correct ucontext.h structures layout
32    set(TBB_COMMON_COMPILE_FLAGS ${TBB_COMMON_COMPILE_FLAGS} -D_XOPEN_SOURCE)
33elseif (MSVC)
34    include(${CMAKE_CURRENT_LIST_DIR}/MSVC.cmake)
35    return()
36else()
37    set(TBB_LINK_DEF_FILE_FLAG -Wl,--version-script=)
38    set(TBB_DEF_FILE_PREFIX lin${TBB_ARCH})
39    set(TBB_TEST_COMPILE_FLAGS ${TBB_TEST_COMPILE_FLAGS} $<$<NOT:$<VERSION_LESS:${CMAKE_CXX_COMPILER_VERSION},10.0>>:-ffp-model=precise>)
40endif()
41
42# Depfile options (e.g. -MD) are inserted automatically in some cases.
43# Don't add -MMD to avoid conflicts in such cases.
44if (NOT CMAKE_GENERATOR MATCHES "Ninja" AND NOT CMAKE_CXX_DEPENDS_USE_COMPILER)
45    set(TBB_MMD_FLAG -MMD)
46endif()
47
48set(TBB_WARNING_LEVEL -Wall -Wextra $<$<BOOL:${TBB_STRICT}>:-Werror>)
49set(TBB_TEST_WARNING_FLAGS -Wshadow -Wcast-qual -Woverloaded-virtual -Wnon-virtual-dtor)
50
51# Ignore -Werror set through add_compile_options() or added to CMAKE_CXX_FLAGS if TBB_STRICT is disabled.
52if (NOT TBB_STRICT AND COMMAND tbb_remove_compile_flag)
53    tbb_remove_compile_flag(-Werror)
54endif()
55
56# Enable Intel(R) Transactional Synchronization Extensions (-mrtm) and WAITPKG instructions support (-mwaitpkg) on relevant processors
57if (CMAKE_SYSTEM_PROCESSOR MATCHES "(AMD64|amd64|i.86|x86)" AND NOT EMSCRIPTEN)
58    set(TBB_COMMON_COMPILE_FLAGS ${TBB_COMMON_COMPILE_FLAGS} -mrtm $<$<NOT:$<VERSION_LESS:${CMAKE_CXX_COMPILER_VERSION},12.0>>:-mwaitpkg>)
59endif()
60
61# Clang flags to prevent compiler from optimizing out security checks
62set(TBB_COMMON_COMPILE_FLAGS ${TBB_COMMON_COMPILE_FLAGS} -Wformat -Wformat-security -Werror=format-security -fPIC $<$<NOT:$<BOOL:${EMSCRIPTEN}>>:-fstack-protector-strong>)
63
64# -z switch is not supported on MacOS
65if (NOT APPLE)
66    set(TBB_LIB_LINK_FLAGS ${TBB_LIB_LINK_FLAGS} -Wl,-z,relro,-z,now)
67endif()
68
69set(TBB_COMMON_LINK_LIBS ${CMAKE_DL_LIBS})
70
71set(TBB_COMMON_COMPILE_FLAGS ${TBB_COMMON_COMPILE_FLAGS} $<$<NOT:$<CONFIG:Debug>>:-D_FORTIFY_SOURCE=2>)
72
73if (MINGW)
74    list(APPEND TBB_COMMON_COMPILE_FLAGS -U__STRICT_ANSI__)
75endif()
76
77set(TBB_IPO_COMPILE_FLAGS $<$<NOT:$<CONFIG:Debug>>:-flto>)
78set(TBB_IPO_LINK_FLAGS $<$<NOT:$<CONFIG:Debug>>:-flto>)
79
80# TBB malloc settings
81set(TBBMALLOC_LIB_COMPILE_FLAGS -fno-rtti -fno-exceptions)
82