1# This file contains all the logic for running configure-time checks
2
3include(CheckSymbolExists)
4include(CheckIncludeFile)
5include(CheckIncludeFiles)
6include(CheckLibraryExists)
7
8set(CMAKE_REQUIRED_DEFINITIONS -D_GNU_SOURCE)
9check_symbol_exists(ppoll poll.h HAVE_PPOLL)
10set(CMAKE_REQUIRED_DEFINITIONS)
11check_symbol_exists(sigaction signal.h HAVE_SIGACTION)
12check_cxx_symbol_exists(accept4 "sys/socket.h" HAVE_ACCEPT4)
13
14check_include_file(termios.h HAVE_TERMIOS_H)
15check_include_files("sys/types.h;sys/event.h" HAVE_SYS_EVENT_H)
16
17check_cxx_source_compiles("
18  #include <sys/uio.h>
19  int main() { process_vm_readv(0, nullptr, 0, nullptr, 0, 0); return 0; }"
20  HAVE_PROCESS_VM_READV)
21check_cxx_source_compiles("
22    #include <sys/syscall.h>
23    int main() { return __NR_process_vm_readv; }"
24    HAVE_NR_PROCESS_VM_READV)
25
26check_library_exists(compression compression_encode_buffer "" HAVE_LIBCOMPRESSION)
27
28# These checks exist in LLVM's configuration, so I want to match the LLVM names
29# so that the check isn't duplicated, but we translate them into the LLDB names
30# so that I don't have to change all the uses at the moment.
31set(LLDB_CONFIG_TERMIOS_SUPPORTED ${HAVE_TERMIOS_H})
32if(NOT UNIX)
33  set(LLDB_DISABLE_POSIX 1)
34endif()
35
36if(NOT LLDB_CONFIG_HEADER_INPUT)
37 set(LLDB_CONFIG_HEADER_INPUT ${LLDB_INCLUDE_ROOT}/lldb/Host/Config.h.cmake)
38endif()
39
40if(NOT LLDB_CONFIG_HEADER_OUTPUT)
41 set(LLDB_CONFIG_HEADER_OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/include/lldb/Host/Config.h)
42endif()
43
44# This should be done at the end
45configure_file(
46  ${LLDB_CONFIG_HEADER_INPUT}
47  ${LLDB_CONFIG_HEADER_OUTPUT}
48  )
49