1" Test for insert completion
2
3source screendump.vim
4source check.vim
5
6" Test for insert expansion
7func Test_ins_complete()
8  edit test_ins_complete.vim
9  " The files in the current directory interferes with the files
10  " used by this test. So use a separate directory for the test.
11  call mkdir('Xdir')
12  cd Xdir
13
14  set ff=unix
15  call writefile(["test11\t36Gepeto\t/Tag/",
16	      \ "asd\ttest11file\t36G",
17	      \ "Makefile\tto\trun"], 'Xtestfile')
18  call writefile(['', 'start of testfile',
19	      \ 'ru',
20	      \ 'run1',
21	      \ 'run2',
22	      \ 'STARTTEST',
23	      \ 'ENDTEST',
24	      \ 'end of testfile'], 'Xtestdata')
25  set ff&
26
27  enew!
28  edit Xtestdata
29  new
30  call append(0, ['#include "Xtestfile"', ''])
31  call cursor(2, 1)
32
33  set cot=
34  set cpt=.,w
35  " add-expands (word from next line) from other window
36  exe "normal iru\<C-N>\<C-N>\<C-X>\<C-N>\<Esc>\<C-A>"
37  call assert_equal('run1 run3', getline('.'))
38  " add-expands (current buffer first)
39  exe "normal o\<C-P>\<C-X>\<C-N>"
40  call assert_equal('run3 run3', getline('.'))
41  " Local expansion, ends in an empty line (unless it becomes a global
42  " expansion)
43  exe "normal o\<C-X>\<C-P>\<C-P>\<C-P>\<C-P>\<C-P>"
44  call assert_equal('', getline('.'))
45  " starts Local and switches to global add-expansion
46  exe "normal o\<C-X>\<C-P>\<C-P>\<C-X>\<C-X>\<C-N>\<C-X>\<C-N>\<C-N>"
47  call assert_equal('run1 run2', getline('.'))
48
49  set cpt=.,w,i
50  " i-add-expands and switches to local
51  exe "normal OM\<C-N>\<C-X>\<C-N>\<C-X>\<C-N>\<C-X>\<C-X>\<C-X>\<C-P>"
52  call assert_equal("Makefile\tto\trun3", getline('.'))
53  " add-expands lines (it would end in an empty line if it didn't ignored
54  " itself)
55  exe "normal o\<C-X>\<C-L>\<C-X>\<C-L>\<C-P>\<C-P>"
56  call assert_equal("Makefile\tto\trun3", getline('.'))
57  call assert_equal("Makefile\tto\trun3", getline(line('.') - 1))
58
59  set cpt=kXtestfile
60  " checks k-expansion, and file expansion (use Xtest11 instead of test11,
61  " because TEST11.OUT may match first on DOS)
62  write Xtest11.one
63  write Xtest11.two
64  exe "normal o\<C-N>\<Esc>IX\<Esc>A\<C-X>\<C-F>\<C-N>"
65  call assert_equal('Xtest11.two', getline('.'))
66
67  " use CTRL-X CTRL-F to complete Xtest11.one, remove it and then use CTRL-X
68  " CTRL-F again to verify this doesn't cause trouble.
69  exe "normal oXt\<C-X>\<C-F>\<BS>\<BS>\<BS>\<BS>\<BS>\<BS>\<BS>\<BS>\<C-X>\<C-F>"
70  call assert_equal('Xtest11.one', getline('.'))
71  normal ddk
72
73  set cpt=w
74  " checks make_cyclic in other window
75  exe "normal oST\<C-N>\<C-P>\<C-P>\<C-P>\<C-P>"
76  call assert_equal('STARTTEST', getline('.'))
77
78  set cpt=u nohid
79  " checks unloaded buffer expansion
80  only
81  exe "normal oEN\<C-N>"
82  call assert_equal('ENDTEST', getline('.'))
83  " checks adding mode abortion
84  exe "normal ounl\<C-N>\<C-X>\<C-X>\<C-P>"
85  call assert_equal('unless', getline('.'))
86
87  set cpt=t,d def=^\\k* tags=Xtestfile notagbsearch
88  " tag expansion, define add-expansion interrupted
89  exe "normal o\<C-X>\<C-]>\<C-X>\<C-D>\<C-X>\<C-D>\<C-X>\<C-X>\<C-D>\<C-X>\<C-D>\<C-X>\<C-D>\<C-X>\<C-D>"
90  call assert_equal('test11file	36Gepeto	/Tag/ asd', getline('.'))
91  " t-expansion
92  exe "normal oa\<C-N>\<Esc>"
93  call assert_equal('asd', getline('.'))
94
95  %bw!
96  call delete('Xtestfile')
97  call delete('Xtest11.one')
98  call delete('Xtest11.two')
99  call delete('Xtestdata')
100  set cpt& cot& def& tags& tagbsearch& hidden&
101  cd ..
102  call delete('Xdir', 'rf')
103endfunc
104
105func Test_omni_dash()
106  func Omni(findstart, base)
107    if a:findstart
108        return 5
109    else
110        echom a:base
111	return ['-help', '-v']
112    endif
113  endfunc
114  set omnifunc=Omni
115  new
116  exe "normal Gofind -\<C-x>\<C-o>"
117  call assert_equal("\n-\nmatch 1 of 2", execute(':2mess'))
118
119  bwipe!
120  delfunc Omni
121  set omnifunc=
122endfunc
123
124func Test_completefunc_args()
125  let s:args = []
126  func! CompleteFunc(findstart, base)
127    let s:args += [[a:findstart, empty(a:base)]]
128  endfunc
129  new
130
131  set completefunc=CompleteFunc
132  call feedkeys("i\<C-X>\<C-U>\<Esc>", 'x')
133  call assert_equal([1, 1], s:args[0])
134  call assert_equal(0, s:args[1][0])
135  set completefunc=
136
137  let s:args = []
138  set omnifunc=CompleteFunc
139  call feedkeys("i\<C-X>\<C-O>\<Esc>", 'x')
140  call assert_equal([1, 1], s:args[0])
141  call assert_equal(0, s:args[1][0])
142  set omnifunc=
143
144  bwipe!
145  unlet s:args
146  delfunc CompleteFunc
147endfunc
148
149func s:CompleteDone_CompleteFuncNone( findstart, base )
150  if a:findstart
151    return 0
152  endif
153
154  return v:none
155endfunc
156
157func s:CompleteDone_CompleteFuncDict( findstart, base )
158  if a:findstart
159    return 0
160  endif
161
162  return {
163	  \ 'words': [
164	    \ {
165	      \ 'word': 'aword',
166	      \ 'abbr': 'wrd',
167	      \ 'menu': 'extra text',
168	      \ 'info': 'words are cool',
169	      \ 'kind': 'W',
170	      \ 'user_data': 'test'
171	    \ }
172	  \ ]
173	\ }
174endfunc
175
176func s:CompleteDone_CheckCompletedItemNone()
177  let s:called_completedone = 1
178endfunc
179
180func s:CompleteDone_CheckCompletedItemDict(pre)
181  call assert_equal( 'aword',          v:completed_item[ 'word' ] )
182  call assert_equal( 'wrd',            v:completed_item[ 'abbr' ] )
183  call assert_equal( 'extra text',     v:completed_item[ 'menu' ] )
184  call assert_equal( 'words are cool', v:completed_item[ 'info' ] )
185  call assert_equal( 'W',              v:completed_item[ 'kind' ] )
186  call assert_equal( 'test',           v:completed_item[ 'user_data' ] )
187
188  if a:pre
189    call assert_equal('function', complete_info().mode)
190  endif
191
192  let s:called_completedone = 1
193endfunc
194
195func Test_CompleteDoneNone()
196  au CompleteDone * :call <SID>CompleteDone_CheckCompletedItemNone()
197  let oldline = join(map(range(&columns), 'nr2char(screenchar(&lines-1, v:val+1))'), '')
198
199  set completefunc=<SID>CompleteDone_CompleteFuncNone
200  execute "normal a\<C-X>\<C-U>\<C-Y>"
201  set completefunc&
202  let newline = join(map(range(&columns), 'nr2char(screenchar(&lines-1, v:val+1))'), '')
203
204  call assert_true(s:called_completedone)
205  call assert_equal(oldline, newline)
206
207  let s:called_completedone = 0
208  au! CompleteDone
209endfunc
210
211func Test_CompleteDoneDict()
212  au CompleteDonePre * :call <SID>CompleteDone_CheckCompletedItemDict(1)
213  au CompleteDone * :call <SID>CompleteDone_CheckCompletedItemDict(0)
214
215  set completefunc=<SID>CompleteDone_CompleteFuncDict
216  execute "normal a\<C-X>\<C-U>\<C-Y>"
217  set completefunc&
218
219  call assert_equal('test', v:completed_item[ 'user_data' ])
220  call assert_true(s:called_completedone)
221
222  let s:called_completedone = 0
223  au! CompleteDone
224endfunc
225
226func s:CompleteDone_CompleteFuncDictNoUserData(findstart, base)
227  if a:findstart
228    return 0
229  endif
230
231  return {
232	  \ 'words': [
233	    \ {
234	      \ 'word': 'aword',
235	      \ 'abbr': 'wrd',
236	      \ 'menu': 'extra text',
237	      \ 'info': 'words are cool',
238	      \ 'kind': 'W',
239	      \ 'user_data': ['one', 'two'],
240	    \ }
241	  \ ]
242	\ }
243endfunc
244
245func s:CompleteDone_CheckCompletedItemDictNoUserData()
246  call assert_equal( 'aword',          v:completed_item[ 'word' ] )
247  call assert_equal( 'wrd',            v:completed_item[ 'abbr' ] )
248  call assert_equal( 'extra text',     v:completed_item[ 'menu' ] )
249  call assert_equal( 'words are cool', v:completed_item[ 'info' ] )
250  call assert_equal( 'W',              v:completed_item[ 'kind' ] )
251  call assert_equal( ['one', 'two'],   v:completed_item[ 'user_data' ] )
252
253  let s:called_completedone = 1
254endfunc
255
256func Test_CompleteDoneDictNoUserData()
257  au CompleteDone * :call <SID>CompleteDone_CheckCompletedItemDictNoUserData()
258
259  set completefunc=<SID>CompleteDone_CompleteFuncDictNoUserData
260  execute "normal a\<C-X>\<C-U>\<C-Y>"
261  set completefunc&
262
263  call assert_equal(['one', 'two'], v:completed_item[ 'user_data' ])
264  call assert_true(s:called_completedone)
265
266  let s:called_completedone = 0
267  au! CompleteDone
268endfunc
269
270func s:CompleteDone_CompleteFuncList(findstart, base)
271  if a:findstart
272    return 0
273  endif
274
275  return [ 'aword' ]
276endfunc
277
278func s:CompleteDone_CheckCompletedItemList()
279  call assert_equal( 'aword', v:completed_item[ 'word' ] )
280  call assert_equal( '',      v:completed_item[ 'abbr' ] )
281  call assert_equal( '',      v:completed_item[ 'menu' ] )
282  call assert_equal( '',      v:completed_item[ 'info' ] )
283  call assert_equal( '',      v:completed_item[ 'kind' ] )
284  call assert_equal( '',      v:completed_item[ 'user_data' ] )
285
286  let s:called_completedone = 1
287endfunc
288
289func Test_CompleteDoneList()
290  au CompleteDone * :call <SID>CompleteDone_CheckCompletedItemList()
291
292  set completefunc=<SID>CompleteDone_CompleteFuncList
293  execute "normal a\<C-X>\<C-U>\<C-Y>"
294  set completefunc&
295
296  call assert_equal('', v:completed_item[ 'user_data' ])
297  call assert_true(s:called_completedone)
298
299  let s:called_completedone = 0
300  au! CompleteDone
301endfunc
302
303func Test_CompleteDone_undo()
304  au CompleteDone * call append(0, "prepend1")
305  new
306  call setline(1, ["line1", "line2"])
307  call feedkeys("Go\<C-X>\<C-N>\<CR>\<ESC>", "tx")
308  call assert_equal(["prepend1", "line1", "line2", "line1", ""],
309              \     getline(1, '$'))
310  undo
311  call assert_equal(["line1", "line2"], getline(1, '$'))
312  bwipe!
313  au! CompleteDone
314endfunc
315
316func CompleteTest(findstart, query)
317  if a:findstart
318    return col('.')
319  endif
320  return ['matched']
321endfunc
322
323func Test_completefunc_info()
324  new
325  set completeopt=menuone
326  set completefunc=CompleteTest
327  call feedkeys("i\<C-X>\<C-U>\<C-R>\<C-R>=string(complete_info())\<CR>\<ESC>", "tx")
328  call assert_equal("matched{'pum_visible': 1, 'mode': 'function', 'selected': -1, 'items': [{'word': 'matched', 'menu': '', 'user_data': '', 'info': '', 'kind': '', 'abbr': ''}]}", getline(1))
329  bwipe!
330  set completeopt&
331  set completefunc&
332endfunc
333
334" Check that when using feedkeys() typeahead does not interrupt searching for
335" completions.
336func Test_compl_feedkeys()
337  new
338  set completeopt=menuone,noselect
339  call feedkeys("ajump ju\<C-X>\<C-N>\<C-P>\<ESC>", "tx")
340  call assert_equal("jump jump", getline(1))
341  bwipe!
342  set completeopt&
343endfunc
344
345func Test_compl_in_cmdwin()
346  set wildmenu wildchar=<Tab>
347  com! -nargs=1 -complete=command GetInput let input = <q-args>
348  com! -buffer TestCommand echo 'TestCommand'
349
350  let input = ''
351  call feedkeys("q:iGetInput T\<C-x>\<C-v>\<CR>", 'tx!')
352  call assert_equal('TestCommand', input)
353
354  let input = ''
355  call feedkeys("q::GetInput T\<Tab>\<CR>:q\<CR>", 'tx!')
356  call assert_equal('T', input)
357
358  delcom TestCommand
359  delcom GetInput
360  set wildmenu& wildchar&
361endfunc
362
363" Test for insert path completion with completeslash option
364func Test_ins_completeslash()
365  CheckMSWindows
366
367  call mkdir('Xdir')
368  let orig_shellslash = &shellslash
369  set cpt&
370  new
371
372  set noshellslash
373
374  set completeslash=
375  exe "normal oXd\<C-X>\<C-F>"
376  call assert_equal('Xdir\', getline('.'))
377
378  set completeslash=backslash
379  exe "normal oXd\<C-X>\<C-F>"
380  call assert_equal('Xdir\', getline('.'))
381
382  set completeslash=slash
383  exe "normal oXd\<C-X>\<C-F>"
384  call assert_equal('Xdir/', getline('.'))
385
386  set shellslash
387
388  set completeslash=
389  exe "normal oXd\<C-X>\<C-F>"
390  call assert_equal('Xdir/', getline('.'))
391
392  set completeslash=backslash
393  exe "normal oXd\<C-X>\<C-F>"
394  call assert_equal('Xdir\', getline('.'))
395
396  set completeslash=slash
397  exe "normal oXd\<C-X>\<C-F>"
398  call assert_equal('Xdir/', getline('.'))
399  %bw!
400  call delete('Xdir', 'rf')
401
402  set noshellslash
403  set completeslash=slash
404  call assert_true(stridx(globpath(&rtp, 'syntax/*.vim', 1, 1)[0], '\') != -1)
405
406  let &shellslash = orig_shellslash
407  set completeslash=
408endfunc
409
410func Test_pum_stopped_by_timer()
411  CheckScreendump
412
413  let lines =<< trim END
414    call setline(1, ['hello', 'hullo', 'heeee', ''])
415    func StartCompl()
416      call timer_start(100, { -> execute('stopinsert') })
417      call feedkeys("Gah\<C-N>")
418    endfunc
419  END
420
421  call writefile(lines, 'Xpumscript')
422  let buf = RunVimInTerminal('-S Xpumscript', #{rows: 12})
423  call term_sendkeys(buf, ":call StartCompl()\<CR>")
424  call TermWait(buf, 200)
425  call term_sendkeys(buf, "k")
426  call VerifyScreenDump(buf, 'Test_pum_stopped_by_timer', {})
427
428  call StopVimInTerminal(buf)
429  call delete('Xpumscript')
430endfunc
431
432func Test_pum_with_folds_two_tabs()
433  CheckScreendump
434
435  let lines =<< trim END
436    set fdm=marker
437    call setline(1, ['" x {{{1', '" a some text'])
438    call setline(3, range(&lines)->map({_, val -> '" a' .. val}))
439    norm! zm
440    tab sp
441    call feedkeys('2Gzv', 'xt')
442    call feedkeys("0fa", 'xt')
443  END
444
445  call writefile(lines, 'Xpumscript')
446  let buf = RunVimInTerminal('-S Xpumscript', #{rows: 10})
447  call TermWait(buf, 50)
448  call term_sendkeys(buf, "a\<C-N>")
449  call VerifyScreenDump(buf, 'Test_pum_with_folds_two_tabs', {})
450
451  call term_sendkeys(buf, "\<Esc>")
452  call StopVimInTerminal(buf)
453  call delete('Xpumscript')
454endfunc
455
456func Test_pum_with_preview_win()
457  CheckScreendump
458
459  let lines =<< trim END
460      funct Omni_test(findstart, base)
461	if a:findstart
462	  return col(".") - 1
463	endif
464	return [#{word: "one", info: "1info"}, #{word: "two", info: "2info"}, #{word: "three", info: "3info"}]
465      endfunc
466      set omnifunc=Omni_test
467      set completeopt+=longest
468  END
469
470  call writefile(lines, 'Xpreviewscript')
471  let buf = RunVimInTerminal('-S Xpreviewscript', #{rows: 12})
472  call TermWait(buf, 50)
473  call term_sendkeys(buf, "Gi\<C-X>\<C-O>")
474  call TermWait(buf, 100)
475  call term_sendkeys(buf, "\<C-N>")
476  call VerifyScreenDump(buf, 'Test_pum_with_preview_win', {})
477
478  call term_sendkeys(buf, "\<Esc>")
479  call StopVimInTerminal(buf)
480  call delete('Xpreviewscript')
481endfunc
482
483" Test for inserting the tag search pattern in insert mode
484func Test_ins_compl_tag_sft()
485  call writefile([
486        \ "!_TAG_FILE_ENCODING\tutf-8\t//",
487        \ "first\tXfoo\t/^int first() {}$/",
488        \ "second\tXfoo\t/^int second() {}$/",
489        \ "third\tXfoo\t/^int third() {}$/"],
490        \ 'Xtags')
491  set tags=Xtags
492  let code =<< trim [CODE]
493    int first() {}
494    int second() {}
495    int third() {}
496  [CODE]
497  call writefile(code, 'Xfoo')
498
499  enew
500  set showfulltag
501  exe "normal isec\<C-X>\<C-]>\<C-N>\<CR>"
502  call assert_equal('int second() {}', getline(1))
503  set noshowfulltag
504
505  call delete('Xtags')
506  call delete('Xfoo')
507  set tags&
508  %bwipe!
509endfunc
510
511" Test for 'completefunc' deleting text
512func Test_completefunc_error()
513  new
514  " delete text when called for the first time
515  func CompleteFunc(findstart, base)
516    if a:findstart == 1
517      normal dd
518      return col('.') - 1
519    endif
520    return ['a', 'b']
521  endfunc
522  set completefunc=CompleteFunc
523  call setline(1, ['', 'abcd', ''])
524  call assert_fails('exe "normal 2G$a\<C-X>\<C-U>"', 'E840:')
525
526  " delete text when called for the second time
527  func CompleteFunc2(findstart, base)
528    if a:findstart == 1
529      return col('.') - 1
530    endif
531    normal dd
532    return ['a', 'b']
533  endfunc
534  set completefunc=CompleteFunc2
535  call setline(1, ['', 'abcd', ''])
536  call assert_fails('exe "normal 2G$a\<C-X>\<C-U>"', 'E578:')
537
538  " Jump to a different window from the complete function
539  " TODO: The following test causes an ASAN failure. Once this issue is
540  " addressed, enable the following test.
541  "func! CompleteFunc(findstart, base)
542  "  if a:findstart == 1
543  "    return col('.') - 1
544  "  endif
545  "  wincmd p
546  "  return ['a', 'b']
547  "endfunc
548  "set completefunc=CompleteFunc
549  "new
550  "call assert_fails('exe "normal a\<C-X>\<C-U>"', 'E839:')
551  "close!
552
553  set completefunc&
554  delfunc CompleteFunc
555  delfunc CompleteFunc2
556  close!
557endfunc
558
559" Test for returning non-string values from 'completefunc'
560func Test_completefunc_invalid_data()
561  new
562  func! CompleteFunc(findstart, base)
563    if a:findstart == 1
564      return col('.') - 1
565    endif
566    return [{}, '', 'moon']
567  endfunc
568  set completefunc=CompleteFunc
569  exe "normal i\<C-X>\<C-U>"
570  call assert_equal('moon', getline(1))
571  set completefunc&
572  close!
573endfunc
574
575" Test for errors in using complete() function
576func Test_complete_func_error()
577  call assert_fails('call complete(1, ["a"])', 'E785:')
578  func ListColors()
579    call complete(col('.'), "blue")
580  endfunc
581  call assert_fails('exe "normal i\<C-R>=ListColors()\<CR>"', 'E474:')
582  func ListMonths()
583    call complete(col('.'), test_null_list())
584  endfunc
585  call assert_fails('exe "normal i\<C-R>=ListMonths()\<CR>"', 'E474:')
586  delfunc ListColors
587  delfunc ListMonths
588  call assert_fails('call complete_info({})', 'E714:')
589  call assert_equal([], complete_info(['items']).items)
590endfunc
591
592" Test for completing words following a completed word in a line
593func Test_complete_wrapscan()
594  " complete words from another buffer
595  new
596  call setline(1, ['one two', 'three four'])
597  new
598  setlocal complete=w
599  call feedkeys("itw\<C-N>\<C-X>\<C-N>\<C-X>\<C-N>\<C-X>\<C-N>", 'xt')
600  call assert_equal('two three four', getline(1))
601  close!
602  " complete words from the current buffer
603  setlocal complete=.
604  %d
605  call setline(1, ['one two', ''])
606  call cursor(2, 1)
607  call feedkeys("ion\<C-N>\<C-X>\<C-N>\<C-X>\<C-N>\<C-X>\<C-N>", 'xt')
608  call assert_equal('one two one two', getline(2))
609  close!
610endfunc
611
612" Test for completing special characters
613func Test_complete_special_chars()
614  new
615  call setline(1, 'int .*[-\^$ func float')
616  call feedkeys("oin\<C-X>\<C-P>\<C-X>\<C-P>\<C-X>\<C-P>", 'xt')
617  call assert_equal('int .*[-\^$ func float', getline(2))
618  close!
619endfunc
620
621" Test for completion when text is wrapped across lines.
622func Test_complete_across_line()
623  new
624  call setline(1, ['red green blue', 'one two three'])
625  setlocal textwidth=20
626  exe "normal 2G$a re\<C-X>\<C-P>\<C-X>\<C-P>\<C-X>\<C-P>\<C-X>\<C-P>"
627  call assert_equal(['one two three red', 'green blue one'], getline(2, '$'))
628  close!
629endfunc
630
631" Test for using CTRL-L to add one character when completing matching
632func Test_complete_add_onechar()
633  new
634  call setline(1, ['wool', 'woodwork'])
635  call feedkeys("Gowoo\<C-P>\<C-P>\<C-P>\<C-L>f", 'xt')
636  call assert_equal('woof', getline(3))
637
638  " use 'ignorecase' and backspace to erase characters from the prefix string
639  " and then add letters using CTRL-L
640  %d
641  set ignorecase backspace=2
642  setlocal complete=.
643  call setline(1, ['workhorse', 'workload'])
644  normal Go
645  exe "normal aWOR\<C-P>\<bs>\<bs>\<bs>\<bs>\<bs>\<bs>\<C-L>r\<C-L>\<C-L>"
646  call assert_equal('workh', getline(3))
647  set ignorecase& backspace&
648  close!
649endfunc
650
651" Test insert completion with 'cindent' (adjust the indent)
652func Test_complete_with_cindent()
653  new
654  setlocal cindent
655  call setline(1, ['if (i == 1)', "    j = 2;"])
656  exe "normal Go{\<CR>i\<C-X>\<C-L>\<C-X>\<C-L>\<CR>}"
657  call assert_equal(['{', "\tif (i == 1)", "\t\tj = 2;", '}'], getline(3, '$'))
658
659  %d
660  call setline(1, ['when while', '{', ''])
661  setlocal cinkeys+==while
662  exe "normal Giwh\<C-P> "
663  call assert_equal("\twhile ", getline('$'))
664  close!
665endfunc
666
667" Test for <CTRL-X> <CTRL-V> completion. Complete commands and functions
668func Test_complete_cmdline()
669  new
670  exe "normal icaddb\<C-X>\<C-V>"
671  call assert_equal('caddbuffer', getline(1))
672  exe "normal ocall getqf\<C-X>\<C-V>"
673  call assert_equal('call getqflist(', getline(2))
674  exe "normal oabcxyz(\<C-X>\<C-V>"
675  call assert_equal('abcxyz(', getline(3))
676  close!
677endfunc
678
679func Test_issue_7021()
680  CheckMSWindows
681
682  let orig_shellslash = &shellslash
683  set noshellslash
684
685  set completeslash=slash
686  call assert_false(expand('~') =~ '/')
687
688  let &shellslash = orig_shellslash
689  set completeslash=
690endfunc
691
692" vim: shiftwidth=2 sts=2 expandtab
693