1// RUN: mlir-opt %s --sparse-compiler | \
2// RUN: mlir-cpu-runner \
3// RUN:  -e entry -entry-point-result=void  \
4// RUN:  -shared-libs=%mlir_integration_test_dir/libmlir_c_runner_utils%shlibext | \
5// RUN: FileCheck %s
6
7#ST1 = #sparse_tensor.encoding<{dimLevelType = ["compressed", "compressed", "compressed"]}>
8#ST2 = #sparse_tensor.encoding<{dimLevelType = ["compressed", "compressed", "dense"]}>
9
10//
11// Trait for 3-d tensor operation.
12//
13#trait_scale = {
14  indexing_maps = [
15    affine_map<(i,j,k) -> (i,j,k)>,  // A (in)
16    affine_map<(i,j,k) -> (i,j,k)>   // X (out)
17  ],
18  iterator_types = ["parallel", "parallel", "parallel"],
19  doc = "X(i,j,k) = A(i,j,k) * 2.0"
20}
21
22module {
23  // Scales a sparse tensor into a new sparse tensor.
24  func.func @tensor_scale(%arga: tensor<?x?x?xf64, #ST1>) -> tensor<?x?x?xf64, #ST2> {
25    %s = arith.constant 2.0 : f64
26    %c0 = arith.constant 0 : index
27    %c1 = arith.constant 1 : index
28    %c2 = arith.constant 2 : index
29    %d0 = tensor.dim %arga, %c0 : tensor<?x?x?xf64, #ST1>
30    %d1 = tensor.dim %arga, %c1 : tensor<?x?x?xf64, #ST1>
31    %d2 = tensor.dim %arga, %c2 : tensor<?x?x?xf64, #ST1>
32    %xm = bufferization.alloc_tensor(%d0, %d1, %d2) : tensor<?x?x?xf64, #ST2>
33    %0 = linalg.generic #trait_scale
34       ins(%arga: tensor<?x?x?xf64, #ST1>)
35        outs(%xm: tensor<?x?x?xf64, #ST2>) {
36        ^bb(%a: f64, %x: f64):
37          %1 = arith.mulf %a, %s : f64
38          linalg.yield %1 : f64
39    } -> tensor<?x?x?xf64, #ST2>
40    return %0 : tensor<?x?x?xf64, #ST2>
41  }
42
43  // Driver method to call and verify tensor kernel.
44  func.func @entry() {
45    %c0 = arith.constant 0 : index
46    %d1 = arith.constant -1.0 : f64
47
48    // Setup sparse tensor.
49    %t = arith.constant dense<
50      [ [ [1.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 ],
51          [0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 ],
52          [0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 ],
53          [0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 2.0 ] ],
54        [ [0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 ],
55          [0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 ],
56          [0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 ],
57          [0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 ] ],
58        [ [0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 ],
59          [0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 ],
60          [0.0, 3.0, 4.0, 0.0, 0.0, 0.0, 0.0, 5.0 ],
61          [0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 ] ] ]> : tensor<3x4x8xf64>
62    %st = sparse_tensor.convert %t : tensor<3x4x8xf64> to tensor<?x?x?xf64, #ST1>
63
64    // Call sparse vector kernels.
65    %0 = call @tensor_scale(%st) : (tensor<?x?x?xf64, #ST1>) -> tensor<?x?x?xf64, #ST2>
66
67    // Sanity check on stored values.
68    //
69    // CHECK:      ( 1, 2, 3, 4, 5, -1, -1, -1 )
70    // CHECK-NEXT: ( 2, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 4, 0, 6, 8, 0, 0, 0, 0, 10, -1, -1, -1, -1, -1, -1, -1, -1 )
71    %m1 = sparse_tensor.values %st : tensor<?x?x?xf64, #ST1> to memref<?xf64>
72    %m2 = sparse_tensor.values %0  : tensor<?x?x?xf64, #ST2> to memref<?xf64>
73    %v1 = vector.transfer_read %m1[%c0], %d1: memref<?xf64>, vector<8xf64>
74    %v2 = vector.transfer_read %m2[%c0], %d1: memref<?xf64>, vector<32xf64>
75    vector.print %v1 : vector<8xf64>
76    vector.print %v2 : vector<32xf64>
77
78    // Release the resources.
79    bufferization.dealloc_tensor %st : tensor<?x?x?xf64, #ST1>
80    bufferization.dealloc_tensor %0  : tensor<?x?x?xf64, #ST2>
81    return
82  }
83}
84