1;/*
2;            Copyright Oliver Kowalke 2009.
3;   Distributed under the Boost Software License, Version 1.0.
4;      (See accompanying file LICENSE_1_0.txt or copy at
5;          http://www.boost.org/LICENSE_1_0.txt)
6;*/
7
8; *******************************************************
9; *                                                     *
10; *  -------------------------------------------------  *
11; *  |  0  |  1  |  2  |  3  |  4  |  5  |  6  |  7  |  *
12; *  -------------------------------------------------  *
13; *  | 0x0 | 0x4 | 0x8 | 0xc | 0x10| 0x14| 0x18| 0x1c|  *
14; *  -------------------------------------------------  *
15; *  | s16 | s17 | s18 | s19 | s20 | s21 | s22 | s23 |  *
16; *  -------------------------------------------------  *
17; *  -------------------------------------------------  *
18; *  |  8  |  9  |  10 |  11 |  12 |  13 |  14 |  15 |  *
19; *  -------------------------------------------------  *
20; *  | 0x20| 0x24| 0x28| 0x2c| 0x30| 0x34| 0x38| 0x3c|  *
21; *  -------------------------------------------------  *
22; *  | s24 | s25 | s26 | s27 | s28 | s29 | s30 | s31 |  *
23; *  -------------------------------------------------  *
24; *  -------------------------------------------------  *
25; *  |  16 |  17 |  18 |  19 |  20 |  21 |  22 |  23 |  *
26; *  -------------------------------------------------  *
27; *  | 0x40| 0x44| 0x48| 0x4c| 0x50| 0x54| 0x58| 0x5c|  *
28; *  -------------------------------------------------  *
29; *  |deall|limit| base|  v1 |  v2 |  v3 |  v4 |  v5 |  *
30; *  -------------------------------------------------  *
31; *  -------------------------------------------------  *
32; *  |  24 |  25 |  26 |  27 |  28 |                 |  *
33; *  -------------------------------------------------  *
34; *  | 0x60| 0x64| 0x68| 0x6c| 0x70|                 |  *
35; *  -------------------------------------------------  *
36; *  |  v6 |  v7 |  v8 |  lr |  pc |                 |  *
37; *  -------------------------------------------------  *
38; *                                                     *
39; *******************************************************
40
41
42    AREA |.text|, CODE
43    ALIGN 4
44    EXPORT make_fcontext
45    IMPORT _exit
46
47make_fcontext PROC
48    ; first arg of make_fcontext() == top of context-stack
49    ; save top of context-stack (base) A4
50    mov  a4, a1
51
52    ; shift address in A1 to lower 16 byte boundary
53    bic  a1, a1, #0x0f
54
55    ; reserve space for context-data on context-stack
56    sub  a1, a1, #0x74
57
58    ; save top address of context_stack as 'base'
59    str  a4, [a1,#0x48]
60    ; second arg of make_fcontext() == size of context-stack
61    ; compute bottom address of context-stack (limit)
62    sub  a4, a4, a2
63    ; save bottom address of context-stack as 'limit'
64    str  a4, [a1,#0x44]
65    ; save bottom address of context-stack as 'dealloction stack'
66    str  a4, [a1,#0x40]
67
68    ; third arg of make_fcontext() == address of context-function
69    str  a3, [a1,#0x70]
70
71    ; compute abs address of label finish
72    adr  a2, finish
73    ; save address of finish as return-address for context-function
74    ; will be entered after context-function returns
75    str  a2, [a1,#0x6c]
76
77    bx  lr ; return pointer to context-data
78
79finish
80    ; exit code is zero
81    mov  a1, #0
82    ; exit application
83    bl  _exit
84
85    ENDP
86    END
87