1" Tests for the List and Dict types
2
3func TearDown()
4  " Run garbage collection after every test
5  call test_garbagecollect_now()
6endfunc
7
8" Tests for List type
9
10" List creation
11func Test_list_create()
12  " Creating List directly with different types
13  let l = [1, 'as''d', [1, 2, function("strlen")], {'a': 1},]
14  call assert_equal("[1, 'as''d', [1, 2, function('strlen')], {'a': 1}]", string(l))
15  call assert_equal({'a' : 1}, l[-1])
16  call assert_equal(1, l[-4])
17  let x = 10
18  try
19    let x = l[-5]
20  catch
21    call assert_match('E684:', v:exception)
22  endtry
23  call assert_equal(10, x)
24endfunc
25
26" List slices
27func Test_list_slice()
28  let l = [1, 'as''d', [1, 2, function("strlen")], {'a': 1},]
29  call assert_equal([1, 'as''d', [1, 2, function('strlen')], {'a': 1}], l[:])
30  call assert_equal(['as''d', [1, 2, function('strlen')], {'a': 1}], l[1:])
31  call assert_equal([1, 'as''d', [1, 2, function('strlen')]], l[:-2])
32  call assert_equal([1, 'as''d', [1, 2, function('strlen')], {'a': 1}], l[0:8])
33  call assert_equal([], l[8:-1])
34endfunc
35
36" List identity
37func Test_list_identity()
38  let l = [1, 'as''d', [1, 2, function("strlen")], {'a': 1},]
39  let ll = l
40  let lx = copy(l)
41  call assert_true(l == ll)
42  call assert_false(l isnot ll)
43  call assert_true(l is ll)
44  call assert_true(l == lx)
45  call assert_false(l is lx)
46  call assert_true(l isnot lx)
47endfunc
48
49" removing items with :unlet
50func Test_list_unlet()
51  let l = [1, 'as''d', [1, 2, function("strlen")], {'a': 1},]
52  unlet l[2]
53  call assert_equal([1, 'as''d', {'a': 1}], l)
54  let l = range(8)
55  unlet l[:3]
56  unlet l[1:]
57  call assert_equal([4], l)
58
59  " removing items out of range: silently skip items that don't exist
60  let l = [0, 1, 2, 3]
61  call assert_fails('unlet l[2:1]', 'E684')
62  let l = [0, 1, 2, 3]
63  unlet l[2:2]
64  call assert_equal([0, 1, 3], l)
65  let l = [0, 1, 2, 3]
66  unlet l[2:3]
67  call assert_equal([0, 1], l)
68  let l = [0, 1, 2, 3]
69  unlet l[2:4]
70  call assert_equal([0, 1], l)
71  let l = [0, 1, 2, 3]
72  unlet l[2:5]
73  call assert_equal([0, 1], l)
74  let l = [0, 1, 2, 3]
75  call assert_fails('unlet l[-1:2]', 'E684')
76  let l = [0, 1, 2, 3]
77  unlet l[-2:2]
78  call assert_equal([0, 1, 3], l)
79  let l = [0, 1, 2, 3]
80  unlet l[-3:2]
81  call assert_equal([0, 3], l)
82  let l = [0, 1, 2, 3]
83  unlet l[-4:2]
84  call assert_equal([3], l)
85  let l = [0, 1, 2, 3]
86  unlet l[-5:2]
87  call assert_equal([3], l)
88  let l = [0, 1, 2, 3]
89  unlet l[-6:2]
90  call assert_equal([3], l)
91endfunc
92
93" assignment to a list
94func Test_list_assign()
95  let l = [0, 1, 2, 3]
96  let [va, vb] = l[2:3]
97  call assert_equal([2, 3], [va, vb])
98  call assert_fails('let [va, vb] = l', 'E687')
99  call assert_fails('let [va, vb] = l[1:1]', 'E688')
100endfunc
101
102" test for range assign
103func Test_list_range_assign()
104  let l = [0]
105  let l[:] = [1, 2]
106  call assert_equal([1, 2], l)
107endfunc
108
109" Test removing items in list
110func Test_list_func_remove()
111  " Test removing 1 element
112  let l = [1, 2, 3, 4]
113  call assert_equal(1, remove(l, 0))
114  call assert_equal([2, 3, 4], l)
115
116  let l = [1, 2, 3, 4]
117  call assert_equal(2, remove(l, 1))
118  call assert_equal([1, 3, 4], l)
119
120  let l = [1, 2, 3, 4]
121  call assert_equal(4, remove(l, -1))
122  call assert_equal([1, 2, 3], l)
123
124  " Test removing range of element(s)
125  let l = [1, 2, 3, 4]
126  call assert_equal([3], remove(l, 2, 2))
127  call assert_equal([1, 2, 4], l)
128
129  let l = [1, 2, 3, 4]
130  call assert_equal([2, 3], remove(l, 1, 2))
131  call assert_equal([1, 4], l)
132
133  let l = [1, 2, 3, 4]
134  call assert_equal([2, 3], remove(l, -3, -2))
135  call assert_equal([1, 4], l)
136
137  " Test invalid cases
138  let l = [1, 2, 3, 4]
139  call assert_fails("call remove(l, 5)", 'E684:')
140  call assert_fails("call remove(l, 1, 5)", 'E684:')
141  call assert_fails("call remove(l, 3, 2)", 'E16:')
142  call assert_fails("call remove(1, 0)", 'E896:')
143  call assert_fails("call remove(l, l)", 'E745:')
144endfunc
145
146" Tests for Dictionary type
147
148func Test_dict()
149  " Creating Dictionary directly with different types
150  let d = {001: 'asd', 'b': [1, 2, function('strlen')], -1: {'a': 1},}
151  call assert_equal("{'1': 'asd', 'b': [1, 2, function('strlen')], '-1': {'a': 1}}", string(d))
152  call assert_equal('asd', d.1)
153  call assert_equal(['-1', '1', 'b'], sort(keys(d)))
154  call assert_equal(['asd', [1, 2, function('strlen')], {'a': 1}], values(d))
155  let v = []
156  for [key, val] in items(d)
157    call extend(v, [key, val])
158    unlet key val
159  endfor
160  call assert_equal(['1','asd','b',[1, 2, function('strlen')],'-1',{'a': 1}], v)
161
162  call extend(d, {3:33, 1:99})
163  call extend(d, {'b':'bbb', 'c':'ccc'}, "keep")
164  call assert_fails("call extend(d, {3:333,4:444}, 'error')", 'E737')
165  call assert_equal({'c': 'ccc', '1': 99, 'b': [1, 2, function('strlen')], '3': 33, '-1': {'a': 1}}, d)
166  call filter(d, 'v:key =~ ''[ac391]''')
167  call assert_equal({'c': 'ccc', '1': 99, '3': 33, '-1': {'a': 1}}, d)
168endfunc
169
170" Dictionary identity
171func Test_dict_identity()
172  let d = {001: 'asd', 'b': [1, 2, function('strlen')], -1: {'a': 1},}
173  let dd = d
174  let dx = copy(d)
175  call assert_true(d == dd)
176  call assert_false(d isnot dd)
177  call assert_true(d is dd)
178  call assert_true(d == dx)
179  call assert_false(d is dx)
180  call assert_true(d isnot dx)
181endfunc
182
183" removing items with :unlet
184func Test_dict_unlet()
185  let d = {'b':'bbb', '1': 99, '3': 33, '-1': {'a': 1}}
186  unlet d.b
187  unlet d[-1]
188  call assert_equal({'1': 99, '3': 33}, d)
189endfunc
190
191" manipulating a big Dictionary (hashtable.c has a border of 1000 entries)
192func Test_dict_big()
193  let d = {}
194  for i in range(1500)
195    let d[i] = 3000 - i
196  endfor
197  call assert_equal([3000, 2900, 2001, 1600, 1501], [d[0], d[100], d[999], d[1400], d[1499]])
198  let str = ''
199  try
200    let n = d[1500]
201  catch
202    let str=substitute(v:exception, '\v(.{14}).*( \d{4}).*', '\1\2', '')
203  endtry
204  call assert_equal('Vim(let):E716: 1500', str)
205
206  " lookup each items
207  for i in range(1500)
208    call assert_equal(3000 - i, d[i])
209  endfor
210  let i += 1
211
212  " delete even items
213  while i >= 2
214    let i -= 2
215    unlet d[i]
216  endwhile
217  call assert_equal('NONE', get(d, 1500 - 100, 'NONE'))
218  call assert_equal(2999, d[1])
219
220  " delete odd items, checking value, one intentionally wrong
221  let d[33] = 999
222  let i = 1
223  while i < 1500
224   if i != 33
225     call assert_equal(3000 - i, d[i])
226   else
227     call assert_equal(999, d[i])
228   endif
229   unlet d[i]
230   let i += 2
231  endwhile
232  call assert_equal({}, d)
233  unlet d
234endfunc
235
236" Dictionary function
237func Test_dict_func()
238  let d = {}
239  func d.func(a) dict
240    return a:a . len(self.data)
241  endfunc
242  let d.data = [1,2,3]
243  call assert_equal('len: 3', d.func('len: '))
244  let x = d.func('again: ')
245  call assert_equal('again: 3', x)
246  let Fn = d.func
247  call assert_equal('xxx3', Fn('xxx'))
248endfunc
249
250" Function in script-local List or Dict
251func Test_script_local_dict_func()
252  let g:dict = {}
253  function g:dict.func() dict
254    return 'g:dict.func' . self.foo[1] . self.foo[0]('asdf')
255  endfunc
256  let g:dict.foo = ['-', 2, 3]
257  call insert(g:dict.foo, function('strlen'))
258  call assert_equal('g:dict.func-4', g:dict.func())
259  unlet g:dict
260endfunc
261
262" Test removing items in la dictionary
263func Test_dict_func_remove()
264  let d = {1:'a', 2:'b', 3:'c'}
265  call assert_equal('b', remove(d, 2))
266  call assert_equal({1:'a', 3:'c'}, d)
267
268  call assert_fails("call remove(d, 1, 2)", 'E118:')
269  call assert_fails("call remove(d, 'a')", 'E716:')
270  call assert_fails("call remove(d, [])", 'E730:')
271endfunc
272
273" Nasty: remove func from Dict that's being called (works)
274func Test_dict_func_remove_in_use()
275  let d = {1:1}
276  func d.func(a)
277    return "a:" . a:a
278  endfunc
279  let expected = 'a:' . string(get(d, 'func'))
280  call assert_equal(expected, d.func(string(remove(d, 'func'))))
281endfunc
282
283func Test_dict_literal_keys()
284  call assert_equal({'one': 1, 'two2': 2, '3three': 3, '44': 4}, #{one: 1, two2: 2, 3three: 3, 44: 4},)
285
286  " why *{} cannot be used
287  let blue = 'blue'
288  call assert_equal('6', trim(execute('echo 2 *{blue: 3}.blue')))
289endfunc
290
291" Nasty: deepcopy() dict that refers to itself (fails when noref used)
292func Test_dict_deepcopy()
293  let d = {1:1, 2:2}
294  let l = [4, d, 6]
295  let d[3] = l
296  let dc = deepcopy(d)
297  call assert_fails('call deepcopy(d, 1)', 'E698')
298  let l2 = [0, l, l, 3]
299  let l[1] = l2
300  let l3 = deepcopy(l2)
301  call assert_true(l3[1] is l3[2])
302endfunc
303
304" Locked variables
305func Test_list_locked_var()
306  let expected = [
307	      \ [['0000-000', 'ppppppp'],
308	      \  ['0000-000', 'ppppppp'],
309	      \  ['0000-000', 'ppppppp']],
310	      \ [['1000-000', 'ppppppF'],
311	      \  ['0000-000', 'ppppppp'],
312	      \  ['0000-000', 'ppppppp']],
313	      \ [['1100-100', 'ppFppFF'],
314	      \  ['0000-000', 'ppppppp'],
315	      \  ['0000-000', 'ppppppp']],
316	      \ [['1110-110', 'pFFpFFF'],
317	      \  ['0010-010', 'pFppFpp'],
318	      \  ['0000-000', 'ppppppp']],
319	      \ [['1111-111', 'FFFFFFF'],
320	      \  ['0011-011', 'FFpFFpp'],
321	      \  ['0000-000', 'ppppppp']]
322	      \ ]
323  for depth in range(5)
324    for u in range(3)
325      unlet! l
326      let l = [0, [1, [2, 3]], {4: 5, 6: {7: 8}}]
327      exe "lockvar " . depth . " l"
328      if u == 1
329        exe "unlockvar l"
330      elseif u == 2
331        exe "unlockvar " . depth . " l"
332      endif
333      let ps = islocked("l").islocked("l[1]").islocked("l[1][1]").islocked("l[1][1][0]").'-'.islocked("l[2]").islocked("l[2]['6']").islocked("l[2]['6'][7]")
334      call assert_equal(expected[depth][u][0], ps)
335      let ps = ''
336      try
337        let l[1][1][0] = 99
338        let ps .= 'p'
339      catch
340        let ps .= 'F'
341      endtry
342      try
343        let l[1][1] = [99]
344        let ps .= 'p'
345      catch
346        let ps .= 'F'
347      endtry
348      try
349        let l[1] = [99]
350        let ps .= 'p'
351      catch
352        let ps .= 'F'
353      endtry
354      try
355        let l[2]['6'][7] = 99
356        let ps .= 'p'
357      catch
358        let ps .= 'F'
359      endtry
360      try
361        let l[2][6] = {99: 99}
362        let ps .= 'p'
363      catch
364        let ps .= 'F'
365      endtry
366      try
367        let l[2] = {99: 99}
368        let ps .= 'p'
369      catch
370        let ps .= 'F'
371      endtry
372      try
373        let l = [99]
374        let ps .= 'p'
375      catch
376        let ps .= 'F'
377      endtry
378      call assert_equal(expected[depth][u][1], ps)
379    endfor
380  endfor
381endfunc
382
383" Unletting locked variables
384func Test_list_locked_var_unlet()
385  let expected = [
386	      \ [['0000-000', 'ppppppp'],
387	      \  ['0000-000', 'ppppppp'],
388	      \  ['0000-000', 'ppppppp']],
389	      \ [['1000-000', 'ppFppFp'],
390	      \  ['0000-000', 'ppppppp'],
391	      \  ['0000-000', 'ppppppp']],
392	      \ [['1100-100', 'pFFpFFp'],
393	      \  ['0000-000', 'ppppppp'],
394	      \  ['0000-000', 'ppppppp']],
395	      \ [['1110-110', 'FFFFFFp'],
396	      \  ['0010-010', 'FppFppp'],
397	      \  ['0000-000', 'ppppppp']],
398	      \ [['1111-111', 'FFFFFFp'],
399	      \  ['0011-011', 'FppFppp'],
400	      \  ['0000-000', 'ppppppp']]
401	      \ ]
402
403  for depth in range(5)
404    for u in range(3)
405      unlet! l
406      let l = [0, [1, [2, 3]], {4: 5, 6: {7: 8}}]
407      exe "lockvar " . depth . " l"
408      if u == 1
409        exe "unlockvar l"
410      elseif u == 2
411        exe "unlockvar " . depth . " l"
412      endif
413      let ps = islocked("l").islocked("l[1]").islocked("l[1][1]").islocked("l[1][1][0]").'-'.islocked("l[2]").islocked("l[2]['6']").islocked("l[2]['6'][7]")
414      call assert_equal(expected[depth][u][0], ps)
415      let ps = ''
416      try
417        unlet l[2]['6'][7]
418        let ps .= 'p'
419      catch
420        let ps .= 'F'
421      endtry
422      try
423        unlet l[2][6]
424        let ps .= 'p'
425      catch
426        let ps .= 'F'
427      endtry
428      try
429        unlet l[2]
430        let ps .= 'p'
431      catch
432        let ps .= 'F'
433      endtry
434      try
435        unlet l[1][1][0]
436        let ps .= 'p'
437      catch
438        let ps .= 'F'
439      endtry
440      try
441        unlet l[1][1]
442        let ps .= 'p'
443      catch
444        let ps .= 'F'
445      endtry
446      try
447        unlet l[1]
448        let ps .= 'p'
449      catch
450        let ps .= 'F'
451      endtry
452      try
453        unlet l
454        let ps .= 'p'
455      catch
456        let ps .= 'F'
457      endtry
458      call assert_equal(expected[depth][u][1], ps)
459    endfor
460  endfor
461endfunc
462
463" Locked variables and :unlet or list / dict functions
464
465" No :unlet after lock on dict:
466func Test_dict_lock_unlet()
467  unlet! d
468  let d = {'a': 99, 'b': 100}
469  lockvar 1 d
470  call assert_fails('unlet d.a', 'E741')
471endfunc
472
473" unlet after lock on dict item
474func Test_dict_item_lock_unlet()
475  unlet! d
476  let d = {'a': 99, 'b': 100}
477  lockvar d.a
478  unlet d.a
479  call assert_equal({'b' : 100}, d)
480endfunc
481
482" filter() after lock on dict item
483func Test_dict_lock_filter()
484  unlet! d
485  let d = {'a': 99, 'b': 100}
486  lockvar d.a
487  call filter(d, 'v:key != "a"')
488  call assert_equal({'b' : 100}, d)
489endfunc
490
491" map() after lock on dict
492func Test_dict_lock_map()
493  unlet! d
494  let d = {'a': 99, 'b': 100}
495  lockvar 1 d
496  call map(d, 'v:val + 200')
497  call assert_equal({'a' : 299, 'b' : 300}, d)
498endfunc
499
500" No extend() after lock on dict item
501func Test_dict_lock_extend()
502  unlet! d
503  let d = {'a': 99, 'b': 100}
504  lockvar d.a
505  call assert_fails("call extend(d, {'a' : 123})", 'E741')
506  call assert_equal({'a': 99, 'b': 100}, d)
507endfunc
508
509" No remove() of write-protected scope-level variable
510func Tfunc1(this_is_a_long_parameter_name)
511  call assert_fails("call remove(a:, 'this_is_a_long_parameter_name')", 'E742')
512endfunc
513func Test_dict_scope_var_remove()
514  call Tfunc1('testval')
515endfunc
516
517" No extend() of write-protected scope-level variable
518func Test_dict_scope_var_extend()
519  call assert_fails("call extend(a:, {'this_is_a_long_parameter_name': 1234})", 'E742')
520endfunc
521
522func Tfunc2(this_is_a_long_parameter_name)
523  call assert_fails("call extend(a:, {'this_is_a_long_parameter_name': 1234})", 'E742')
524endfunc
525func Test_dict_scope_var_extend_overwrite()
526  call Tfunc2('testval')
527endfunc
528
529" No :unlet of variable in locked scope
530func Test_lock_var_unlet()
531  let b:testvar = 123
532  lockvar 1 b:
533  call assert_fails('unlet b:testvar', 'E741:')
534  unlockvar 1 b:
535  unlet! b:testvar
536endfunc
537
538" No :let += of locked list variable
539func Test_let_lock_list()
540  let l = ['a', 'b', 3]
541  lockvar 1 l
542  call assert_fails("let l += ['x']", 'E741:')
543  call assert_equal(['a', 'b', 3], l)
544
545  unlet l
546  let l = [1, 2, 3, 4]
547  lockvar! l
548  call assert_equal([1, 2, 3, 4], l)
549  unlockvar l[1]
550  call assert_fails('unlet l[0:1]', 'E741:')
551  call assert_equal([1, 2, 3, 4], l)
552  call assert_fails('unlet l[1:2]', 'E741:')
553  call assert_equal([1, 2, 3, 4], l)
554  unlockvar l[1]
555  call assert_fails('let l[0:1] = [0, 1]', 'E741:')
556  call assert_equal([1, 2, 3, 4], l)
557  call assert_fails('let l[1:2] = [0, 1]', 'E741:')
558  call assert_equal([1, 2, 3, 4], l)
559  unlet l
560endfunc
561
562" lockvar/islocked() triggering script autoloading
563func Test_lockvar_script_autoload()
564  let old_rtp = &rtp
565  set rtp+=./sautest
566  lockvar g:footest#x
567  unlockvar g:footest#x
568  call assert_equal(-1, islocked('g:footest#x'))
569  call assert_equal(0, exists('g:footest#x'))
570  call assert_equal(1, g:footest#x)
571  let &rtp = old_rtp
572endfunc
573
574" a:000 function argument test
575func s:arg_list_test(...)
576  call assert_fails('let a:000 = [1, 2]', 'E46:')
577  call assert_fails('let a:000[0] = 9', 'E742:')
578  call assert_fails('let a:000[2] = [9, 10]', 'E742:')
579  call assert_fails('let a:000[3] = {9 : 10}', 'E742:')
580
581  " now the tests that should pass
582  let a:000[2][1] = 9
583  call extend(a:000[2], [5, 6])
584  let a:000[3][5] = 8
585  let a:000[3]['a'] = 12
586  call assert_equal([1, 2, [3, 9, 5, 6], {'a': 12, '5': 8}], a:000)
587endfunc
588
589func Test_func_arg_list()
590  call s:arg_list_test(1, 2, [3, 4], {5: 6})
591endfunc
592
593" Tests for reverse(), sort(), uniq()
594func Test_reverse_sort_uniq()
595  let l = ['-0', 'A11', 2, 2, 'xaaa', 4, 'foo', 'foo6', 'foo', [0, 1, 2], 'x8', [0, 1, 2], 1.5]
596  call assert_equal(['-0', 'A11', 2, 'xaaa', 4, 'foo', 'foo6', 'foo', [0, 1, 2], 'x8', [0, 1, 2], 1.5], uniq(copy(l)))
597  call assert_equal([1.5, [0, 1, 2], 'x8', [0, 1, 2], 'foo', 'foo6', 'foo', 4, 'xaaa', 2, 2, 'A11', '-0'], reverse(l))
598  call assert_equal([1.5, [0, 1, 2], 'x8', [0, 1, 2], 'foo', 'foo6', 'foo', 4, 'xaaa', 2, 2, 'A11', '-0'], reverse(reverse(l)))
599  call assert_equal(['-0', 'A11', 'foo', 'foo', 'foo6', 'x8', 'xaaa', 1.5, 2, 2, 4, [0, 1, 2], [0, 1, 2]], sort(l))
600  call assert_equal([[0, 1, 2], [0, 1, 2], 4, 2, 2, 1.5, 'xaaa', 'x8', 'foo6', 'foo', 'foo', 'A11', '-0'], reverse(sort(l)))
601  call assert_equal(['-0', 'A11', 'foo', 'foo', 'foo6', 'x8', 'xaaa', 1.5, 2, 2, 4, [0, 1, 2], [0, 1, 2]], sort(reverse(sort(l))))
602  call assert_equal(['-0', 'A11', 'foo', 'foo6', 'x8', 'xaaa', 1.5, 2, 4, [0, 1, 2]], uniq(sort(l)))
603
604  let l=[7, 9, 'one', 18, 12, 22, 'two', 10.0e-16, -1, 'three', 0xff, 0.22, 'four']
605  call assert_equal([-1, 'one', 'two', 'three', 'four', 1.0e-15, 0.22, 7, 9, 12, 18, 22, 255], sort(copy(l), 'n'))
606
607  let l=[7, 9, 18, 12, 22, 10.0e-16, -1, 0xff, 0, -0, 0.22, 'bar', 'BAR', 'Bar', 'Foo', 'FOO', 'foo', 'FOOBAR', {}, []]
608  call assert_equal(['bar', 'BAR', 'Bar', 'Foo', 'FOO', 'foo', 'FOOBAR', -1, 0, 0, 0.22, 1.0e-15, 12, 18, 22, 255, 7, 9, [], {}], sort(copy(l), 1))
609  call assert_equal(['bar', 'BAR', 'Bar', 'Foo', 'FOO', 'foo', 'FOOBAR', -1, 0, 0, 0.22, 1.0e-15, 12, 18, 22, 255, 7, 9, [], {}], sort(copy(l), 'i'))
610  call assert_equal(['BAR', 'Bar', 'FOO', 'FOOBAR', 'Foo', 'bar', 'foo', -1, 0, 0, 0.22, 1.0e-15, 12, 18, 22, 255, 7, 9, [], {}], sort(copy(l)))
611
612  call assert_fails('call reverse("")', 'E899:')
613endfunc
614
615" splitting a string to a List
616func Test_str_split()
617  call assert_equal(['aa', 'bb'], split('  aa  bb '))
618  call assert_equal(['aa', 'bb'], split('  aa  bb  ', '\W\+', 0))
619  call assert_equal(['', 'aa', 'bb', ''], split('  aa  bb  ', '\W\+', 1))
620  call assert_equal(['', '', 'aa', '', 'bb', '', ''], split('  aa  bb  ', '\W', 1))
621  call assert_equal(['aa', '', 'bb'], split(':aa::bb:', ':', 0))
622  call assert_equal(['', 'aa', '', 'bb', ''], split(':aa::bb:', ':', 1))
623  call assert_equal(['aa', '', 'bb', 'cc', ''], split('aa,,bb, cc,', ',\s*', 1))
624  call assert_equal(['a', 'b', 'c'], split('abc', '\zs'))
625  call assert_equal(['', 'a', '', 'b', '', 'c', ''], split('abc', '\zs', 1))
626endfunc
627
628" compare recursively linked list and dict
629func Test_listdict_compare()
630  let l = [1, 2, 3, 4]
631  let d = {'1': 1, '2': l, '3': 3}
632  let l[1] = d
633  call assert_true(l == l)
634  call assert_true(d == d)
635  call assert_false(l != deepcopy(l))
636  call assert_false(d != deepcopy(d))
637endfunc
638
639  " compare complex recursively linked list and dict
640func Test_listdict_compare_complex()
641  let l = []
642  call add(l, l)
643  let dict4 = {"l": l}
644  call add(dict4.l, dict4)
645  let lcopy = deepcopy(l)
646  let dict4copy = deepcopy(dict4)
647  call assert_true(l == lcopy)
648  call assert_true(dict4 == dict4copy)
649endfunc
650
651func Test_listdict_extend()
652  " Test extend() with lists
653
654  " Pass the same List to extend()
655  let l = [1, 2, 3]
656  call assert_equal([1, 2, 3, 1, 2, 3], extend(l, l))
657  call assert_equal([1, 2, 3, 1, 2, 3], l)
658
659  let l = [1, 2, 3]
660  call assert_equal([1, 2, 3, 4, 5, 6], extend(l, [4, 5, 6]))
661  call assert_equal([1, 2, 3, 4, 5, 6], l)
662
663  let l = [1, 2, 3]
664  call extend(l, [4, 5, 6], 0)
665  call assert_equal([4, 5, 6, 1, 2, 3], l)
666
667  let l = [1, 2, 3]
668  call extend(l, [4, 5, 6], 1)
669  call assert_equal([1, 4, 5, 6, 2, 3], l)
670
671  let l = [1, 2, 3]
672  call extend(l, [4, 5, 6], 3)
673  call assert_equal([1, 2, 3, 4, 5, 6], l)
674
675  let l = [1, 2, 3]
676  call extend(l, [4, 5, 6], -1)
677  call assert_equal([1, 2, 4, 5, 6, 3], l)
678
679  let l = [1, 2, 3]
680  call extend(l, [4, 5, 6], -3)
681  call assert_equal([4, 5, 6, 1, 2,  3], l)
682
683  let l = [1, 2, 3]
684  call assert_fails("call extend(l, [4, 5, 6], 4)", 'E684:')
685  call assert_fails("call extend(l, [4, 5, 6], -4)", 'E684:')
686  call assert_fails("call extend(l, [4, 5, 6], 1.2)", 'E805:')
687
688  " Test extend() with dictionaries.
689
690  " Pass the same Dict to extend()
691  let d = { 'a': {'b': 'B'}}
692  call extend(d, d)
693  call assert_equal({'a': {'b': 'B'}}, d)
694
695  let d = {'a': 'A', 'b': 'B'}
696  call assert_equal({'a': 'A', 'b': 0, 'c': 'C'}, extend(d, {'b': 0, 'c':'C'}))
697  call assert_equal({'a': 'A', 'b': 0, 'c': 'C'}, d)
698
699  let d = {'a': 'A', 'b': 'B'}
700  call extend(d, {'a': 'A', 'b': 0, 'c': 'C'}, "force")
701  call assert_equal({'a': 'A', 'b': 0, 'c': 'C'}, d)
702
703  let d = {'a': 'A', 'b': 'B'}
704  call extend(d, {'b': 0, 'c':'C'}, "keep")
705  call assert_equal({'a': 'A', 'b': 'B', 'c': 'C'}, d)
706
707  let d = {'a': 'A', 'b': 'B'}
708  call assert_fails("call extend(d, {'b': 0, 'c':'C'}, 'error')", 'E737:')
709  call assert_fails("call extend(d, {'b': 0, 'c':'C'}, 'xxx')", 'E475:')
710  call assert_fails("call extend(d, {'b': 0, 'c':'C'}, 1.2)", 'E806:')
711  call assert_equal({'a': 'A', 'b': 'B'}, d)
712
713  call assert_fails("call extend([1, 2], 1)", 'E712:')
714  call assert_fails("call extend([1, 2], {})", 'E712:')
715endfunc
716
717func s:check_scope_dict(x, fixed)
718  func s:gen_cmd(cmd, x)
719    return substitute(a:cmd, '\<x\ze:', a:x, 'g')
720  endfunc
721
722  let cmd = s:gen_cmd('let x:foo = 1', a:x)
723  if a:fixed
724    call assert_fails(cmd, 'E461')
725  else
726    exe cmd
727    exe s:gen_cmd('call assert_equal(1, x:foo)', a:x)
728  endif
729
730  let cmd = s:gen_cmd('let x:["bar"] = 2', a:x)
731  if a:fixed
732    call assert_fails(cmd, 'E461')
733  else
734    exe cmd
735    exe s:gen_cmd('call assert_equal(2, x:bar)', a:x)
736  endif
737
738  let cmd = s:gen_cmd('call extend(x:, {"baz": 3})', a:x)
739  if a:fixed
740    call assert_fails(cmd, 'E742')
741  else
742    exe cmd
743    exe s:gen_cmd('call assert_equal(3, x:baz)', a:x)
744  endif
745
746  if a:fixed
747    if a:x ==# 'a'
748      call assert_fails('unlet a:x', 'E795')
749      call assert_fails('call remove(a:, "x")', 'E742')
750    elseif a:x ==# 'v'
751      call assert_fails('unlet v:count', 'E795')
752      call assert_fails('call remove(v:, "count")', 'E742')
753    endif
754  else
755    exe s:gen_cmd('unlet x:foo', a:x)
756    exe s:gen_cmd('unlet x:bar', a:x)
757    exe s:gen_cmd('call remove(x:, "baz")', a:x)
758  endif
759
760  delfunc s:gen_cmd
761endfunc
762
763func Test_scope_dict()
764  " Test for g:
765  call s:check_scope_dict('g', v:false)
766
767  " Test for s:
768  call s:check_scope_dict('s', v:false)
769
770  " Test for l:
771  call s:check_scope_dict('l', v:false)
772
773  " Test for a:
774  call s:check_scope_dict('a', v:true)
775
776  " Test for b:
777  call s:check_scope_dict('b', v:false)
778
779  " Test for w:
780  call s:check_scope_dict('w', v:false)
781
782  " Test for t:
783  call s:check_scope_dict('t', v:false)
784
785  " Test for v:
786  call s:check_scope_dict('v', v:true)
787endfunc
788