1/*-
2 * Copyright (c) 2001, 2004, 2008, Juniper Networks, Inc.
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 * 1. Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 * 2. Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in the
12 *    documentation and/or other materials provided with the distribution.
13 * 3. Neither the name of the Juniper Networks, Inc. nor the names of its
14 *    contributors may be used to endorse or promote products derived from
15 *    this software without specific prior written permission.
16 *
17 * THIS SOFTWARE IS PROVIDED BY JUNIPER NETWORKS AND CONTRIBUTORS ``AS IS'' AND
18 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
19 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
20 * ARE DISCLAIMED. IN NO EVENT SHALL JUNIPER NETWORKS OR CONTRIBUTORS BE LIABLE
21 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
22 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
23 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
24 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
25 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
26 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
27 * SUCH DAMAGE.
28 *
29 *	JNPR: ldscript.mips,v 1.3 2006/10/11 06:12:04
30 * $FreeBSD$
31 */
32
33OUTPUT_ARCH(mips)
34ENTRY(_start)
35SEARCH_DIR(/usr/lib);
36
37SECTIONS
38{
39  /* Read-only sections, merged into text segment: */
40  . = KERNLOADADDR + SIZEOF_HEADERS;
41  .interp     : { *(.interp) 	}
42  .hash          : { *(.hash)		}
43  .dynsym        : { *(.dynsym)		}
44  .dynstr        : { *(.dynstr)		}
45  .gnu.version   : { *(.gnu.version)	}
46  .gnu.version_d   : { *(.gnu.version_d)	}
47  .gnu.version_r   : { *(.gnu.version_r)	}
48  .rel.init      : { *(.rel.init)	}
49  .rela.init     : { *(.rela.init)	}
50  .rel.text      :
51    {
52      *(.rel.text)
53      *(.rel.text.*)
54      *(.rel.gnu.linkonce.t.*)
55    }
56  .rela.text     :
57    {
58      *(.rela.text)
59      *(.rela.text.*)
60      *(.rela.gnu.linkonce.t.*)
61    }
62  .rel.fini      : { *(.rel.fini)	}
63  .rela.fini     : { *(.rela.fini)	}
64  .rel.rodata    :
65    {
66      *(.rel.rodata)
67      *(.rel.rodata.*)
68      *(.rel.gnu.linkonce.r.*)
69    }
70  .rela.rodata   :
71    {
72      *(.rela.rodata)
73      *(.rela.rodata.*)
74      *(.rela.gnu.linkonce.r.*)
75    }
76  .rel.data      :
77    {
78      *(.rel.data)
79      *(.rel.data.*)
80      *(.rel.gnu.linkonce.d.*)
81    }
82  .rela.data     :
83    {
84      *(.rela.data)
85      *(.rela.data.*)
86      *(.rela.gnu.linkonce.d.*)
87    }
88  .rel.ctors     : { *(.rel.ctors)	}
89  .rela.ctors    : { *(.rela.ctors)	}
90  .rel.dtors     : { *(.rel.dtors)	}
91  .rela.dtors    : { *(.rela.dtors)	}
92  .rel.got       : { *(.rel.got)		}
93  .rela.got      : { *(.rela.got)		}
94  .rel.sdata     :
95    {
96      *(.rel.sdata)
97      *(.rel.sdata.*)
98      *(.rel.gnu.linkonce.s.*)
99    }
100  .rela.sdata     :
101    {
102      *(.rela.sdata)
103      *(.rela.sdata.*)
104      *(.rela.gnu.linkonce.s.*)
105    }
106  .rel.sbss      :
107    {
108      *(.rel.sbss)
109      *(.rel.sbss.*)
110      *(.rel.gnu.linkonce.sb.*)
111    }
112  .rela.sbss     :
113    {
114      *(.rela.sbss)
115      *(.rela.sbss.*)
116      *(.rel.gnu.linkonce.sb.*)
117    }
118  .rel.sdata2    :
119    {
120      *(.rel.sdata2)
121      *(.rel.sdata2.*)
122      *(.rel.gnu.linkonce.s2.*)
123    }
124  .rela.sdata2   :
125    {
126      *(.rela.sdata2)
127      *(.rela.sdata2.*)
128      *(.rela.gnu.linkonce.s2.*)
129    }
130  .rel.sbss2     :
131    {
132      *(.rel.sbss2)
133      *(.rel.sbss2.*)
134      *(.rel.gnu.linkonce.sb2.*)
135    }
136  .rela.sbss2    :
137    {
138      *(.rela.sbss2)
139      *(.rela.sbss2.*)
140      *(.rela.gnu.linkonce.sb2.*)
141    }
142  .rel.bss       :
143    {
144      *(.rel.bss)
145      *(.rel.bss.*)
146      *(.rel.gnu.linkonce.b.*)
147    }
148  .rela.bss      :
149    {
150      *(.rela.bss)
151      *(.rela.bss.*)
152      *(.rela.gnu.linkonce.b.*)
153    }
154  .rel.plt       : { *(.rel.plt)		}
155  .rela.plt      : { *(.rela.plt)		}
156  .init          :
157  {
158    KEEP (*(.init))
159  } =0x1000000
160  .text      :
161  {
162    *(.trap)
163    *(.text)
164    *(.text.*)
165    *(.stub)
166    /* .gnu.warning sections are handled specially by elf64.em.  */
167    *(.gnu.warning)
168    *(.gnu.linkonce.t.*)
169  } =0x1000000
170  .fini      :
171  {
172    KEEP (*(.fini))
173  } =0x1000000
174  PROVIDE (__etext = .);
175  PROVIDE (_etext = .);
176  PROVIDE (etext = .);
177  .rodata   : { *(.rodata) *(.rodata.*) *(.gnu.linkonce.r.*) }
178  .rodata1   : { *(.rodata1) }
179  .note.gnu.build-id : {
180    PROVIDE (__build_id_start = .);
181    *(.note.gnu.build-id)
182    PROVIDE (__build_id_end = .);
183  }
184  .reginfo : { *(.reginfo) }
185  .sdata2   : { *(.sdata2) *(.sdata2.*) *(.gnu.linkonce.s2.*) }
186  .sbss2   : { *(.sbss2) *(.sbss2.*) *(.gnu.linkonce.sb2.*) }
187  . = ALIGN(0x2000) + (. & (0x2000 - 1));
188  .data    :
189  {
190    *(.data)
191    *(.data.*)
192    *(.gnu.linkonce.d.*)
193  }
194  .data1   : { *(.data1) }
195  .eh_frame : { KEEP (*(.eh_frame)) }
196  .gcc_except_table : { *(.gcc_except_table) }
197  .ctors   :
198  {
199    /* gcc uses crtbegin.o to find the start of
200       the constructors, so we make sure it is
201       first.  Because this is a wildcard, it
202       doesn't matter if the user does not
203       actually link against crtbegin.o; the
204       linker won't look for a file to match a
205       wildcard.  The wildcard also means that it
206       doesn't matter which directory crtbegin.o
207       is in.  */
208    KEEP (*crtbegin.o(.ctors))
209    /* We don't want to include the .ctor section from
210       from the crtend.o file until after the sorted ctors.
211       The .ctor section from the crtend file contains the
212       end of ctors marker and it must be last */
213    KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
214    KEEP (*(SORT(.ctors.*)))
215    KEEP (*(.ctors))
216  }
217   .dtors         :
218  {
219    KEEP (*crtbegin.o(.dtors))
220    KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
221    KEEP (*(SORT(.dtors.*)))
222    KEEP (*(.dtors))
223  }
224  .plt      : { *(.plt)	}
225  _gp = ALIGN(16) + 0x7ff0;
226  .got		  : { *(.got.plt) *(.got) }
227  .dynamic       : { *(.dynamic) }
228  /* We want the small data sections together, so single-instruction offsets
229     can access them all, and initialized data all before uninitialized, so
230     we can shorten the on-disk segment size.  */
231  .sdata     :
232  {
233    *(.sdata)
234    *(.sdata.*)
235    *(.gnu.linkonce.s.*)
236  }
237  _edata = .;
238  PROVIDE (edata = .);
239  __bss_start = .;
240  .sbss      :
241  {
242    PROVIDE (__sbss_start = .);
243    PROVIDE (___sbss_start = .);
244    *(.dynsbss)
245    *(.sbss)
246    *(.sbss.*)
247    *(.gnu.linkonce.sb.*)
248    *(.scommon)
249    PROVIDE (__sbss_end = .);
250    PROVIDE (___sbss_end = .);
251  }
252  .bss       :
253  {
254   *(.dynbss)
255   *(.bss)
256   *(.bss.*)
257   *(.gnu.linkonce.b.*)
258   *(COMMON)
259   /* Align here to ensure that the .bss section occupies space up to
260      _end.  Align after .bss to ensure correct alignment even if the
261      .bss section disappears because there are no input sections.  */
262   . = ALIGN(64 / 8);
263  }
264  . = ALIGN(64 / 8);
265  _end = .;
266  PROVIDE (end = .);
267  /* Stabs debugging sections.  */
268  .stab 0 : { *(.stab) }
269  .stabstr 0 : { *(.stabstr) }
270  .stab.excl 0 : { *(.stab.excl) }
271  .stab.exclstr 0 : { *(.stab.exclstr) }
272  .stab.index 0 : { *(.stab.index) }
273  .stab.indexstr 0 : { *(.stab.indexstr) }
274  .comment 0 : { *(.comment) }
275  /* DWARF debug sections.
276     Symbols in the DWARF debugging sections are relative to the beginning
277     of the section so we begin them at 0.  */
278  /* DWARF 1 */
279  .debug          0 : { *(.debug) }
280  .line           0 : { *(.line) }
281  /* GNU DWARF 1 extensions */
282  .debug_srcinfo  0 : { *(.debug_srcinfo) }
283  .debug_sfnames  0 : { *(.debug_sfnames) }
284  /* DWARF 1.1 and DWARF 2 */
285  .debug_aranges  0 : { *(.debug_aranges) }
286  .debug_pubnames 0 : { *(.debug_pubnames) }
287  /* DWARF 2 */
288  .debug_info     0 : { *(.debug_info) *(.gnu.linkonce.wi.*) }
289  .debug_abbrev   0 : { *(.debug_abbrev) }
290  .debug_line     0 : { *(.debug_line) }
291  .debug_frame    0 : { *(.debug_frame) }
292  .debug_str      0 : { *(.debug_str) }
293  .debug_loc      0 : { *(.debug_loc) }
294  .debug_macinfo  0 : { *(.debug_macinfo) }
295  /* SGI/MIPS DWARF 2 extensions */
296  .debug_weaknames 0 : { *(.debug_weaknames) }
297  .debug_funcnames 0 : { *(.debug_funcnames) }
298  .debug_typenames 0 : { *(.debug_typenames) }
299  .debug_varnames  0 : { *(.debug_varnames) }
300  /* These must appear regardless of  .  */
301}
302