1" Tests for the writefile() function and some :write commands.
2
3source check.vim
4source term_util.vim
5
6func Test_writefile()
7  let f = tempname()
8  call writefile(["over","written"], f, "b")
9  call writefile(["hello","world"], f, "b")
10  call writefile(["!", "good"], f, "a")
11  call writefile(["morning"], f, "ab")
12  call writefile(["", "vimmers"], f, "ab")
13  let l = readfile(f)
14  call assert_equal("hello", l[0])
15  call assert_equal("world!", l[1])
16  call assert_equal("good", l[2])
17  call assert_equal("morning", l[3])
18  call assert_equal("vimmers", l[4])
19  call delete(f)
20
21  call assert_fails('call writefile("text", "Xfile")', 'E475: Invalid argument: writefile() first argument must be a List or a Blob')
22endfunc
23
24func Test_writefile_ignore_regexp_error()
25  write Xt[z-a]est.txt
26  call delete('Xt[z-a]est.txt')
27endfunc
28
29func Test_writefile_fails_gently()
30  call assert_fails('call writefile(["test"], "Xfile", [])', 'E730:')
31  call assert_false(filereadable("Xfile"))
32  call delete("Xfile")
33
34  call assert_fails('call writefile(["test", [], [], [], "tset"], "Xfile")', 'E730:')
35  call assert_false(filereadable("Xfile"))
36  call delete("Xfile")
37
38  call assert_fails('call writefile([], "Xfile", [])', 'E730:')
39  call assert_false(filereadable("Xfile"))
40  call delete("Xfile")
41
42  call assert_fails('call writefile([], [])', 'E730:')
43endfunc
44
45func Test_writefile_fails_conversion()
46  if !has('iconv') || has('sun')
47    return
48  endif
49  " Without a backup file the write won't happen if there is a conversion
50  " error.
51  set nobackup nowritebackup backupdir=. backupskip=
52  new
53  let contents = ["line one", "line two"]
54  call writefile(contents, 'Xfile')
55  edit Xfile
56  call setline(1, ["first line", "cannot convert \u010b", "third line"])
57  call assert_fails('write ++enc=cp932', 'E513:')
58  call assert_equal(contents, readfile('Xfile'))
59
60  call delete('Xfile')
61  bwipe!
62  set backup& writebackup& backupdir&vim backupskip&vim
63endfunc
64
65func Test_writefile_fails_conversion2()
66  if !has('iconv') || has('sun')
67    return
68  endif
69  " With a backup file the write happens even if there is a conversion error,
70  " but then the backup file must remain
71  set nobackup writebackup backupdir=. backupskip=
72  let contents = ["line one", "line two"]
73  call writefile(contents, 'Xfile_conversion_err')
74  edit Xfile_conversion_err
75  call setline(1, ["first line", "cannot convert \u010b", "third line"])
76  set fileencoding=latin1
77  let output = execute('write')
78  call assert_match('CONVERSION ERROR', output)
79  call assert_equal(contents, readfile('Xfile_conversion_err~'))
80
81  call delete('Xfile_conversion_err')
82  call delete('Xfile_conversion_err~')
83  bwipe!
84  set backup& writebackup& backupdir&vim backupskip&vim
85endfunc
86
87func SetFlag(timer)
88  let g:flag = 1
89endfunc
90
91func Test_write_quit_split()
92  " Prevent exiting by splitting window on file write.
93  augroup testgroup
94    autocmd BufWritePre * split
95  augroup END
96  e! Xfile
97  call setline(1, 'nothing')
98  wq
99
100  if has('timers')
101    " timer will not run if "exiting" is still set
102    let g:flag = 0
103    call timer_start(1, 'SetFlag')
104    sleep 50m
105    call assert_equal(1, g:flag)
106    unlet g:flag
107  endif
108  au! testgroup
109  bwipe Xfile
110  call delete('Xfile')
111endfunc
112
113func Test_nowrite_quit_split()
114  " Prevent exiting by opening a help window.
115  e! Xfile
116  help
117  wincmd w
118  exe winnr() . 'q'
119
120  if has('timers')
121    " timer will not run if "exiting" is still set
122    let g:flag = 0
123    call timer_start(1, 'SetFlag')
124    sleep 50m
125    call assert_equal(1, g:flag)
126    unlet g:flag
127  endif
128  bwipe Xfile
129endfunc
130
131func Test_writefile_sync_arg()
132  " This doesn't check if fsync() works, only that the argument is accepted.
133  call writefile(['one'], 'Xtest', 's')
134  call writefile(['two'], 'Xtest', 'S')
135  call delete('Xtest')
136endfunc
137
138func Test_writefile_sync_dev_stdout()
139  if !has('unix')
140    return
141  endif
142  if filewritable('/dev/stdout')
143    " Just check that this doesn't cause an error.
144    call writefile(['one'], '/dev/stdout')
145  else
146    throw 'Skipped: /dev/stdout is not writable'
147  endif
148endfunc
149
150func Test_writefile_autowrite()
151  set autowrite
152  new
153  next Xa Xb Xc
154  call setline(1, 'aaa')
155  next
156  call assert_equal(['aaa'], readfile('Xa'))
157  call setline(1, 'bbb')
158  call assert_fails('edit XX')
159  call assert_false(filereadable('Xb'))
160
161  set autowriteall
162  edit XX
163  call assert_equal(['bbb'], readfile('Xb'))
164
165  bwipe!
166  call delete('Xa')
167  call delete('Xb')
168  set noautowrite
169endfunc
170
171func Test_writefile_autowrite_nowrite()
172  set autowrite
173  new
174  next Xa Xb Xc
175  set buftype=nowrite
176  call setline(1, 'aaa')
177  let buf = bufnr('%')
178  " buffer contents silently lost
179  edit XX
180  call assert_false(filereadable('Xa'))
181  rewind
182  call assert_equal('', getline(1))
183
184  bwipe!
185  set noautowrite
186endfunc
187
188" Test for ':w !<cmd>' to pipe lines from the current buffer to an external
189" command.
190func Test_write_pipe_to_cmd()
191  CheckUnix
192  new
193  call setline(1, ['L1', 'L2', 'L3', 'L4'])
194  2,3w !cat > Xfile
195  call assert_equal(['L2', 'L3'], readfile('Xfile'))
196  close!
197  call delete('Xfile')
198endfunc
199
200" Test for :saveas
201func Test_saveas()
202  call assert_fails('saveas', 'E471:')
203  call writefile(['L1'], 'Xfile')
204  new Xfile
205  new
206  call setline(1, ['L1'])
207  call assert_fails('saveas Xfile', 'E139:')
208  close!
209  enew | only
210  call delete('Xfile')
211endfunc
212
213func Test_write_errors()
214  " Test for writing partial buffer
215  call writefile(['L1', 'L2', 'L3'], 'Xfile')
216  new Xfile
217  call assert_fails('1,2write', 'E140:')
218  close!
219
220  call assert_fails('w > Xtest', 'E494:')
221
222  " Try to overwrite a directory
223  if has('unix')
224    call mkdir('Xdir1')
225    call assert_fails('write Xdir1', 'E17:')
226    call delete('Xdir1', 'd')
227  endif
228
229  " Test for :wall for a buffer with no name
230  enew | only
231  call setline(1, ['L1'])
232  call assert_fails('wall', 'E141:')
233  enew!
234
235  " Test for writing a 'readonly' file
236  new Xfile
237  set readonly
238  call assert_fails('write', 'E45:')
239  close
240
241  " Test for writing to a read-only file
242  new Xfile
243  call setfperm('Xfile', 'r--r--r--')
244  call assert_fails('write', 'E505:')
245  call setfperm('Xfile', 'rw-rw-rw-')
246  close
247
248  call delete('Xfile')
249
250  call writefile(test_null_list(), 'Xfile')
251  call assert_false(filereadable('Xfile'))
252  call writefile(test_null_blob(), 'Xfile')
253  call assert_false(filereadable('Xfile'))
254  call assert_fails('call writefile([], "")', 'E482:')
255
256  " very long file name
257  let long_fname = repeat('n', 5000)
258  call assert_fails('exe "w " .. long_fname', 'E75:')
259  call assert_fails('call writefile([], long_fname)', 'E482:')
260endfunc
261
262" Test for writing to a file which is modified after Vim read it
263func Test_write_file_mtime()
264  CheckEnglish
265  CheckRunVimInTerminal
266
267  " First read the file into a buffer
268  call writefile(["Line1", "Line2"], 'Xfile')
269  let old_ftime = getftime('Xfile')
270  let buf = RunVimInTerminal('Xfile', #{rows : 10})
271  call term_wait(buf)
272  call term_sendkeys(buf, ":set noswapfile\<CR>")
273  call term_wait(buf)
274
275  " Modify the file directly.  Make sure the file modification time is
276  " different. Note that on Linux/Unix, the file is considered modified
277  " outside, only if the difference is 2 seconds or more
278  sleep 1
279  call writefile(["Line3", "Line4"], 'Xfile')
280  let new_ftime = getftime('Xfile')
281  while new_ftime - old_ftime < 2
282    sleep 100m
283    call writefile(["Line3", "Line4"], 'Xfile')
284    let new_ftime = getftime('Xfile')
285  endwhile
286
287  " Try to overwrite the file and check for the prompt
288  call term_sendkeys(buf, ":w\<CR>")
289  call term_wait(buf)
290  call WaitForAssert({-> assert_equal("WARNING: The file has been changed since reading it!!!", term_getline(buf, 9))})
291  call assert_equal("Do you really want to write to it (y/n)?",
292        \ term_getline(buf, 10))
293  call term_sendkeys(buf, "n\<CR>")
294  call term_wait(buf)
295  call assert_equal(new_ftime, getftime('Xfile'))
296  call term_sendkeys(buf, ":w\<CR>")
297  call term_wait(buf)
298  call term_sendkeys(buf, "y\<CR>")
299  call term_wait(buf)
300  call WaitForAssert({-> assert_equal('Line2', readfile('Xfile')[1])})
301
302  " clean up
303  call StopVimInTerminal(buf)
304  call delete('Xfile')
305endfunc
306
307" Test for an autocmd unloading a buffer during a write command
308func Test_write_autocmd_unloadbuf_lockmark()
309  augroup WriteTest
310    autocmd BufWritePre Xfile enew | write
311  augroup END
312  e Xfile
313  call assert_fails('lockmarks write', ['E32', 'E203:'])
314  augroup WriteTest
315    au!
316  augroup END
317  augroup! WriteTest
318endfunc
319
320" Test for writing a buffer with 'acwrite' but without autocmds
321func Test_write_acwrite_error()
322  new Xfile
323  call setline(1, ['line1', 'line2', 'line3'])
324  set buftype=acwrite
325  call assert_fails('write', 'E676:')
326  call assert_fails('1,2write!', 'E676:')
327  call assert_fails('w >>', 'E676:')
328  close!
329endfunc
330
331" Test for adding and removing lines from an autocmd when writing a buffer
332func Test_write_autocmd_add_remove_lines()
333  new Xfile
334  call setline(1, ['aaa', 'bbb', 'ccc', 'ddd'])
335
336  " Autocmd deleting lines from the file when writing a partial file
337  augroup WriteTest2
338    au!
339    autocmd FileWritePre Xfile 1,2d
340  augroup END
341  call assert_fails('2,3w!', 'E204:')
342
343  " Autocmd adding lines to a file when writing a partial file
344  augroup WriteTest2
345    au!
346    autocmd FileWritePre Xfile call append(0, ['xxx', 'yyy'])
347  augroup END
348  %d
349  call setline(1, ['aaa', 'bbb', 'ccc', 'ddd'])
350  1,2w!
351  call assert_equal(['xxx', 'yyy', 'aaa', 'bbb'], readfile('Xfile'))
352
353  " Autocmd deleting lines from the file when writing the whole file
354  augroup WriteTest2
355    au!
356    autocmd BufWritePre Xfile 1,2d
357  augroup END
358  %d
359  call setline(1, ['aaa', 'bbb', 'ccc', 'ddd'])
360  w
361  call assert_equal(['ccc', 'ddd'], readfile('Xfile'))
362
363  augroup WriteTest2
364    au!
365  augroup END
366  augroup! WriteTest2
367
368  close!
369  call delete('Xfile')
370endfunc
371
372" Test for writing to a readonly file
373func Test_write_readonly()
374  " In Cirrus-CI, the freebsd tests are run under a root account. So this test
375  " doesn't fail.
376  CheckNotBSD
377  call writefile([], 'Xfile')
378  call setfperm('Xfile', "r--------")
379  edit Xfile
380  set noreadonly
381  call assert_fails('write', 'E505:')
382  let save_cpo = &cpo
383  set cpo+=W
384  call assert_fails('write!', 'E504:')
385  let &cpo = save_cpo
386  call setline(1, ['line1'])
387  write!
388  call assert_equal(['line1'], readfile('Xfile'))
389  call delete('Xfile')
390endfunc
391
392" Test for 'patchmode'
393func Test_patchmode()
394  CheckNotBSD
395  call writefile(['one'], 'Xfile')
396  set patchmode=.orig nobackup writebackup
397  new Xfile
398  call setline(1, 'two')
399  " first write should create the .orig file
400  write
401  " TODO: Xfile.orig is not created in Cirrus FreeBSD CI test
402  call assert_equal(['one'], readfile('Xfile.orig'))
403  call setline(1, 'three')
404  " subsequent writes should not create/modify the .orig file
405  write
406  call assert_equal(['one'], readfile('Xfile.orig'))
407  set patchmode& backup& writebackup&
408  call delete('Xfile')
409  call delete('Xfile.orig')
410endfunc
411
412" Test for writing to a file in a readonly directory
413func Test_write_readonly_dir()
414  if !has('unix') || has('bsd')
415    " On MS-Windows, modifying files in a read-only directory is allowed.
416    " In Cirrus-CI for Freebsd, tests are run under a root account where
417    " modifying files in a read-only directory are allowed.
418    return
419  endif
420  call mkdir('Xdir')
421  call writefile(['one'], 'Xdir/Xfile1')
422  call setfperm('Xdir', 'r-xr--r--')
423  " try to create a new file in the directory
424  new Xdir/Xfile2
425  call setline(1, 'two')
426  call assert_fails('write', 'E212:')
427  " try to create a backup file in the directory
428  edit! Xdir/Xfile1
429  set backupdir=./Xdir
430  set patchmode=.orig
431  call assert_fails('write', 'E509:')
432  call setfperm('Xdir', 'rwxr--r--')
433  call delete('Xdir', 'rf')
434  set backupdir& patchmode&
435endfunc
436
437" Test for writing a file using invalid file encoding
438func Test_write_invalid_encoding()
439  new
440  call setline(1, 'abc')
441  call assert_fails('write ++enc=axbyc Xfile', 'E213:')
442  close!
443endfunc
444
445" Tests for reading and writing files with conversion for Win32.
446func Test_write_file_encoding()
447  CheckMSWindows
448  let save_encoding = &encoding
449  let save_fileencodings = &fileencodings
450  set encoding& fileencodings&
451  let text =<< trim END
452    1 utf-8 text: Для Vim version 6.2.  Последнее изменение: 1970 Jan 01
453    2 cp1251 text: ��� Vim version 6.2.  ��������� ���������: 1970 Jan 01
454    3 cp866 text: ��� Vim version 6.2.  ��᫥���� ���������: 1970 Jan 01
455  END
456  call writefile(text, 'Xfile')
457  edit Xfile
458
459  " write tests:
460  " combine three values for 'encoding' with three values for 'fileencoding'
461  " also write files for read tests
462  call cursor(1, 1)
463  set encoding=utf-8
464  .w! ++enc=utf-8 Xtest
465  .w ++enc=cp1251 >> Xtest
466  .w ++enc=cp866 >> Xtest
467  .w! ++enc=utf-8 Xutf8
468  let expected =<< trim END
469    1 utf-8 text: Для Vim version 6.2.  Последнее изменение: 1970 Jan 01
470    1 utf-8 text: ��� Vim version 6.2.  ��������� ���������: 1970 Jan 01
471    1 utf-8 text: ��� Vim version 6.2.  ��᫥���� ���������: 1970 Jan 01
472  END
473  call assert_equal(expected, readfile('Xtest'))
474
475  call cursor(2, 1)
476  set encoding=cp1251
477  .w! ++enc=utf-8 Xtest
478  .w ++enc=cp1251 >> Xtest
479  .w ++enc=cp866 >> Xtest
480  .w! ++enc=cp1251 Xcp1251
481  let expected =<< trim END
482    2 cp1251 text: Для Vim version 6.2.  Последнее изменение: 1970 Jan 01
483    2 cp1251 text: ��� Vim version 6.2.  ��������� ���������: 1970 Jan 01
484    2 cp1251 text: ��� Vim version 6.2.  ��᫥���� ���������: 1970 Jan 01
485  END
486  call assert_equal(expected, readfile('Xtest'))
487
488  call cursor(3, 1)
489  set encoding=cp866
490  .w! ++enc=utf-8 Xtest
491  .w ++enc=cp1251 >> Xtest
492  .w ++enc=cp866 >> Xtest
493  .w! ++enc=cp866 Xcp866
494  let expected =<< trim END
495    3 cp866 text: Для Vim version 6.2.  Последнее изменение: 1970 Jan 01
496    3 cp866 text: ��� Vim version 6.2.  ��������� ���������: 1970 Jan 01
497    3 cp866 text: ��� Vim version 6.2.  ��᫥���� ���������: 1970 Jan 01
498  END
499  call assert_equal(expected, readfile('Xtest'))
500
501  " read three 'fileencoding's with utf-8 'encoding'
502  set encoding=utf-8 fencs=utf-8,cp1251
503  e Xutf8
504  .w! ++enc=utf-8 Xtest
505  e Xcp1251
506  .w ++enc=utf-8 >> Xtest
507  set fencs=utf-8,cp866
508  e Xcp866
509  .w ++enc=utf-8 >> Xtest
510  let expected =<< trim END
511    1 utf-8 text: Для Vim version 6.2.  Последнее изменение: 1970 Jan 01
512    2 cp1251 text: Для Vim version 6.2.  Последнее изменение: 1970 Jan 01
513    3 cp866 text: Для Vim version 6.2.  Последнее изменение: 1970 Jan 01
514  END
515  call assert_equal(expected, readfile('Xtest'))
516
517  " read three 'fileencoding's with cp1251 'encoding'
518  set encoding=utf-8 fencs=utf-8,cp1251
519  e Xutf8
520  .w! ++enc=cp1251 Xtest
521  e Xcp1251
522  .w ++enc=cp1251 >> Xtest
523  set fencs=utf-8,cp866
524  e Xcp866
525  .w ++enc=cp1251 >> Xtest
526  let expected =<< trim END
527    1 utf-8 text: ��� Vim version 6.2.  ��������� ���������: 1970 Jan 01
528    2 cp1251 text: ��� Vim version 6.2.  ��������� ���������: 1970 Jan 01
529    3 cp866 text: ��� Vim version 6.2.  ��������� ���������: 1970 Jan 01
530  END
531  call assert_equal(expected, readfile('Xtest'))
532
533  " read three 'fileencoding's with cp866 'encoding'
534  set encoding=cp866 fencs=utf-8,cp1251
535  e Xutf8
536  .w! ++enc=cp866 Xtest
537  e Xcp1251
538  .w ++enc=cp866 >> Xtest
539  set fencs=utf-8,cp866
540  e Xcp866
541  .w ++enc=cp866 >> Xtest
542  let expected =<< trim END
543    1 utf-8 text: ��� Vim version 6.2.  ��᫥���� ���������: 1970 Jan 01
544    2 cp1251 text: ��� Vim version 6.2.  ��᫥���� ���������: 1970 Jan 01
545    3 cp866 text: ��� Vim version 6.2.  ��᫥���� ���������: 1970 Jan 01
546  END
547  call assert_equal(expected, readfile('Xtest'))
548
549  call delete('Xfile')
550  call delete('Xtest')
551  call delete('Xutf8')
552  call delete('Xcp1251')
553  call delete('Xcp866')
554  let &encoding = save_encoding
555  let &fileencodings = save_fileencodings
556  %bw!
557endfunc
558
559" Test for writing and reading a file starting with a BOM.
560" Byte Order Mark (BOM) character for various encodings is below:
561"     UTF-8      : EF BB BF
562"     UTF-16 (BE): FE FF
563"     UTF-16 (LE): FF FE
564"     UTF-32 (BE): 00 00 FE FF
565"     UTF-32 (LE): FF FE 00 00
566func Test_readwrite_file_with_bom()
567  let utf8_bom = "\xEF\xBB\xBF"
568  let utf16be_bom = "\xFE\xFF"
569  let utf16le_bom = "\xFF\xFE"
570  let utf32be_bom = "\n\n\xFE\xFF"
571  let utf32le_bom = "\xFF\xFE\n\n"
572  let save_fileencoding = &fileencoding
573  set cpoptions+=S
574
575  " Check that editing a latin1 file doesn't see a BOM
576  call writefile(["\xFE\xFElatin-1"], 'Xtest1')
577  edit Xtest1
578  call assert_equal('latin1', &fileencoding)
579  call assert_equal(0, &bomb)
580  set fenc=latin1
581  write Xfile2
582  call assert_equal(["\xFE\xFElatin-1", ''], readfile('Xfile2', 'b'))
583  set bomb fenc=latin1
584  write Xtest3
585  call assert_equal(["\xFE\xFElatin-1", ''], readfile('Xtest3', 'b'))
586  set bomb&
587
588  " Check utf-8 BOM
589  %bw!
590  call writefile([utf8_bom .. "utf-8"], 'Xtest1')
591  edit! Xtest1
592  call assert_equal('utf-8', &fileencoding)
593  call assert_equal(1, &bomb)
594  call assert_equal('utf-8', getline(1))
595  set fenc=latin1
596  write! Xfile2
597  call assert_equal(['utf-8', ''], readfile('Xfile2', 'b'))
598  set fenc=utf-8
599  w! Xtest3
600  call assert_equal([utf8_bom .. "utf-8", ''], readfile('Xtest3', 'b'))
601
602  " Check utf-8 with an error (will fall back to latin-1)
603  %bw!
604  call writefile([utf8_bom .. "utf-8\x80err"], 'Xtest1')
605  edit! Xtest1
606  call assert_equal('latin1', &fileencoding)
607  call assert_equal(0, &bomb)
608  call assert_equal("\xC3\xAF\xC2\xBB\xC2\xBFutf-8\xC2\x80err", getline(1))
609  set fenc=latin1
610  write! Xfile2
611  call assert_equal([utf8_bom .. "utf-8\x80err", ''], readfile('Xfile2', 'b'))
612  set fenc=utf-8
613  w! Xtest3
614  call assert_equal(["\xC3\xAF\xC2\xBB\xC2\xBFutf-8\xC2\x80err", ''],
615        \ readfile('Xtest3', 'b'))
616
617  " Check ucs-2 BOM
618  %bw!
619  call writefile([utf16be_bom .. "\nu\nc\ns\n-\n2\n"], 'Xtest1')
620  edit! Xtest1
621  call assert_equal('utf-16', &fileencoding)
622  call assert_equal(1, &bomb)
623  call assert_equal('ucs-2', getline(1))
624  set fenc=latin1
625  write! Xfile2
626  call assert_equal(["ucs-2", ''], readfile('Xfile2', 'b'))
627  set fenc=ucs-2
628  w! Xtest3
629  call assert_equal([utf16be_bom .. "\nu\nc\ns\n-\n2\n", ''],
630        \ readfile('Xtest3', 'b'))
631
632  " Check ucs-2le BOM
633  %bw!
634  call writefile([utf16le_bom .. "u\nc\ns\n-\n2\nl\ne\n"], 'Xtest1')
635  " Need to add a NUL byte after the NL byte
636  call writefile(0z00, 'Xtest1', 'a')
637  edit! Xtest1
638  call assert_equal('utf-16le', &fileencoding)
639  call assert_equal(1, &bomb)
640  call assert_equal('ucs-2le', getline(1))
641  set fenc=latin1
642  write! Xfile2
643  call assert_equal(["ucs-2le", ''], readfile('Xfile2', 'b'))
644  set fenc=ucs-2le
645  w! Xtest3
646  call assert_equal([utf16le_bom .. "u\nc\ns\n-\n2\nl\ne\n", "\n"],
647        \ readfile('Xtest3', 'b'))
648
649  " Check ucs-4 BOM
650  %bw!
651  call writefile([utf32be_bom .. "\n\n\nu\n\n\nc\n\n\ns\n\n\n-\n\n\n4\n\n\n"], 'Xtest1')
652  edit! Xtest1
653  call assert_equal('ucs-4', &fileencoding)
654  call assert_equal(1, &bomb)
655  call assert_equal('ucs-4', getline(1))
656  set fenc=latin1
657  write! Xfile2
658  call assert_equal(["ucs-4", ''], readfile('Xfile2', 'b'))
659  set fenc=ucs-4
660  w! Xtest3
661  call assert_equal([utf32be_bom .. "\n\n\nu\n\n\nc\n\n\ns\n\n\n-\n\n\n4\n\n\n", ''], readfile('Xtest3', 'b'))
662
663  " Check ucs-4le BOM
664  %bw!
665  call writefile([utf32le_bom .. "u\n\n\nc\n\n\ns\n\n\n-\n\n\n4\n\n\nl\n\n\ne\n\n\n"], 'Xtest1')
666  " Need to add three NUL bytes after the NL byte
667  call writefile(0z000000, 'Xtest1', 'a')
668  edit! Xtest1
669  call assert_equal('ucs-4le', &fileencoding)
670  call assert_equal(1, &bomb)
671  call assert_equal('ucs-4le', getline(1))
672  set fenc=latin1
673  write! Xfile2
674  call assert_equal(["ucs-4le", ''], readfile('Xfile2', 'b'))
675  set fenc=ucs-4le
676  w! Xtest3
677  call assert_equal([utf32le_bom .. "u\n\n\nc\n\n\ns\n\n\n-\n\n\n4\n\n\nl\n\n\ne\n\n\n", "\n\n\n"], readfile('Xtest3', 'b'))
678
679  set cpoptions-=S
680  let &fileencoding = save_fileencoding
681  call delete('Xtest1')
682  call delete('Xtest2')
683  call delete('Xtest3')
684  %bw!
685endfunc
686
687" vim: shiftwidth=2 sts=2 expandtab
688