1/*
2            Copyright Oliver Kowalke 2009.
3   Distributed under the Boost Software License, Version 1.0.
4      (See accompanying file LICENSE_1_0.txt or copy at
5            http://www.boost.org/LICENSE_1_0.txt)
6*/
7
8/****************************************************************************************
9 *                                                                                      *
10 *  ----------------------------------------------------------------------------------  *
11 *  |    0    |    1    |    2    |    3    |    4     |    5    |    6    |    7    |  *
12 *  ----------------------------------------------------------------------------------  *
13 *  |   0x0   |   0x4   |   0x8   |   0xc   |   0x10   |   0x14  |   0x18  |   0x1c  |  *
14 *  ----------------------------------------------------------------------------------  *
15 *  | fc_mxcsr|fc_x87_cw|        R12        |         R13        |        R14        |  *
16 *  ----------------------------------------------------------------------------------  *
17 *  ----------------------------------------------------------------------------------  *
18 *  |    8    |    9    |   10    |   11    |    12    |    13   |    14   |    15   |  *
19 *  ----------------------------------------------------------------------------------  *
20 *  |   0x20  |   0x24  |   0x28  |  0x2c   |   0x30   |   0x34  |   0x38  |   0x3c  |  *
21 *  ----------------------------------------------------------------------------------  *
22 *  |        R15        |        RBX        |         RBP        |        RIP        |  *
23 *  ----------------------------------------------------------------------------------  *
24 *  ----------------------------------------------------------------------------------  *
25 *  |    16   |   17    |                                                            |  *
26 *  ----------------------------------------------------------------------------------  *
27 *  |   0x40  |   0x44  |                                                            |  *
28 *  ----------------------------------------------------------------------------------  *
29 *  |        EXIT       |                                                            |  *
30 *  ----------------------------------------------------------------------------------  *
31 *                                                                                      *
32 ****************************************************************************************/
33
34.text
35.globl make_fcontext
36.type make_fcontext,@function
37.align 16
38make_fcontext:
39    /* first arg of make_fcontext() == top of context-stack */
40    movq  %rdi, %rax
41
42    /* shift address in RAX to lower 16 byte boundary */
43    andq  $-16, %rax
44
45    /* reserve space for context-data on context-stack */
46    /* size for fc_mxcsr .. RIP + return-address for context-function */
47    /* on context-function entry: (RSP -0x8) % 16 == 0 */
48    leaq  -0x48(%rax), %rax
49
50    /* third arg of make_fcontext() == address of context-function */
51    movq  %rdx, 0x38(%rax)
52
53    /* save MMX control- and status-word */
54    stmxcsr  (%rax)
55    /* save x87 control-word */
56    fnstcw   0x4(%rax)
57
58    /* compute abs address of label finish */
59    leaq  finish(%rip), %rcx
60    /* save address of finish as return-address for context-function */
61    /* will be entered after context-function returns */
62    movq  %rcx, 0x40(%rax)
63
64    ret /* return pointer to context-data */
65
66finish:
67    /* exit code is zero */
68    xorq  %rdi, %rdi
69    /* exit application */
70    call  _exit@PLT
71    hlt
72.size make_fcontext,.-make_fcontext
73
74/* Mark that we don't need executable stack. */
75.section .note.GNU-stack,"",%progbits
76