1
2OUTPUT_FORMAT("elf64-powerpcle-freebsd", "elf64-powerpcle-freebsd",
3	      "elf64-powerpcle-freebsd")
4OUTPUT_ARCH(powerpc:common64)
5ENTRY(__start)
6SEARCH_DIR(/usr/lib);
7PROVIDE (__stack = 0);
8PHDRS
9{
10	text PT_LOAD ;
11	dynamic PT_DYNAMIC ;
12}
13SECTIONS
14{
15
16  /* Low-address wrapper for bootloaders (kexec/kboot) that can't parse ELF */
17  . = kernbase - 0x100;
18  .kboot : { *(.text.kboot) } :text
19
20  /* Read-only sections, merged into text segment: */
21  . = kernbase;
22  PROVIDE (begin = .);
23
24  .text      :
25  {
26    *(.glink)
27    *(.text)
28    *(.stub)
29    /* .gnu.warning sections are handled specially by elf32.em.  */
30    *(.gnu.warning)
31    *(.gnu.linkonce.t*)
32  } =0
33  _etext = .;
34  PROVIDE (etext = .);
35
36  /* Do not emit PT_INTERP section, which confuses some loaders (kexec-lite) */
37  /DISCARD/   : { *(.interp)	}
38
39  /* Also delete notes */
40  /DISCARD/   : { *(.note.*)	}
41
42  .hash          : { *(.hash)		}
43  .dynsym        : { *(.dynsym)		}
44  .dynstr        : { *(.dynstr)		}
45  .gnu.version   : { *(.gnu.version)	}
46  .gnu.version_d   : { *(.gnu.version_d)	}
47  .gnu.version_r   : { *(.gnu.version_r)	}
48  .note.gnu.build-id : {
49    PROVIDE (__build_id_start = .);
50    *(.note.gnu.build-id)
51    PROVIDE (__build_id_end = .);
52  }
53  .rela.text     :
54    { *(.rela.text) *(.rela.gnu.linkonce.t*) }
55  .rela.data     :
56    { *(.rela.data) *(.rela.gnu.linkonce.d*) }
57  .rela.rodata   :
58    { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
59  .rela.got      : { *(.rela.got)		}
60  .rela.got1     : { *(.rela.got1)		}
61  .rela.got2     : { *(.rela.got2)		}
62  .rela.ctors    : { *(.rela.ctors)	}
63  .rela.dtors    : { *(.rela.dtors)	}
64  .rela.init     : { *(.rela.init)	}
65  .rela.fini     : { *(.rela.fini)	}
66  .rela.bss      : { *(.rela.bss)		}
67  .rela.plt      : { *(.rela.plt)		}
68  .rela.sdata    : { *(.rela.sdata)		}
69  .rela.sbss     : { *(.rela.sbss)		}
70  .rela.sdata2   : { *(.rela.sdata2)		}
71  .rela.sbss2    : { *(.rela.sbss2)		}
72
73  .init      : { *(.init)    } =0
74  .fini      : { *(.fini)    } =0
75  .rodata    : { *(.rodata) *(.gnu.linkonce.r*) }
76  .rodata1   : { *(.rodata1) }
77  .sdata2    : { *(.sdata2)  }
78  .sbss2     : { *(.sbss2)   }
79  /* Adjust the address for the data segment to the next page up. */
80  . = ALIGN(4096);
81  .data.read_frequently :
82  {
83    *(SORT_BY_ALIGNMENT(.data.read_frequently))
84  }
85  .data.read_mostly :
86  {
87    *(.data.read_mostly)
88  }
89  . = ALIGN(128);
90  .data.exclusive_cache_line :
91  {
92    *(.data.exclusive_cache_line)
93  }
94  . = ALIGN(128);
95  .data    :
96  {
97    *(.data)
98    *(.gnu.linkonce.d*)
99  }
100  .data1     : { *(.data1) }
101  .toc1      : ALIGN(8) { *(.toc1) }
102  .opd       : ALIGN(8) { KEEP (*(.opd)) }
103  .branch_lt : ALIGN(8) { *(.branch_lt) }
104  . = ALIGN(4096);
105  .got       : ALIGN(8) { __tocbase = .; *(.got) }
106  .toc       : ALIGN(8) { *(.toc) }
107  .init_array     :
108  {
109    PROVIDE_HIDDEN (__init_array_start = .);
110    KEEP (*(SORT_BY_INIT_PRIORITY(.init_array.*)))
111    KEEP (*(.init_array))
112    PROVIDE_HIDDEN (__init_array_end = .);
113  }
114  .fini_array     :
115  {
116    PROVIDE_HIDDEN (__fini_array_start = .);
117    KEEP (*(SORT_BY_INIT_PRIORITY(.fini_array.*)))
118    KEEP (*(.fini_array))
119    PROVIDE_HIDDEN (__fini_array_end = .);
120  }
121  .dynamic        : { *(.dynamic) } :text :dynamic
122  /* Put .ctors and .dtors next to the .got2 section, so that the pointers
123     get relocated with -mrelocatable. Also put in the .fixup pointers.
124     The current compiler no longer needs this, but keep it around for 2.7.2  */
125                PROVIDE (_GOT2_START_ = .);
126  .got2           :  { *(.got2) }
127                PROVIDE (__CTOR_LIST__ = .);
128  .ctors          : { *(.ctors) }
129                PROVIDE (__CTOR_END__ = .);
130                PROVIDE (__DTOR_LIST__ = .);
131  .dtors          : { *(.dtors) }
132                PROVIDE (__DTOR_END__ = .);
133                PROVIDE (_FIXUP_START_ = .);
134  .fixup          : { *(.fixup) }
135                PROVIDE (_FIXUP_END_ = .);
136                PROVIDE (_GOT2_END_ = .);
137  /* We want the small data sections together, so single-instruction offsets
138     can access them all, and initialized data all before uninitialized, so
139     we can shorten the on-disk segment size.  */
140  .sdata     : { *(.sdata) }
141  _edata  =  .;
142  PROVIDE (edata = .);
143  .sbss      :
144  {
145    PROVIDE (__sbss_start = .);
146    *(.sbss)
147    *(.scommon)
148    *(.dynsbss)
149    PROVIDE (__sbss_end = .);
150  }
151  .plt   : { *(.plt) }
152  .iplt  : { *(.iplt) }
153  .bss       :
154  {
155   PROVIDE (__bss_start = .);
156   *(.dynbss)
157   *(.bss)
158   *(COMMON)
159  }
160  _end = . ;
161  PROVIDE (end = .);
162  /* Stabs debugging sections.  */
163  .stab 0 : { *(.stab) }
164  .stabstr 0 : { *(.stabstr) }
165  /* DWARF debug sections.
166     Symbols in the DWARF debugging sections are relative to the beginning
167     of the section so we begin them at 0.  */
168  /* DWARF 1 */
169  .debug          0 : { *(.debug) }
170  .line           0 : { *(.line) }
171  /* GNU DWARF 1 extensions */
172  .debug_srcinfo  0 : { *(.debug_srcinfo) }
173  .debug_sfnames  0 : { *(.debug_sfnames) }
174  /* DWARF 1.1 and DWARF 2 */
175  .debug_aranges  0 : { *(.debug_aranges) }
176  .debug_pubnames 0 : { *(.debug_pubnames) }
177  /* DWARF 2 */
178  .debug_info     0 : { *(.debug_info) }
179  .debug_abbrev   0 : { *(.debug_abbrev) }
180  .debug_line     0 : { *(.debug_line) }
181  .debug_frame    0 : { *(.debug_frame) }
182  .debug_str      0 : { *(.debug_str) }
183  .debug_loc      0 : { *(.debug_loc) }
184  .debug_macinfo  0 : { *(.debug_macinfo) }
185  /* SGI/MIPS DWARF 2 extensions */
186  .debug_weaknames 0 : { *(.debug_weaknames) }
187  .debug_funcnames 0 : { *(.debug_funcnames) }
188  .debug_typenames 0 : { *(.debug_typenames) }
189  .debug_varnames  0 : { *(.debug_varnames) }
190  /* These must appear regardless of  .  */
191}
192
193