1/*
2            Copyright Oliver Kowalke 2009.
3   Distributed under the Boost Software License, Version 1.0.
4      (See accompanying file LICENSE_1_0.txt or copy at
5          http://www.boost.org/LICENSE_1_0.txt)
6*/
7
8/*******************************************************
9 *                                                     *
10 *  -------------------------------------------------  *
11 *  |  0  |  1  |  2  |  3  |  4  |  5  |  6  |  7  |  *
12 *  -------------------------------------------------  *
13 *  | 0x0 | 0x4 | 0x8 | 0xc | 0x10| 0x14| 0x18| 0x1c|  *
14 *  -------------------------------------------------  *
15 *  | s16 | s17 | s18 | s19 | s20 | s21 | s22 | s23 |  *
16 *  -------------------------------------------------  *
17 *  -------------------------------------------------  *
18 *  |  8  |  9  |  10 |  11 |  12 |  13 |  14 |  15 |  *
19 *  -------------------------------------------------  *
20 *  | 0x20| 0x24| 0x28| 0x2c| 0x30| 0x34| 0x38| 0x3c|  *
21 *  -------------------------------------------------  *
22 *  | s24 | s25 | s26 | s27 | s28 | s29 | s30 | s31 |  *
23 *  -------------------------------------------------  *
24 *  -------------------------------------------------  *
25 *  |  16 |  17 |  18 |  19 |  20 |  21 |  22 |  23 |  *
26 *  -------------------------------------------------  *
27 *  | 0x40| 0x44| 0x48| 0x4c| 0x50| 0x54| 0x58| 0x5c|  *
28 *  -------------------------------------------------  *
29 *  |  v1 |  v2 |  v3 |  v4 |  v5 |  v6 |  v7 |  v8 |  *
30 *  -------------------------------------------------  *
31 *  -------------------------------------------------  *
32 *  |  24 |  25 |                                   |  *
33 *  -------------------------------------------------  *
34 *  | 0x60| 0x64|                                   |  *
35 *  -------------------------------------------------  *
36 *  |  lr |  pc |                                   |  *
37 *  -------------------------------------------------  *
38 *                                                     *
39 *******************************************************/
40
41.text
42.globl make_fcontext
43.align 2
44.type make_fcontext,%function
45make_fcontext:
46    @ shift address in A1 to lower 16 byte boundary
47    bic  a1, a1, #15
48
49    @ reserve space for context-data on context-stack
50    sub  a1, a1, #104
51
52    @ third arg of make_fcontext() == address of context-function
53    str  a3, [a1,#100]
54
55    @ compute abs address of label finish
56    adr  a2, finish
57    @ save address of finish as return-address for context-function
58    @ will be entered after context-function returns
59    str  a2, [a1,#96]
60
61    bx  lr @ return pointer to context-data
62
63finish:
64    @ exit code is zero
65    mov  a1, #0
66    @ exit application
67    bl  _exit@PLT
68.size make_fcontext,.-make_fcontext
69
70@ Mark that we don't need executable stack.
71.section .note.GNU-stack,"",%progbits
72