1(module
2  (type $arr (array (mut i8)))
3
4  (data $d "abcd")
5
6  (func (export "array-init-data") (param $arr_len i32)
7                                   (param $dst i32)
8                                   (param $src i32)
9                                   (param $data_len i32) (result (ref $arr))
10    (local $a (ref $arr))
11    (local.set $a (array.new_default $arr (local.get $arr_len)))
12    (array.init_data $arr $d (local.get $a) (local.get $dst) (local.get $src) (local.get $data_len))
13    (local.get $a)
14  )
15)
16
17;; In bounds.
18(assert_return (invoke "array-init-data" (i32.const 4) (i32.const 0) (i32.const 0) (i32.const 0)) (ref.array))
19(assert_return (invoke "array-init-data" (i32.const 4) (i32.const 0) (i32.const 0) (i32.const 4)) (ref.array))
20(assert_return (invoke "array-init-data" (i32.const 4) (i32.const 0) (i32.const 1) (i32.const 2)) (ref.array))
21(assert_return (invoke "array-init-data" (i32.const 4) (i32.const 0) (i32.const 4) (i32.const 0)) (ref.array))
22
23;; Out-of-bounds data segment accesses.
24(assert_trap
25  (invoke "array-init-data" (i32.const 5) (i32.const 0) (i32.const 0) (i32.const 5))
26  "out of bounds memory access")
27(assert_trap
28  (invoke "array-init-data" (i32.const 4) (i32.const 0) (i32.const 5) (i32.const 0))
29  "out of bounds memory access")
30(assert_trap
31  (invoke "array-init-data" (i32.const 4) (i32.const 0) (i32.const 1) (i32.const 4))
32  "out of bounds memory access")
33(assert_trap
34  (invoke "array-init-data" (i32.const 4) (i32.const 0) (i32.const 4) (i32.const 1))
35  "out of bounds memory access")
36
37;; Out-of-bounds array accesses.
38(assert_trap
39  (invoke "array-init-data" (i32.const 3) (i32.const 0) (i32.const 0) (i32.const 4))
40  "out of bounds array access")
41(assert_trap
42  (invoke "array-init-data" (i32.const 3) (i32.const 1) (i32.const 0) (i32.const 3))
43  "out of bounds array access")
44(assert_trap
45  (invoke "array-init-data" (i32.const 3) (i32.const 3) (i32.const 0) (i32.const 1))
46  "out of bounds array access")
47(assert_trap
48  (invoke "array-init-data" (i32.const 3) (i32.const 4) (i32.const 0) (i32.const 0))
49  "out of bounds array access")
50
51(module
52  (type $arr (array (mut i8)))
53
54  (data $d "\aa\bb\cc\dd")
55
56  (func (export "array-init-data-contents") (result i32 i32)
57    (local (ref $arr))
58    (local.set 0 (array.new_default $arr (i32.const 4)))
59    (array.init_data $arr $d (local.get 0) (i32.const 0) (i32.const 1) (i32.const 2))
60    (array.get_u $arr (local.get 0) (i32.const 0))
61    (array.get_u $arr (local.get 0) (i32.const 1))
62  )
63)
64
65;; Array is initialized with the correct contents.
66(assert_return (invoke "array-init-data-contents") (i32.const 0xbb) (i32.const 0xcc))
67
68(module
69  (type $arr (array (mut i32)))
70
71  (data $d "\aa\bb\cc\dd")
72
73  (func (export "array-init-data-little-endian") (result i32)
74    (local (ref $arr))
75    (local.set 0 (array.new_default $arr (i32.const 1)))
76    (array.init_data $arr $d (local.get 0) (i32.const 0) (i32.const 0) (i32.const 1))
77    (array.get $arr (local.get 0) (i32.const 0))
78  )
79)
80
81;; Data segments are interpreted as little-endian.
82(assert_return (invoke "array-init-data-little-endian") (i32.const 0xddccbbaa))
83
84(module
85  (type $arr (array (mut i16)))
86
87  (data $d "\00\11\22")
88
89  (func (export "array-init-data-unaligned") (result i32)
90    (local (ref $arr))
91    (local.set 0 (array.new_default $arr (i32.const 1)))
92    (array.init_data $arr $d (local.get 0) (i32.const 0) (i32.const 1) (i32.const 1))
93    (array.get_u $arr (local.get 0) (i32.const 0))
94  )
95)
96
97;; Data inside the segment doesn't need to be aligned to the element size.
98(assert_return (invoke "array-init-data-unaligned") (i32.const 0x2211))
99