1// RUN: mlir-opt %s -convert-scf-to-cf -convert-vector-to-llvm -convert-memref-to-llvm -convert-func-to-llvm -reconcile-unrealized-casts | \
2// RUN: mlir-cpu-runner -e entry -entry-point-result=void  \
3// RUN:   -shared-libs=%mlir_integration_test_dir/libmlir_c_runner_utils%shlibext | \
4// RUN: FileCheck %s
5
6func.func @transfer_write16_inbounds_1d(%A : memref<?xf32>, %base: index) {
7  %f = arith.constant 16.0 : f32
8  %v = vector.splat %f : vector<16xf32>
9  vector.transfer_write %v, %A[%base]
10    {permutation_map = affine_map<(d0) -> (d0)>, in_bounds = [true]}
11    : vector<16xf32>, memref<?xf32>
12  return
13}
14
15func.func @transfer_write13_1d(%A : memref<?xf32>, %base: index) {
16  %f = arith.constant 13.0 : f32
17  %v = vector.splat %f : vector<13xf32>
18  vector.transfer_write %v, %A[%base]
19    {permutation_map = affine_map<(d0) -> (d0)>}
20    : vector<13xf32>, memref<?xf32>
21  return
22}
23
24func.func @transfer_write17_1d(%A : memref<?xf32>, %base: index) {
25  %f = arith.constant 17.0 : f32
26  %v = vector.splat %f : vector<17xf32>
27  vector.transfer_write %v, %A[%base]
28    {permutation_map = affine_map<(d0) -> (d0)>}
29    : vector<17xf32>, memref<?xf32>
30  return
31}
32
33func.func @transfer_read_1d(%A : memref<?xf32>) -> vector<32xf32> {
34  %z = arith.constant 0: index
35  %f = arith.constant 0.0: f32
36  %r = vector.transfer_read %A[%z], %f
37    {permutation_map = affine_map<(d0) -> (d0)>}
38    : memref<?xf32>, vector<32xf32>
39  return %r : vector<32xf32>
40}
41
42func.func @entry() {
43  %c0 = arith.constant 0: index
44  %c1 = arith.constant 1: index
45  %c32 = arith.constant 32: index
46  %A = memref.alloc(%c32) {alignment=64} : memref<?xf32>
47  scf.for %i = %c0 to %c32 step %c1 {
48    %f = arith.constant 0.0: f32
49    memref.store %f, %A[%i] : memref<?xf32>
50  }
51
52  // On input, memory contains all zeros.
53  %0 = call @transfer_read_1d(%A) : (memref<?xf32>) -> (vector<32xf32>)
54  vector.print %0 : vector<32xf32>
55
56  // Overwrite with 16 values of 16 at base 3.
57  // Statically guaranteed to be in-bounds. Exercises proper alignment.
58  %c3 = arith.constant 3: index
59  call @transfer_write16_inbounds_1d(%A, %c3) : (memref<?xf32>, index) -> ()
60  %1 = call @transfer_read_1d(%A) : (memref<?xf32>) -> (vector<32xf32>)
61  vector.print %1 : vector<32xf32>
62
63  // Overwrite with 13 values of 13 at base 3.
64  call @transfer_write13_1d(%A, %c3) : (memref<?xf32>, index) -> ()
65  %2 = call @transfer_read_1d(%A) : (memref<?xf32>) -> (vector<32xf32>)
66  vector.print %2 : vector<32xf32>
67
68  // Overwrite with 17 values of 17 at base 7.
69  %c7 = arith.constant 7: index
70  call @transfer_write17_1d(%A, %c3) : (memref<?xf32>, index) -> ()
71  %3 = call @transfer_read_1d(%A) : (memref<?xf32>) -> (vector<32xf32>)
72  vector.print %3 : vector<32xf32>
73
74  // Overwrite with 13 values of 13 at base 8.
75  %c8 = arith.constant 8: index
76  call @transfer_write13_1d(%A, %c8) : (memref<?xf32>, index) -> ()
77  %4 = call @transfer_read_1d(%A) : (memref<?xf32>) -> (vector<32xf32>)
78  vector.print %4 : vector<32xf32>
79
80  // Overwrite with 17 values of 17 at base 14.
81  %c14 = arith.constant 14: index
82  call @transfer_write17_1d(%A, %c14) : (memref<?xf32>, index) -> ()
83  %5 = call @transfer_read_1d(%A) : (memref<?xf32>) -> (vector<32xf32>)
84  vector.print %5 : vector<32xf32>
85
86  // Overwrite with 13 values of 13 at base 19.
87  %c19 = arith.constant 19: index
88  call @transfer_write13_1d(%A, %c19) : (memref<?xf32>, index) -> ()
89  %6 = call @transfer_read_1d(%A) : (memref<?xf32>) -> (vector<32xf32>)
90  vector.print %6 : vector<32xf32>
91
92  memref.dealloc %A : memref<?xf32>
93  return
94}
95
96// CHECK: ( 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 )
97// CHECK: ( 0, 0, 0, 16, 16, 16, 16, 16, 16, 16, 16, 16, 16, 16, 16, 16, 16, 16, 16, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 )
98// CHECK: ( 0, 0, 0, 13, 13, 13, 13, 13, 13, 13, 13, 13, 13, 13, 13, 13, 16, 16, 16, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 )
99// CHECK: ( 0, 0, 0, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 )
100// CHECK: ( 0, 0, 0, 17, 17, 17, 17, 17, 13, 13, 13, 13, 13, 13, 13, 13, 13, 13, 13, 13, 13, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 )
101// CHECK: ( 0, 0, 0, 17, 17, 17, 17, 17, 13, 13, 13, 13, 13, 13, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 17, 0 )
102// CHECK: ( 0, 0, 0, 17, 17, 17, 17, 17, 13, 13, 13, 13, 13, 13, 17, 17, 17, 17, 17, 13, 13, 13, 13, 13, 13, 13, 13, 13, 13, 13, 13, 13 )
103