1" Tests for the List and Dict types
2
3func TearDown()
4  " Run garbage collection after every test
5  call test_garbagecollect_now()
6endfunc
7
8" Tests for List type
9
10" List creation
11func Test_list_create()
12  " Creating List directly with different types
13  let l = [1, 'as''d', [1, 2, function("strlen")], {'a': 1},]
14  call assert_equal("[1, 'as''d', [1, 2, function('strlen')], {'a': 1}]", string(l))
15  call assert_equal({'a' : 1}, l[-1])
16  call assert_equal(1, l[-4])
17  let x = 10
18  try
19    let x = l[-5]
20  catch
21    call assert_match('E684:', v:exception)
22  endtry
23  call assert_equal(10, x)
24endfunc
25
26" List slices
27func Test_list_slice()
28  let l = [1, 'as''d', [1, 2, function("strlen")], {'a': 1},]
29  call assert_equal([1, 'as''d', [1, 2, function('strlen')], {'a': 1}], l[:])
30  call assert_equal(['as''d', [1, 2, function('strlen')], {'a': 1}], l[1:])
31  call assert_equal([1, 'as''d', [1, 2, function('strlen')]], l[:-2])
32  call assert_equal([1, 'as''d', [1, 2, function('strlen')], {'a': 1}], l[0:8])
33  call assert_equal([], l[8:-1])
34endfunc
35
36" List identity
37func Test_list_identity()
38  let l = [1, 'as''d', [1, 2, function("strlen")], {'a': 1},]
39  let ll = l
40  let lx = copy(l)
41  call assert_true(l == ll)
42  call assert_false(l isnot ll)
43  call assert_true(l is ll)
44  call assert_true(l == lx)
45  call assert_false(l is lx)
46  call assert_true(l isnot lx)
47endfunc
48
49" removing items with :unlet
50func Test_list_unlet()
51  let l = [1, 'as''d', [1, 2, function("strlen")], {'a': 1},]
52  unlet l[2]
53  call assert_equal([1, 'as''d', {'a': 1}], l)
54  let l = range(8)
55  unlet l[:3]
56  unlet l[1:]
57  call assert_equal([4], l)
58
59  " removing items out of range: silently skip items that don't exist
60  let l = [0, 1, 2, 3]
61  call assert_fails('unlet l[2:1]', 'E684')
62  let l = [0, 1, 2, 3]
63  unlet l[2:2]
64  call assert_equal([0, 1, 3], l)
65  let l = [0, 1, 2, 3]
66  unlet l[2:3]
67  call assert_equal([0, 1], l)
68  let l = [0, 1, 2, 3]
69  unlet l[2:4]
70  call assert_equal([0, 1], l)
71  let l = [0, 1, 2, 3]
72  unlet l[2:5]
73  call assert_equal([0, 1], l)
74  let l = [0, 1, 2, 3]
75  call assert_fails('unlet l[-1:2]', 'E684')
76  let l = [0, 1, 2, 3]
77  unlet l[-2:2]
78  call assert_equal([0, 1, 3], l)
79  let l = [0, 1, 2, 3]
80  unlet l[-3:2]
81  call assert_equal([0, 3], l)
82  let l = [0, 1, 2, 3]
83  unlet l[-4:2]
84  call assert_equal([3], l)
85  let l = [0, 1, 2, 3]
86  unlet l[-5:2]
87  call assert_equal([3], l)
88  let l = [0, 1, 2, 3]
89  unlet l[-6:2]
90  call assert_equal([3], l)
91endfunc
92
93" assignment to a list
94func Test_list_assign()
95  let l = [0, 1, 2, 3]
96  let [va, vb] = l[2:3]
97  call assert_equal([2, 3], [va, vb])
98  call assert_fails('let [va, vb] = l', 'E687')
99  call assert_fails('let [va, vb] = l[1:1]', 'E688')
100endfunc
101
102" test for range assign
103func Test_list_range_assign()
104  let l = [0]
105  let l[:] = [1, 2]
106  call assert_equal([1, 2], l)
107endfunc
108
109" Test removing items in list
110func Test_list_func_remove()
111  " Test removing 1 element
112  let l = [1, 2, 3, 4]
113  call assert_equal(1, remove(l, 0))
114  call assert_equal([2, 3, 4], l)
115
116  let l = [1, 2, 3, 4]
117  call assert_equal(2, remove(l, 1))
118  call assert_equal([1, 3, 4], l)
119
120  let l = [1, 2, 3, 4]
121  call assert_equal(4, remove(l, -1))
122  call assert_equal([1, 2, 3], l)
123
124  " Test removing range of element(s)
125  let l = [1, 2, 3, 4]
126  call assert_equal([3], remove(l, 2, 2))
127  call assert_equal([1, 2, 4], l)
128
129  let l = [1, 2, 3, 4]
130  call assert_equal([2, 3], remove(l, 1, 2))
131  call assert_equal([1, 4], l)
132
133  let l = [1, 2, 3, 4]
134  call assert_equal([2, 3], remove(l, -3, -2))
135  call assert_equal([1, 4], l)
136
137  " Test invalid cases
138  let l = [1, 2, 3, 4]
139  call assert_fails("call remove(l, 5)", 'E684:')
140  call assert_fails("call remove(l, 1, 5)", 'E684:')
141  call assert_fails("call remove(l, 3, 2)", 'E16:')
142  call assert_fails("call remove(1, 0)", 'E896:')
143  call assert_fails("call remove(l, l)", 'E745:')
144endfunc
145
146" Tests for Dictionary type
147
148func Test_dict()
149  " Creating Dictionary directly with different types
150  let d = {001: 'asd', 'b': [1, 2, function('strlen')], -1: {'a': 1},}
151  call assert_equal("{'1': 'asd', 'b': [1, 2, function('strlen')], '-1': {'a': 1}}", string(d))
152  call assert_equal('asd', d.1)
153  call assert_equal(['-1', '1', 'b'], sort(keys(d)))
154  call assert_equal(['asd', [1, 2, function('strlen')], {'a': 1}], values(d))
155  let v = []
156  for [key, val] in items(d)
157    call extend(v, [key, val])
158    unlet key val
159  endfor
160  call assert_equal(['1','asd','b',[1, 2, function('strlen')],'-1',{'a': 1}], v)
161
162  call extend(d, {3:33, 1:99})
163  call extend(d, {'b':'bbb', 'c':'ccc'}, "keep")
164  call assert_fails("call extend(d, {3:333,4:444}, 'error')", 'E737')
165  call assert_equal({'c': 'ccc', '1': 99, 'b': [1, 2, function('strlen')], '3': 33, '-1': {'a': 1}}, d)
166  call filter(d, 'v:key =~ ''[ac391]''')
167  call assert_equal({'c': 'ccc', '1': 99, '3': 33, '-1': {'a': 1}}, d)
168endfunc
169
170" Dictionary identity
171func Test_dict_identity()
172  let d = {001: 'asd', 'b': [1, 2, function('strlen')], -1: {'a': 1},}
173  let dd = d
174  let dx = copy(d)
175  call assert_true(d == dd)
176  call assert_false(d isnot dd)
177  call assert_true(d is dd)
178  call assert_true(d == dx)
179  call assert_false(d is dx)
180  call assert_true(d isnot dx)
181endfunc
182
183" removing items with :unlet
184func Test_dict_unlet()
185  let d = {'b':'bbb', '1': 99, '3': 33, '-1': {'a': 1}}
186  unlet d.b
187  unlet d[-1]
188  call assert_equal({'1': 99, '3': 33}, d)
189endfunc
190
191" manipulating a big Dictionary (hashtable.c has a border of 1000 entries)
192func Test_dict_big()
193  let d = {}
194  for i in range(1500)
195    let d[i] = 3000 - i
196  endfor
197  call assert_equal([3000, 2900, 2001, 1600, 1501], [d[0], d[100], d[999], d[1400], d[1499]])
198  let str = ''
199  try
200    let n = d[1500]
201  catch
202    let str=substitute(v:exception, '\v(.{14}).*( \d{4}).*', '\1\2', '')
203  endtry
204  call assert_equal('Vim(let):E716: 1500', str)
205
206  " lookup each items
207  for i in range(1500)
208    call assert_equal(3000 - i, d[i])
209  endfor
210  let i += 1
211
212  " delete even items
213  while i >= 2
214    let i -= 2
215    unlet d[i]
216  endwhile
217  call assert_equal('NONE', get(d, 1500 - 100, 'NONE'))
218  call assert_equal(2999, d[1])
219
220  " delete odd items, checking value, one intentionally wrong
221  let d[33] = 999
222  let i = 1
223  while i < 1500
224   if i != 33
225     call assert_equal(3000 - i, d[i])
226   else
227     call assert_equal(999, d[i])
228   endif
229   unlet d[i]
230   let i += 2
231  endwhile
232  call assert_equal({}, d)
233  unlet d
234endfunc
235
236" Dictionary function
237func Test_dict_func()
238  let d = {}
239  func d.func(a) dict
240    return a:a . len(self.data)
241  endfunc
242  let d.data = [1,2,3]
243  call assert_equal('len: 3', d.func('len: '))
244  let x = d.func('again: ')
245  call assert_equal('again: 3', x)
246  let Fn = d.func
247  call assert_equal('xxx3', Fn('xxx'))
248endfunc
249
250" Function in script-local List or Dict
251func Test_script_local_dict_func()
252  let g:dict = {}
253  function g:dict.func() dict
254    return 'g:dict.func' . self.foo[1] . self.foo[0]('asdf')
255  endfunc
256  let g:dict.foo = ['-', 2, 3]
257  call insert(g:dict.foo, function('strlen'))
258  call assert_equal('g:dict.func-4', g:dict.func())
259  unlet g:dict
260endfunc
261
262" Test removing items in la dictionary
263func Test_dict_func_remove()
264  let d = {1:'a', 2:'b', 3:'c'}
265  call assert_equal('b', remove(d, 2))
266  call assert_equal({1:'a', 3:'c'}, d)
267
268  call assert_fails("call remove(d, 1, 2)", 'E118:')
269  call assert_fails("call remove(d, 'a')", 'E716:')
270  call assert_fails("call remove(d, [])", 'E730:')
271endfunc
272
273" Nasty: remove func from Dict that's being called (works)
274func Test_dict_func_remove_in_use()
275  let d = {1:1}
276  func d.func(a)
277    return "a:" . a:a
278  endfunc
279  let expected = 'a:' . string(get(d, 'func'))
280  call assert_equal(expected, d.func(string(remove(d, 'func'))))
281endfunc
282
283" Nasty: deepcopy() dict that refers to itself (fails when noref used)
284func Test_dict_deepcopy()
285  let d = {1:1, 2:2}
286  let l = [4, d, 6]
287  let d[3] = l
288  let dc = deepcopy(d)
289  call assert_fails('call deepcopy(d, 1)', 'E698')
290  let l2 = [0, l, l, 3]
291  let l[1] = l2
292  let l3 = deepcopy(l2)
293  call assert_true(l3[1] is l3[2])
294endfunc
295
296" Locked variables
297func Test_list_locked_var()
298  let expected = [
299	      \ [['0000-000', 'ppppppp'],
300	      \  ['0000-000', 'ppppppp'],
301	      \  ['0000-000', 'ppppppp']],
302	      \ [['1000-000', 'ppppppF'],
303	      \  ['0000-000', 'ppppppp'],
304	      \  ['0000-000', 'ppppppp']],
305	      \ [['1100-100', 'ppFppFF'],
306	      \  ['0000-000', 'ppppppp'],
307	      \  ['0000-000', 'ppppppp']],
308	      \ [['1110-110', 'pFFpFFF'],
309	      \  ['0010-010', 'pFppFpp'],
310	      \  ['0000-000', 'ppppppp']],
311	      \ [['1111-111', 'FFFFFFF'],
312	      \  ['0011-011', 'FFpFFpp'],
313	      \  ['0000-000', 'ppppppp']]
314	      \ ]
315  for depth in range(5)
316    for u in range(3)
317      unlet! l
318      let l = [0, [1, [2, 3]], {4: 5, 6: {7: 8}}]
319      exe "lockvar " . depth . " l"
320      if u == 1
321        exe "unlockvar l"
322      elseif u == 2
323        exe "unlockvar " . depth . " l"
324      endif
325      let ps = islocked("l").islocked("l[1]").islocked("l[1][1]").islocked("l[1][1][0]").'-'.islocked("l[2]").islocked("l[2]['6']").islocked("l[2]['6'][7]")
326      call assert_equal(expected[depth][u][0], ps)
327      let ps = ''
328      try
329        let l[1][1][0] = 99
330        let ps .= 'p'
331      catch
332        let ps .= 'F'
333      endtry
334      try
335        let l[1][1] = [99]
336        let ps .= 'p'
337      catch
338        let ps .= 'F'
339      endtry
340      try
341        let l[1] = [99]
342        let ps .= 'p'
343      catch
344        let ps .= 'F'
345      endtry
346      try
347        let l[2]['6'][7] = 99
348        let ps .= 'p'
349      catch
350        let ps .= 'F'
351      endtry
352      try
353        let l[2][6] = {99: 99}
354        let ps .= 'p'
355      catch
356        let ps .= 'F'
357      endtry
358      try
359        let l[2] = {99: 99}
360        let ps .= 'p'
361      catch
362        let ps .= 'F'
363      endtry
364      try
365        let l = [99]
366        let ps .= 'p'
367      catch
368        let ps .= 'F'
369      endtry
370      call assert_equal(expected[depth][u][1], ps)
371    endfor
372  endfor
373endfunc
374
375" Unletting locked variables
376func Test_list_locked_var_unlet()
377  let expected = [
378	      \ [['0000-000', 'ppppppp'],
379	      \  ['0000-000', 'ppppppp'],
380	      \  ['0000-000', 'ppppppp']],
381	      \ [['1000-000', 'ppFppFp'],
382	      \  ['0000-000', 'ppppppp'],
383	      \  ['0000-000', 'ppppppp']],
384	      \ [['1100-100', 'pFFpFFp'],
385	      \  ['0000-000', 'ppppppp'],
386	      \  ['0000-000', 'ppppppp']],
387	      \ [['1110-110', 'FFFFFFp'],
388	      \  ['0010-010', 'FppFppp'],
389	      \  ['0000-000', 'ppppppp']],
390	      \ [['1111-111', 'FFFFFFp'],
391	      \  ['0011-011', 'FppFppp'],
392	      \  ['0000-000', 'ppppppp']]
393	      \ ]
394
395  for depth in range(5)
396    for u in range(3)
397      unlet! l
398      let l = [0, [1, [2, 3]], {4: 5, 6: {7: 8}}]
399      exe "lockvar " . depth . " l"
400      if u == 1
401        exe "unlockvar l"
402      elseif u == 2
403        exe "unlockvar " . depth . " l"
404      endif
405      let ps = islocked("l").islocked("l[1]").islocked("l[1][1]").islocked("l[1][1][0]").'-'.islocked("l[2]").islocked("l[2]['6']").islocked("l[2]['6'][7]")
406      call assert_equal(expected[depth][u][0], ps)
407      let ps = ''
408      try
409        unlet l[2]['6'][7]
410        let ps .= 'p'
411      catch
412        let ps .= 'F'
413      endtry
414      try
415        unlet l[2][6]
416        let ps .= 'p'
417      catch
418        let ps .= 'F'
419      endtry
420      try
421        unlet l[2]
422        let ps .= 'p'
423      catch
424        let ps .= 'F'
425      endtry
426      try
427        unlet l[1][1][0]
428        let ps .= 'p'
429      catch
430        let ps .= 'F'
431      endtry
432      try
433        unlet l[1][1]
434        let ps .= 'p'
435      catch
436        let ps .= 'F'
437      endtry
438      try
439        unlet l[1]
440        let ps .= 'p'
441      catch
442        let ps .= 'F'
443      endtry
444      try
445        unlet l
446        let ps .= 'p'
447      catch
448        let ps .= 'F'
449      endtry
450      call assert_equal(expected[depth][u][1], ps)
451    endfor
452  endfor
453endfunc
454
455" Locked variables and :unlet or list / dict functions
456
457" No :unlet after lock on dict:
458func Test_dict_lock_unlet()
459  unlet! d
460  let d = {'a': 99, 'b': 100}
461  lockvar 1 d
462  call assert_fails('unlet d.a', 'E741')
463endfunc
464
465" unlet after lock on dict item
466func Test_dict_item_lock_unlet()
467  unlet! d
468  let d = {'a': 99, 'b': 100}
469  lockvar d.a
470  unlet d.a
471  call assert_equal({'b' : 100}, d)
472endfunc
473
474" filter() after lock on dict item
475func Test_dict_lock_filter()
476  unlet! d
477  let d = {'a': 99, 'b': 100}
478  lockvar d.a
479  call filter(d, 'v:key != "a"')
480  call assert_equal({'b' : 100}, d)
481endfunc
482
483" map() after lock on dict
484func Test_dict_lock_map()
485  unlet! d
486  let d = {'a': 99, 'b': 100}
487  lockvar 1 d
488  call map(d, 'v:val + 200')
489  call assert_equal({'a' : 299, 'b' : 300}, d)
490endfunc
491
492" No extend() after lock on dict item
493func Test_dict_lock_extend()
494  unlet! d
495  let d = {'a': 99, 'b': 100}
496  lockvar d.a
497  call assert_fails("call extend(d, {'a' : 123})", 'E741')
498  call assert_equal({'a': 99, 'b': 100}, d)
499endfunc
500
501" No remove() of write-protected scope-level variable
502func Tfunc1(this_is_a_long_parameter_name)
503  call assert_fails("call remove(a:, 'this_is_a_long_parameter_name')", 'E742')
504endfunc
505func Test_dict_scope_var_remove()
506  call Tfunc1('testval')
507endfunc
508
509" No extend() of write-protected scope-level variable
510func Test_dict_scope_var_extend()
511  call assert_fails("call extend(a:, {'this_is_a_long_parameter_name': 1234})", 'E742')
512endfunc
513
514func Tfunc2(this_is_a_long_parameter_name)
515  call assert_fails("call extend(a:, {'this_is_a_long_parameter_name': 1234})", 'E742')
516endfunc
517func Test_dict_scope_var_extend_overwrite()
518  call Tfunc2('testval')
519endfunc
520
521" No :unlet of variable in locked scope
522func Test_lock_var_unlet()
523  let b:testvar = 123
524  lockvar 1 b:
525  call assert_fails('unlet b:testvar', 'E741:')
526  unlockvar 1 b:
527  unlet! b:testvar
528endfunc
529
530" No :let += of locked list variable
531func Test_let_lock_list()
532  let l = ['a', 'b', 3]
533  lockvar 1 l
534  call assert_fails("let l += ['x']", 'E741:')
535  call assert_equal(['a', 'b', 3], l)
536
537  unlet l
538  let l = [1, 2, 3, 4]
539  lockvar! l
540  call assert_equal([1, 2, 3, 4], l)
541  unlockvar l[1]
542  call assert_fails('unlet l[0:1]', 'E741:')
543  call assert_equal([1, 2, 3, 4], l)
544  call assert_fails('unlet l[1:2]', 'E741:')
545  call assert_equal([1, 2, 3, 4], l)
546  unlockvar l[1]
547  call assert_fails('let l[0:1] = [0, 1]', 'E741:')
548  call assert_equal([1, 2, 3, 4], l)
549  call assert_fails('let l[1:2] = [0, 1]', 'E741:')
550  call assert_equal([1, 2, 3, 4], l)
551  unlet l
552endfunc
553
554" lockvar/islocked() triggering script autoloading
555func Test_lockvar_script_autoload()
556  let old_rtp = &rtp
557  set rtp+=./sautest
558  lockvar g:footest#x
559  unlockvar g:footest#x
560  call assert_equal(-1, islocked('g:footest#x'))
561  call assert_equal(0, exists('g:footest#x'))
562  call assert_equal(1, g:footest#x)
563  let &rtp = old_rtp
564endfunc
565
566" a:000 function argument test
567func s:arg_list_test(...)
568  call assert_fails('let a:000 = [1, 2]', 'E46:')
569  call assert_fails('let a:000[0] = 9', 'E742:')
570  call assert_fails('let a:000[2] = [9, 10]', 'E742:')
571  call assert_fails('let a:000[3] = {9 : 10}', 'E742:')
572
573  " now the tests that should pass
574  let a:000[2][1] = 9
575  call extend(a:000[2], [5, 6])
576  let a:000[3][5] = 8
577  let a:000[3]['a'] = 12
578  call assert_equal([1, 2, [3, 9, 5, 6], {'a': 12, '5': 8}], a:000)
579endfunc
580
581func Test_func_arg_list()
582  call s:arg_list_test(1, 2, [3, 4], {5: 6})
583endfunc
584
585" Tests for reverse(), sort(), uniq()
586func Test_reverse_sort_uniq()
587  let l = ['-0', 'A11', 2, 2, 'xaaa', 4, 'foo', 'foo6', 'foo', [0, 1, 2], 'x8', [0, 1, 2], 1.5]
588  call assert_equal(['-0', 'A11', 2, 'xaaa', 4, 'foo', 'foo6', 'foo', [0, 1, 2], 'x8', [0, 1, 2], 1.5], uniq(copy(l)))
589  call assert_equal([1.5, [0, 1, 2], 'x8', [0, 1, 2], 'foo', 'foo6', 'foo', 4, 'xaaa', 2, 2, 'A11', '-0'], reverse(l))
590  call assert_equal([1.5, [0, 1, 2], 'x8', [0, 1, 2], 'foo', 'foo6', 'foo', 4, 'xaaa', 2, 2, 'A11', '-0'], reverse(reverse(l)))
591  call assert_equal(['-0', 'A11', 'foo', 'foo', 'foo6', 'x8', 'xaaa', 1.5, 2, 2, 4, [0, 1, 2], [0, 1, 2]], sort(l))
592  call assert_equal([[0, 1, 2], [0, 1, 2], 4, 2, 2, 1.5, 'xaaa', 'x8', 'foo6', 'foo', 'foo', 'A11', '-0'], reverse(sort(l)))
593  call assert_equal(['-0', 'A11', 'foo', 'foo', 'foo6', 'x8', 'xaaa', 1.5, 2, 2, 4, [0, 1, 2], [0, 1, 2]], sort(reverse(sort(l))))
594  call assert_equal(['-0', 'A11', 'foo', 'foo6', 'x8', 'xaaa', 1.5, 2, 4, [0, 1, 2]], uniq(sort(l)))
595
596  let l=[7, 9, 'one', 18, 12, 22, 'two', 10.0e-16, -1, 'three', 0xff, 0.22, 'four']
597  call assert_equal([-1, 'one', 'two', 'three', 'four', 1.0e-15, 0.22, 7, 9, 12, 18, 22, 255], sort(copy(l), 'n'))
598
599  let l=[7, 9, 18, 12, 22, 10.0e-16, -1, 0xff, 0, -0, 0.22, 'bar', 'BAR', 'Bar', 'Foo', 'FOO', 'foo', 'FOOBAR', {}, []]
600  call assert_equal(['bar', 'BAR', 'Bar', 'Foo', 'FOO', 'foo', 'FOOBAR', -1, 0, 0, 0.22, 1.0e-15, 12, 18, 22, 255, 7, 9, [], {}], sort(copy(l), 1))
601  call assert_equal(['bar', 'BAR', 'Bar', 'Foo', 'FOO', 'foo', 'FOOBAR', -1, 0, 0, 0.22, 1.0e-15, 12, 18, 22, 255, 7, 9, [], {}], sort(copy(l), 'i'))
602  call assert_equal(['BAR', 'Bar', 'FOO', 'FOOBAR', 'Foo', 'bar', 'foo', -1, 0, 0, 0.22, 1.0e-15, 12, 18, 22, 255, 7, 9, [], {}], sort(copy(l)))
603
604  call assert_fails('call reverse("")', 'E899:')
605endfunc
606
607" splitting a string to a List
608func Test_str_split()
609  call assert_equal(['aa', 'bb'], split('  aa  bb '))
610  call assert_equal(['aa', 'bb'], split('  aa  bb  ', '\W\+', 0))
611  call assert_equal(['', 'aa', 'bb', ''], split('  aa  bb  ', '\W\+', 1))
612  call assert_equal(['', '', 'aa', '', 'bb', '', ''], split('  aa  bb  ', '\W', 1))
613  call assert_equal(['aa', '', 'bb'], split(':aa::bb:', ':', 0))
614  call assert_equal(['', 'aa', '', 'bb', ''], split(':aa::bb:', ':', 1))
615  call assert_equal(['aa', '', 'bb', 'cc', ''], split('aa,,bb, cc,', ',\s*', 1))
616  call assert_equal(['a', 'b', 'c'], split('abc', '\zs'))
617  call assert_equal(['', 'a', '', 'b', '', 'c', ''], split('abc', '\zs', 1))
618endfunc
619
620" compare recursively linked list and dict
621func Test_listdict_compare()
622  let l = [1, 2, 3, 4]
623  let d = {'1': 1, '2': l, '3': 3}
624  let l[1] = d
625  call assert_true(l == l)
626  call assert_true(d == d)
627  call assert_false(l != deepcopy(l))
628  call assert_false(d != deepcopy(d))
629endfunc
630
631  " compare complex recursively linked list and dict
632func Test_listdict_compare_complex()
633  let l = []
634  call add(l, l)
635  let dict4 = {"l": l}
636  call add(dict4.l, dict4)
637  let lcopy = deepcopy(l)
638  let dict4copy = deepcopy(dict4)
639  call assert_true(l == lcopy)
640  call assert_true(dict4 == dict4copy)
641endfunc
642
643func Test_listdict_extend()
644  " Test extend() with lists
645
646  " Pass the same List to extend()
647  let l = [1, 2, 3]
648  call assert_equal([1, 2, 3, 1, 2, 3], extend(l, l))
649  call assert_equal([1, 2, 3, 1, 2, 3], l)
650
651  let l = [1, 2, 3]
652  call assert_equal([1, 2, 3, 4, 5, 6], extend(l, [4, 5, 6]))
653  call assert_equal([1, 2, 3, 4, 5, 6], l)
654
655  let l = [1, 2, 3]
656  call extend(l, [4, 5, 6], 0)
657  call assert_equal([4, 5, 6, 1, 2, 3], l)
658
659  let l = [1, 2, 3]
660  call extend(l, [4, 5, 6], 1)
661  call assert_equal([1, 4, 5, 6, 2, 3], l)
662
663  let l = [1, 2, 3]
664  call extend(l, [4, 5, 6], 3)
665  call assert_equal([1, 2, 3, 4, 5, 6], l)
666
667  let l = [1, 2, 3]
668  call extend(l, [4, 5, 6], -1)
669  call assert_equal([1, 2, 4, 5, 6, 3], l)
670
671  let l = [1, 2, 3]
672  call extend(l, [4, 5, 6], -3)
673  call assert_equal([4, 5, 6, 1, 2,  3], l)
674
675  let l = [1, 2, 3]
676  call assert_fails("call extend(l, [4, 5, 6], 4)", 'E684:')
677  call assert_fails("call extend(l, [4, 5, 6], -4)", 'E684:')
678  call assert_fails("call extend(l, [4, 5, 6], 1.2)", 'E805:')
679
680  " Test extend() with dictionaries.
681
682  " Pass the same Dict to extend()
683  let d = { 'a': {'b': 'B'}}
684  call extend(d, d)
685  call assert_equal({'a': {'b': 'B'}}, d)
686
687  let d = {'a': 'A', 'b': 'B'}
688  call assert_equal({'a': 'A', 'b': 0, 'c': 'C'}, extend(d, {'b': 0, 'c':'C'}))
689  call assert_equal({'a': 'A', 'b': 0, 'c': 'C'}, d)
690
691  let d = {'a': 'A', 'b': 'B'}
692  call extend(d, {'a': 'A', 'b': 0, 'c': 'C'}, "force")
693  call assert_equal({'a': 'A', 'b': 0, 'c': 'C'}, d)
694
695  let d = {'a': 'A', 'b': 'B'}
696  call extend(d, {'b': 0, 'c':'C'}, "keep")
697  call assert_equal({'a': 'A', 'b': 'B', 'c': 'C'}, d)
698
699  let d = {'a': 'A', 'b': 'B'}
700  call assert_fails("call extend(d, {'b': 0, 'c':'C'}, 'error')", 'E737:')
701  call assert_fails("call extend(d, {'b': 0, 'c':'C'}, 'xxx')", 'E475:')
702  call assert_fails("call extend(d, {'b': 0, 'c':'C'}, 1.2)", 'E806:')
703  call assert_equal({'a': 'A', 'b': 'B'}, d)
704
705  call assert_fails("call extend([1, 2], 1)", 'E712:')
706  call assert_fails("call extend([1, 2], {})", 'E712:')
707endfunc
708
709func s:check_scope_dict(x, fixed)
710  func s:gen_cmd(cmd, x)
711    return substitute(a:cmd, '\<x\ze:', a:x, 'g')
712  endfunc
713
714  let cmd = s:gen_cmd('let x:foo = 1', a:x)
715  if a:fixed
716    call assert_fails(cmd, 'E461')
717  else
718    exe cmd
719    exe s:gen_cmd('call assert_equal(1, x:foo)', a:x)
720  endif
721
722  let cmd = s:gen_cmd('let x:["bar"] = 2', a:x)
723  if a:fixed
724    call assert_fails(cmd, 'E461')
725  else
726    exe cmd
727    exe s:gen_cmd('call assert_equal(2, x:bar)', a:x)
728  endif
729
730  let cmd = s:gen_cmd('call extend(x:, {"baz": 3})', a:x)
731  if a:fixed
732    call assert_fails(cmd, 'E742')
733  else
734    exe cmd
735    exe s:gen_cmd('call assert_equal(3, x:baz)', a:x)
736  endif
737
738  if a:fixed
739    if a:x ==# 'a'
740      call assert_fails('unlet a:x', 'E795')
741      call assert_fails('call remove(a:, "x")', 'E742')
742    elseif a:x ==# 'v'
743      call assert_fails('unlet v:count', 'E795')
744      call assert_fails('call remove(v:, "count")', 'E742')
745    endif
746  else
747    exe s:gen_cmd('unlet x:foo', a:x)
748    exe s:gen_cmd('unlet x:bar', a:x)
749    exe s:gen_cmd('call remove(x:, "baz")', a:x)
750  endif
751
752  delfunc s:gen_cmd
753endfunc
754
755func Test_scope_dict()
756  " Test for g:
757  call s:check_scope_dict('g', v:false)
758
759  " Test for s:
760  call s:check_scope_dict('s', v:false)
761
762  " Test for l:
763  call s:check_scope_dict('l', v:false)
764
765  " Test for a:
766  call s:check_scope_dict('a', v:true)
767
768  " Test for b:
769  call s:check_scope_dict('b', v:false)
770
771  " Test for w:
772  call s:check_scope_dict('w', v:false)
773
774  " Test for t:
775  call s:check_scope_dict('t', v:false)
776
777  " Test for v:
778  call s:check_scope_dict('v', v:true)
779endfunc
780