xref: /vim-8.2.3635/src/testdir/test_suspend.vim (revision d0bce504) 
1" Test :suspend
2
3source check.vim
4source term_util.vim
5
6func CheckSuspended(buf, fileExists)
7  call WaitForAssert({-> assert_match('[$#] $', term_getline(a:buf, '.'))})
8
9  if a:fileExists
10    call assert_equal(['foo'], readfile('Xfoo'))
11  else
12    " Without 'autowrite', buffer should not be written.
13    call assert_equal(0, filereadable('Xfoo'))
14  endif
15
16  call term_sendkeys(a:buf, "fg\<CR>\<C-L>")
17  call WaitForAssert({-> assert_equal('  1 foo', term_getline(a:buf, '.'))})
18endfunc
19
20func Test_suspend()
21  CheckFeature terminal
22  CheckExecutable /bin/sh
23
24  let buf = term_start('/bin/sh')
25  " Wait for shell prompt.
26  call WaitForAssert({-> assert_match('[$#] $', term_getline(buf, '.'))})
27
28  call term_sendkeys(buf, v:progpath
29        \               . " --clean -X"
30        \               . " -c 'set nu'"
31        \               . " -c 'call setline(1, \"foo\")'"
32        \               . " Xfoo\<CR>")
33  " Cursor in terminal buffer should be on first line in spawned vim.
34  call WaitForAssert({-> assert_equal('  1 foo', term_getline(buf, '.'))})
35
36  for suspend_cmd in [":suspend\<CR>",
37        \             ":stop\<CR>",
38        \             ":suspend!\<CR>",
39        \             ":stop!\<CR>",
40        \             "\<C-Z>"]
41    " Suspend and wait for shell prompt.
42    call term_sendkeys(buf, suspend_cmd)
43    call CheckSuspended(buf, 0)
44  endfor
45
46  " Test that :suspend! with 'autowrite' writes content of buffers if modified.
47  call term_sendkeys(buf, ":set autowrite\<CR>")
48  call assert_equal(0, filereadable('Xfoo'))
49  call term_sendkeys(buf, ":suspend\<CR>")
50  " Wait for shell prompt.
51  call CheckSuspended(buf, 1)
52
53  " Quit gracefully to dump coverage information.
54  call term_sendkeys(buf, ":qall!\<CR>")
55  call TermWait(buf)
56  " Wait until Vim actually exited and shell shows a prompt
57  call WaitForAssert({-> assert_match('[$#] $', term_getline(buf, '.'))})
58  call StopShellInTerminal(buf)
59
60  exe buf . 'bwipe!'
61  call delete('Xfoo')
62endfunc
63
64func Test_suspend_autocmd()
65  CheckFeature terminal
66  CheckExecutable /bin/sh
67
68  let buf = term_start('/bin/sh', #{term_rows: 6})
69  " Wait for shell prompt.
70  call WaitForAssert({-> assert_match('[$#] $', term_getline(buf, '.'))})
71
72  call term_sendkeys(buf, v:progpath
73        \               . " --clean -X"
74        \               . " -c 'set nu'"
75        \               . " -c 'let g:count = 0'"
76        \               . " -c 'au VimSuspend * let g:count += 1'"
77        \               . " -c 'au VimResume * let g:count += 1'"
78        \               . " -c 'call setline(1, \"foo\")'"
79        \               . " Xfoo\<CR>")
80  " Cursor in terminal buffer should be on first line in spawned vim.
81  call WaitForAssert({-> assert_equal('  1 foo', term_getline(buf, '.'))})
82
83  for suspend_cmd in [":suspend\<CR>",
84        \             ":stop\<CR>",
85        \             ":suspend!\<CR>",
86        \             ":stop!\<CR>",
87        \             "\<C-Z>"]
88    " Suspend and wait for shell prompt.  Then "fg" will restore Vim.
89    call term_sendkeys(buf, suspend_cmd)
90    call CheckSuspended(buf, 0)
91  endfor
92
93  call term_sendkeys(buf, ":echo g:count\<CR>")
94  call TermWait(buf)
95  call WaitForAssert({-> assert_match('^10', term_getline(buf, 6))})
96
97  " Quit gracefully to dump coverage information.
98  call term_sendkeys(buf, ":qall!\<CR>")
99  call TermWait(buf)
100  " Wait until Vim actually exited and shell shows a prompt
101  call WaitForAssert({-> assert_match('[$#] $', term_getline(buf, '.'))})
102  call StopShellInTerminal(buf)
103
104  exe buf . 'bwipe!'
105  call delete('Xfoo')
106endfunc
107
108" vim: shiftwidth=2 sts=2 expandtab
109