1# This file contains all the logic for running configure-time checks
2
3include(CheckSymbolExists)
4include(CheckIncludeFile)
5include(CheckIncludeFiles)
6include(CheckLibraryExists)
7
8set(CMAKE_REQUIRED_DEFINITIONS -D_GNU_SOURCE)
9check_symbol_exists(ppoll poll.h HAVE_PPOLL)
10check_symbol_exists(ptsname_r stdlib.h HAVE_PTSNAME_R)
11set(CMAKE_REQUIRED_DEFINITIONS)
12check_cxx_symbol_exists(accept4 "sys/socket.h" HAVE_ACCEPT4)
13
14check_include_file(termios.h HAVE_TERMIOS_H)
15check_include_files("sys/types.h;sys/event.h" HAVE_SYS_EVENT_H)
16
17check_cxx_symbol_exists(process_vm_readv "sys/uio.h" HAVE_PROCESS_VM_READV)
18check_cxx_symbol_exists(__NR_process_vm_readv "sys/syscall.h" HAVE_NR_PROCESS_VM_READV)
19
20check_library_exists(compression compression_encode_buffer "" HAVE_LIBCOMPRESSION)
21
22# These checks exist in LLVM's configuration, so I want to match the LLVM names
23# so that the check isn't duplicated, but we translate them into the LLDB names
24# so that I don't have to change all the uses at the moment.
25set(LLDB_ENABLE_TERMIOS ${HAVE_TERMIOS_H})
26if (UNIX)
27  set(LLDB_ENABLE_POSIX ON)
28else()
29  set(LLDB_ENABLE_POSIX OFF)
30endif()
31
32if(NOT LLDB_CONFIG_HEADER_INPUT)
33 set(LLDB_CONFIG_HEADER_INPUT ${LLDB_INCLUDE_ROOT}/lldb/Host/Config.h.cmake)
34endif()
35
36if(NOT LLDB_CONFIG_HEADER_OUTPUT)
37 set(LLDB_CONFIG_HEADER_OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/include/lldb/Host/Config.h)
38endif()
39
40# This should be done at the end
41configure_file(
42  ${LLDB_CONFIG_HEADER_INPUT}
43  ${LLDB_CONFIG_HEADER_OUTPUT}
44  )
45