1// RUN: mlir-opt -allow-unregistered-dialect -convert-scf-to-spirv %s -o - | FileCheck %s
2
3module attributes {
4  spv.target_env = #spv.target_env<
5    #spv.vce<v1.0, [Shader, Int64], [SPV_KHR_storage_buffer_storage_class]>, #spv.resource_limits<>>
6} {
7
8// CHECK-LABEL: @while_loop1
9func.func @while_loop1(%arg0: i32, %arg1: i32) -> i32 {
10  // CHECK-SAME: (%[[ARG1:.*]]: i32, %[[ARG2:.*]]: i32)
11  // CHECK: %[[INITVAR:.*]] = spv.Constant 2 : i32
12  // CHECK: %[[VAR1:.*]] = spv.Variable : !spv.ptr<i32, Function>
13  // CHECK: spv.mlir.loop {
14  // CHECK:   spv.Branch ^[[HEADER:.*]](%[[ARG1]] : i32)
15  // CHECK: ^[[HEADER]](%[[INDVAR1:.*]]: i32):
16  // CHECK:   %[[CMP:.*]] = spv.SLessThan %[[INDVAR1]], %[[ARG2]] : i32
17  // CHECK:   spv.Store "Function" %[[VAR1]], %[[INDVAR1]] : i32
18  // CHECK:   spv.BranchConditional %[[CMP]], ^[[BODY:.*]](%[[INDVAR1]] : i32), ^[[MERGE:.*]]
19  // CHECK: ^[[BODY]](%[[INDVAR2:.*]]: i32):
20  // CHECK:   %[[UPDATED:.*]] = spv.IMul %[[INDVAR2]], %[[INITVAR]] : i32
21  // CHECK: spv.Branch ^[[HEADER]](%[[UPDATED]] : i32)
22  // CHECK: ^[[MERGE]]:
23  // CHECK:   spv.mlir.merge
24  // CHECK: }
25  %c2_i32 = arith.constant 2 : i32
26  %0 = scf.while (%arg3 = %arg0) : (i32) -> (i32) {
27    %1 = arith.cmpi slt, %arg3, %arg1 : i32
28    scf.condition(%1) %arg3 : i32
29  } do {
30  ^bb0(%arg5: i32):
31    %1 = arith.muli %arg5, %c2_i32 : i32
32    scf.yield %1 : i32
33  }
34  // CHECK: %[[OUT:.*]] = spv.Load "Function" %[[VAR1]] : i32
35  // CHECK: spv.ReturnValue %[[OUT]] : i32
36  return %0 : i32
37}
38
39// -----
40
41// CHECK-LABEL: @while_loop2
42func.func @while_loop2(%arg0: f32) -> i64 {
43  // CHECK-SAME: (%[[ARG:.*]]: f32)
44  // CHECK: %[[VAR:.*]] = spv.Variable : !spv.ptr<i64, Function>
45  // CHECK: spv.mlir.loop {
46  // CHECK:   spv.Branch ^[[HEADER:.*]](%[[ARG]] : f32)
47  // CHECK: ^[[HEADER]](%[[INDVAR1:.*]]: f32):
48  // CHECK:   %[[SHARED:.*]] = "foo.shared_compute"(%[[INDVAR1]]) : (f32) -> i64
49  // CHECK:   %[[CMP:.*]] = "foo.evaluate_condition"(%[[INDVAR1]], %[[SHARED]]) : (f32, i64) -> i1
50  // CHECK:   spv.Store "Function" %[[VAR]], %[[SHARED]] : i64
51  // CHECK:   spv.BranchConditional %[[CMP]], ^[[BODY:.*]](%[[SHARED]] : i64), ^[[MERGE:.*]]
52  // CHECK: ^[[BODY]](%[[INDVAR2:.*]]: i64):
53  // CHECK:   %[[UPDATED:.*]] = "foo.payload"(%[[INDVAR2]]) : (i64) -> f32
54  // CHECK: spv.Branch ^[[HEADER]](%[[UPDATED]] : f32)
55  // CHECK: ^[[MERGE]]:
56  // CHECK:   spv.mlir.merge
57  // CHECK: }
58  %res = scf.while (%arg1 = %arg0) : (f32) -> i64 {
59    %shared = "foo.shared_compute"(%arg1) : (f32) -> i64
60    %condition = "foo.evaluate_condition"(%arg1, %shared) : (f32, i64) -> i1
61    scf.condition(%condition) %shared : i64
62  } do {
63  ^bb0(%arg2: i64):
64    %res = "foo.payload"(%arg2) : (i64) -> f32
65    scf.yield %res : f32
66  }
67  // CHECK: %[[OUT:.*]] = spv.Load "Function" %[[VAR]] : i64
68  // CHECK: spv.ReturnValue %[[OUT]] : i64
69  return %res : i64
70}
71
72} // end module
73