1/*
2            Copyright Oliver Kowalke 2009.
3   Distributed under the Boost Software License, Version 1.0.
4      (See accompanying file LICENSE_1_0.txt or copy at
5          http://www.boost.org/LICENSE_1_0.txt)
6*/
7
8/*******************************************************
9 *                                                     *
10 *  -------------------------------------------------  *
11 *  |  0  |  1  |  2  |  3  |  4  |  5  |  6  |  7  |  *
12 *  -------------------------------------------------  *
13 *  |  0  |  4  |  8  |  12 |  16 |  20 |  24 |  28 |  *
14 *  -------------------------------------------------  *
15 *  |    F14    |    F15    |    F16    |    F17    |  *
16 *  -------------------------------------------------  *
17 *  -------------------------------------------------  *
18 *  |  8  |  9  |  10 |  11 |  12 |  13 |  14 |  15 |  *
19 *  -------------------------------------------------  *
20 *  |  32 |  36 |  40 |  44 |  48 |  52 |  56 |  60 |  *
21 *  -------------------------------------------------  *
22 *  |    F18    |    F19    |    F20    |    F21    |  *
23 *  -------------------------------------------------  *
24 *  -------------------------------------------------  *
25 *  |  16 |  17 |  18 |  19 |  20 |  21 |  22 |  23 |  *
26 *  -------------------------------------------------  *
27 *  |  64 |  68 |  72 |  76 |  80 |  84 |  88 |  92 |  *
28 *  -------------------------------------------------  *
29 *  |    F22    |    F23    |    F24    |    F25    |  *
30 *  -------------------------------------------------  *
31 *  -------------------------------------------------  *
32 *  |  24 |  25 |  26 |  27 |  28 |  29 |  30 |  31 |  *
33 *  -------------------------------------------------  *
34 *  |  96 | 100 | 104 | 108 | 112 | 116 | 120 | 124 |  *
35 *  -------------------------------------------------  *
36 *  |    F26    |    F27    |    F28    |    F29    |  *
37 *  -------------------------------------------------  *
38 *  -------------------------------------------------  *
39 *  |  32 |  33 |  34 |  35 |  36 |  37 |  38 |  39 |  *
40 *  -------------------------------------------------  *
41 *  | 128 | 132 | 136 | 140 | 144 | 148 | 152 | 156 |  *
42 *  -------------------------------------------------  *
43 *  |    F30    |    F31    |   fpscr   | R13 | R14 |  *
44 *  -------------------------------------------------  *
45 *  -------------------------------------------------  *
46 *  |  40 |  41 |  42 |  43 |  44 |  45 |  46 |  47 |  *
47 *  -------------------------------------------------  *
48 *  | 160 | 164 | 168 | 172 | 176 | 180 | 184 | 188 |  *
49 *  -------------------------------------------------  *
50 *  | R15 | R16 | R17 | R18 | R19 | R20 | R21 | R22 |  *
51 *  -------------------------------------------------  *
52 *  -------------------------------------------------  *
53 *  |  48 |  49 |  50 |  51 |  52 |  53 |  54 |  55 |  *
54 *  -------------------------------------------------  *
55 *  | 192 | 196 | 200 | 204 | 208 | 212 | 216 | 220 |  *
56 *  -------------------------------------------------  *
57 *  | R23 | R24 | R25 | R26 | R27 | R28 | R29 | R30 |  *
58 *  -------------------------------------------------  *
59 *  -------------------------------------------------  *
60 *  |  56 |  57 |  58 |  59 |                       |  *
61 *  -------------------------------------------------  *
62 *  | 224 | 228 | 232 | 236 |                       |  *
63 *  -------------------------------------------------  *
64 *  | R31 |  CR |  LR |  PC |                       |  *
65 *  -------------------------------------------------  *
66 *                                                     *
67 *******************************************************/
68
69.text
70.globl make_fcontext
71.align 2
72.type make_fcontext,@function
73make_fcontext:
74    # save return address into R6
75    mflr  %r6
76
77    # first arg of make_fcontext() == top address of context-function
78    # shift address in R3 to lower 16 byte boundary
79    clrrwi  %r3, %r3, 4
80
81    # reserve space for context-data on context-stack
82    # including 64 byte of linkage + parameter area (R1 % 16 == 0)
83    subi  %r3, %r3, 304
84
85    # third arg of make_fcontext() == address of context-function
86    stw  %r5, 236(%r3)
87
88    # load LR
89    mflr  %r0
90    # jump to label 1
91    bl  1f
921:
93    # load LR into R4
94    mflr  %r4
95    # compute abs address of label finish
96    addi  %r4, %r4, finish - 1b
97    # restore LR
98    mtlr  %r0
99    # save address of finish as return-address for context-function
100    # will be entered after context-function returns
101    stw  %r4, 232(%r3)
102
103    # restore return address from R6
104    mtlr  %r6
105
106    blr  # return pointer to context-data
107
108finish:
109    # save return address into R0
110    mflr  %r0
111    # save return address on stack, set up stack frame
112    stw  %r0, 4(%r1)
113    # allocate stack space, R1 % 16 == 0
114    stwu  %r1, -16(%r1)
115
116    # exit code is zero
117    li  %r3, 0
118    # exit application
119    bl  _exit@plt
120.size make_fcontext, .-make_fcontext
121
122/* Mark that we don't need executable stack.  */
123.section .note.GNU-stack,"",%progbits
124