1" Test for insert completion
2
3source screendump.vim
4source check.vim
5
6" Test for insert expansion
7func Test_ins_complete()
8  edit test_ins_complete.vim
9  " The files in the current directory interferes with the files
10  " used by this test. So use a separate directory for the test.
11  call mkdir('Xdir')
12  cd Xdir
13
14  set ff=unix
15  call writefile(["test11\t36Gepeto\t/Tag/",
16	      \ "asd\ttest11file\t36G",
17	      \ "Makefile\tto\trun"], 'Xtestfile')
18  call writefile(['', 'start of testfile',
19	      \ 'ru',
20	      \ 'run1',
21	      \ 'run2',
22	      \ 'STARTTEST',
23	      \ 'ENDTEST',
24	      \ 'end of testfile'], 'Xtestdata')
25  set ff&
26
27  enew!
28  edit Xtestdata
29  new
30  call append(0, ['#include "Xtestfile"', ''])
31  call cursor(2, 1)
32
33  set cot=
34  set cpt=.,w
35  " add-expands (word from next line) from other window
36  exe "normal iru\<C-N>\<C-N>\<C-X>\<C-N>\<Esc>\<C-A>"
37  call assert_equal('run1 run3', getline('.'))
38  " add-expands (current buffer first)
39  exe "normal o\<C-P>\<C-X>\<C-N>"
40  call assert_equal('run3 run3', getline('.'))
41  " Local expansion, ends in an empty line (unless it becomes a global
42  " expansion)
43  exe "normal o\<C-X>\<C-P>\<C-P>\<C-P>\<C-P>\<C-P>"
44  call assert_equal('', getline('.'))
45  " starts Local and switches to global add-expansion
46  exe "normal o\<C-X>\<C-P>\<C-P>\<C-X>\<C-X>\<C-N>\<C-X>\<C-N>\<C-N>"
47  call assert_equal('run1 run2', getline('.'))
48
49  set cpt=.,w,i
50  " i-add-expands and switches to local
51  exe "normal OM\<C-N>\<C-X>\<C-N>\<C-X>\<C-N>\<C-X>\<C-X>\<C-X>\<C-P>"
52  call assert_equal("Makefile\tto\trun3", getline('.'))
53  " add-expands lines (it would end in an empty line if it didn't ignored
54  " itself)
55  exe "normal o\<C-X>\<C-L>\<C-X>\<C-L>\<C-P>\<C-P>"
56  call assert_equal("Makefile\tto\trun3", getline('.'))
57  call assert_equal("Makefile\tto\trun3", getline(line('.') - 1))
58
59  set cpt=kXtestfile
60  " checks k-expansion, and file expansion (use Xtest11 instead of test11,
61  " because TEST11.OUT may match first on DOS)
62  write Xtest11.one
63  write Xtest11.two
64  exe "normal o\<C-N>\<Esc>IX\<Esc>A\<C-X>\<C-F>\<C-N>"
65  call assert_equal('Xtest11.two', getline('.'))
66
67  " use CTRL-X CTRL-F to complete Xtest11.one, remove it and then use CTRL-X
68  " CTRL-F again to verify this doesn't cause trouble.
69  exe "normal oXt\<C-X>\<C-F>\<BS>\<BS>\<BS>\<BS>\<BS>\<BS>\<BS>\<BS>\<C-X>\<C-F>"
70  call assert_equal('Xtest11.one', getline('.'))
71  normal ddk
72
73  set cpt=w
74  " checks make_cyclic in other window
75  exe "normal oST\<C-N>\<C-P>\<C-P>\<C-P>\<C-P>"
76  call assert_equal('STARTTEST', getline('.'))
77
78  set cpt=u nohid
79  " checks unloaded buffer expansion
80  only
81  exe "normal oEN\<C-N>"
82  call assert_equal('ENDTEST', getline('.'))
83  " checks adding mode abortion
84  exe "normal ounl\<C-N>\<C-X>\<C-X>\<C-P>"
85  call assert_equal('unless', getline('.'))
86
87  set cpt=t,d def=^\\k* tags=Xtestfile notagbsearch
88  " tag expansion, define add-expansion interrupted
89  exe "normal o\<C-X>\<C-]>\<C-X>\<C-D>\<C-X>\<C-D>\<C-X>\<C-X>\<C-D>\<C-X>\<C-D>\<C-X>\<C-D>\<C-X>\<C-D>"
90  call assert_equal('test11file	36Gepeto	/Tag/ asd', getline('.'))
91  " t-expansion
92  exe "normal oa\<C-N>\<Esc>"
93  call assert_equal('asd', getline('.'))
94
95  %bw!
96  call delete('Xtestfile')
97  call delete('Xtest11.one')
98  call delete('Xtest11.two')
99  call delete('Xtestdata')
100  set cpt& cot& def& tags& tagbsearch& hidden&
101  cd ..
102  call delete('Xdir', 'rf')
103endfunc
104
105func Test_omni_dash()
106  func Omni(findstart, base)
107    if a:findstart
108        return 5
109    else
110        echom a:base
111	return ['-help', '-v']
112    endif
113  endfunc
114  set omnifunc=Omni
115  new
116  exe "normal Gofind -\<C-x>\<C-o>"
117  call assert_equal("\n-\nmatch 1 of 2", execute(':2mess'))
118
119  bwipe!
120  delfunc Omni
121  set omnifunc=
122endfunc
123
124func Test_completefunc_args()
125  let s:args = []
126  func! CompleteFunc(findstart, base)
127    let s:args += [[a:findstart, empty(a:base)]]
128  endfunc
129  new
130
131  set completefunc=CompleteFunc
132  call feedkeys("i\<C-X>\<C-U>\<Esc>", 'x')
133  call assert_equal([1, 1], s:args[0])
134  call assert_equal(0, s:args[1][0])
135  set completefunc=
136
137  let s:args = []
138  set omnifunc=CompleteFunc
139  call feedkeys("i\<C-X>\<C-O>\<Esc>", 'x')
140  call assert_equal([1, 1], s:args[0])
141  call assert_equal(0, s:args[1][0])
142  set omnifunc=
143
144  bwipe!
145  unlet s:args
146  delfunc CompleteFunc
147endfunc
148
149func s:CompleteDone_CompleteFuncNone( findstart, base )
150  if a:findstart
151    return 0
152  endif
153
154  return v:none
155endfunc
156
157func s:CompleteDone_CompleteFuncDict( findstart, base )
158  if a:findstart
159    return 0
160  endif
161
162  return {
163	  \ 'words': [
164	    \ {
165	      \ 'word': 'aword',
166	      \ 'abbr': 'wrd',
167	      \ 'menu': 'extra text',
168	      \ 'info': 'words are cool',
169	      \ 'kind': 'W',
170	      \ 'user_data': 'test'
171	    \ }
172	  \ ]
173	\ }
174endfunc
175
176func s:CompleteDone_CheckCompletedItemNone()
177  let s:called_completedone = 1
178endfunc
179
180func s:CompleteDone_CheckCompletedItemDict(pre)
181  call assert_equal( 'aword',          v:completed_item[ 'word' ] )
182  call assert_equal( 'wrd',            v:completed_item[ 'abbr' ] )
183  call assert_equal( 'extra text',     v:completed_item[ 'menu' ] )
184  call assert_equal( 'words are cool', v:completed_item[ 'info' ] )
185  call assert_equal( 'W',              v:completed_item[ 'kind' ] )
186  call assert_equal( 'test',           v:completed_item[ 'user_data' ] )
187
188  if a:pre
189    call assert_equal('function', complete_info().mode)
190  endif
191
192  let s:called_completedone = 1
193endfunc
194
195func Test_CompleteDoneNone()
196  au CompleteDone * :call <SID>CompleteDone_CheckCompletedItemNone()
197  let oldline = join(map(range(&columns), 'nr2char(screenchar(&lines-1, v:val+1))'), '')
198
199  set completefunc=<SID>CompleteDone_CompleteFuncNone
200  execute "normal a\<C-X>\<C-U>\<C-Y>"
201  set completefunc&
202  let newline = join(map(range(&columns), 'nr2char(screenchar(&lines-1, v:val+1))'), '')
203
204  call assert_true(s:called_completedone)
205  call assert_equal(oldline, newline)
206
207  let s:called_completedone = 0
208  au! CompleteDone
209endfunc
210
211func Test_CompleteDoneDict()
212  au CompleteDonePre * :call <SID>CompleteDone_CheckCompletedItemDict(1)
213  au CompleteDone * :call <SID>CompleteDone_CheckCompletedItemDict(0)
214
215  set completefunc=<SID>CompleteDone_CompleteFuncDict
216  execute "normal a\<C-X>\<C-U>\<C-Y>"
217  set completefunc&
218
219  call assert_equal('test', v:completed_item[ 'user_data' ])
220  call assert_true(s:called_completedone)
221
222  let s:called_completedone = 0
223  au! CompleteDone
224endfunc
225
226func s:CompleteDone_CompleteFuncDictNoUserData(findstart, base)
227  if a:findstart
228    return 0
229  endif
230
231  return {
232	  \ 'words': [
233	    \ {
234	      \ 'word': 'aword',
235	      \ 'abbr': 'wrd',
236	      \ 'menu': 'extra text',
237	      \ 'info': 'words are cool',
238	      \ 'kind': 'W',
239	      \ 'user_data': ['one', 'two'],
240	    \ }
241	  \ ]
242	\ }
243endfunc
244
245func s:CompleteDone_CheckCompletedItemDictNoUserData()
246  call assert_equal( 'aword',          v:completed_item[ 'word' ] )
247  call assert_equal( 'wrd',            v:completed_item[ 'abbr' ] )
248  call assert_equal( 'extra text',     v:completed_item[ 'menu' ] )
249  call assert_equal( 'words are cool', v:completed_item[ 'info' ] )
250  call assert_equal( 'W',              v:completed_item[ 'kind' ] )
251  call assert_equal( ['one', 'two'],   v:completed_item[ 'user_data' ] )
252
253  let s:called_completedone = 1
254endfunc
255
256func Test_CompleteDoneDictNoUserData()
257  au CompleteDone * :call <SID>CompleteDone_CheckCompletedItemDictNoUserData()
258
259  set completefunc=<SID>CompleteDone_CompleteFuncDictNoUserData
260  execute "normal a\<C-X>\<C-U>\<C-Y>"
261  set completefunc&
262
263  call assert_equal(['one', 'two'], v:completed_item[ 'user_data' ])
264  call assert_true(s:called_completedone)
265
266  let s:called_completedone = 0
267  au! CompleteDone
268endfunc
269
270func s:CompleteDone_CompleteFuncList(findstart, base)
271  if a:findstart
272    return 0
273  endif
274
275  return [ 'aword' ]
276endfunc
277
278func s:CompleteDone_CheckCompletedItemList()
279  call assert_equal( 'aword', v:completed_item[ 'word' ] )
280  call assert_equal( '',      v:completed_item[ 'abbr' ] )
281  call assert_equal( '',      v:completed_item[ 'menu' ] )
282  call assert_equal( '',      v:completed_item[ 'info' ] )
283  call assert_equal( '',      v:completed_item[ 'kind' ] )
284  call assert_equal( '',      v:completed_item[ 'user_data' ] )
285
286  let s:called_completedone = 1
287endfunc
288
289func Test_CompleteDoneList()
290  au CompleteDone * :call <SID>CompleteDone_CheckCompletedItemList()
291
292  set completefunc=<SID>CompleteDone_CompleteFuncList
293  execute "normal a\<C-X>\<C-U>\<C-Y>"
294  set completefunc&
295
296  call assert_equal('', v:completed_item[ 'user_data' ])
297  call assert_true(s:called_completedone)
298
299  let s:called_completedone = 0
300  au! CompleteDone
301endfunc
302
303func Test_CompleteDone_undo()
304  au CompleteDone * call append(0, "prepend1")
305  new
306  call setline(1, ["line1", "line2"])
307  call feedkeys("Go\<C-X>\<C-N>\<CR>\<ESC>", "tx")
308  call assert_equal(["prepend1", "line1", "line2", "line1", ""],
309              \     getline(1, '$'))
310  undo
311  call assert_equal(["line1", "line2"], getline(1, '$'))
312  bwipe!
313  au! CompleteDone
314endfunc
315
316" Check that when using feedkeys() typeahead does not interrupt searching for
317" completions.
318func Test_compl_feedkeys()
319  new
320  set completeopt=menuone,noselect
321  call feedkeys("ajump ju\<C-X>\<C-N>\<C-P>\<ESC>", "tx")
322  call assert_equal("jump jump", getline(1))
323  bwipe!
324  set completeopt&
325endfunc
326
327func Test_compl_in_cmdwin()
328  set wildmenu wildchar=<Tab>
329  com! -nargs=1 -complete=command GetInput let input = <q-args>
330  com! -buffer TestCommand echo 'TestCommand'
331
332  let input = ''
333  call feedkeys("q:iGetInput T\<C-x>\<C-v>\<CR>", 'tx!')
334  call assert_equal('TestCommand', input)
335
336  let input = ''
337  call feedkeys("q::GetInput T\<Tab>\<CR>:q\<CR>", 'tx!')
338  call assert_equal('T', input)
339
340  delcom TestCommand
341  delcom GetInput
342  set wildmenu& wildchar&
343endfunc
344
345" Test for insert path completion with completeslash option
346func Test_ins_completeslash()
347  CheckMSWindows
348
349  call mkdir('Xdir')
350  let orig_shellslash = &shellslash
351  set cpt&
352  new
353
354  set noshellslash
355
356  set completeslash=
357  exe "normal oXd\<C-X>\<C-F>"
358  call assert_equal('Xdir\', getline('.'))
359
360  set completeslash=backslash
361  exe "normal oXd\<C-X>\<C-F>"
362  call assert_equal('Xdir\', getline('.'))
363
364  set completeslash=slash
365  exe "normal oXd\<C-X>\<C-F>"
366  call assert_equal('Xdir/', getline('.'))
367
368  set shellslash
369
370  set completeslash=
371  exe "normal oXd\<C-X>\<C-F>"
372  call assert_equal('Xdir/', getline('.'))
373
374  set completeslash=backslash
375  exe "normal oXd\<C-X>\<C-F>"
376  call assert_equal('Xdir\', getline('.'))
377
378  set completeslash=slash
379  exe "normal oXd\<C-X>\<C-F>"
380  call assert_equal('Xdir/', getline('.'))
381  %bw!
382  call delete('Xdir', 'rf')
383
384  set noshellslash
385  set completeslash=slash
386  call assert_true(stridx(globpath(&rtp, 'syntax/*.vim', 1, 1)[0], '\') != -1)
387
388  let &shellslash = orig_shellslash
389  set completeslash=
390endfunc
391
392func Test_pum_with_folds_two_tabs()
393  CheckScreendump
394
395  let lines =<< trim END
396    set fdm=marker
397    call setline(1, ['" x {{{1', '" a some text'])
398    call setline(3, range(&lines)->map({_, val -> '" a' .. val}))
399    norm! zm
400    tab sp
401    call feedkeys('2Gzv', 'xt')
402    call feedkeys("0fa", 'xt')
403  END
404
405  call writefile(lines, 'Xpumscript')
406  let buf = RunVimInTerminal('-S Xpumscript', #{rows: 10})
407  call TermWait(buf, 50)
408  call term_sendkeys(buf, "a\<C-N>")
409  call VerifyScreenDump(buf, 'Test_pum_with_folds_two_tabs', {})
410
411  call term_sendkeys(buf, "\<Esc>")
412  call StopVimInTerminal(buf)
413  call delete('Xpumscript')
414endfunc
415
416func Test_pum_with_preview_win()
417  CheckScreendump
418
419  let lines =<< trim END
420      funct Omni_test(findstart, base)
421	if a:findstart
422	  return col(".") - 1
423	endif
424	return [#{word: "one", info: "1info"}, #{word: "two", info: "2info"}, #{word: "three", info: "3info"}]
425      endfunc
426      set omnifunc=Omni_test
427      set completeopt+=longest
428  END
429
430  call writefile(lines, 'Xpreviewscript')
431  let buf = RunVimInTerminal('-S Xpreviewscript', #{rows: 12})
432  call TermWait(buf, 50)
433  call term_sendkeys(buf, "Gi\<C-X>\<C-O>")
434  call TermWait(buf, 100)
435  call term_sendkeys(buf, "\<C-N>")
436  call VerifyScreenDump(buf, 'Test_pum_with_preview_win', {})
437
438  call term_sendkeys(buf, "\<Esc>")
439  call StopVimInTerminal(buf)
440  call delete('Xpreviewscript')
441endfunc
442
443" Test for inserting the tag search pattern in insert mode
444func Test_ins_compl_tag_sft()
445  call writefile([
446        \ "!_TAG_FILE_ENCODING\tutf-8\t//",
447        \ "first\tXfoo\t/^int first() {}$/",
448        \ "second\tXfoo\t/^int second() {}$/",
449        \ "third\tXfoo\t/^int third() {}$/"],
450        \ 'Xtags')
451  set tags=Xtags
452  let code =<< trim [CODE]
453    int first() {}
454    int second() {}
455    int third() {}
456  [CODE]
457  call writefile(code, 'Xfoo')
458
459  enew
460  set showfulltag
461  exe "normal isec\<C-X>\<C-]>\<C-N>\<CR>"
462  call assert_equal('int second() {}', getline(1))
463  set noshowfulltag
464
465  call delete('Xtags')
466  call delete('Xfoo')
467  set tags&
468  %bwipe!
469endfunc
470
471" Test for 'completefunc' deleting text
472func Test_completefunc_error()
473  new
474  " delete text when called for the first time
475  func CompleteFunc(findstart, base)
476    if a:findstart == 1
477      normal dd
478      return col('.') - 1
479    endif
480    return ['a', 'b']
481  endfunc
482  set completefunc=CompleteFunc
483  call setline(1, ['', 'abcd', ''])
484  call assert_fails('exe "normal 2G$a\<C-X>\<C-U>"', 'E840:')
485
486  " delete text when called for the second time
487  func CompleteFunc2(findstart, base)
488    if a:findstart == 1
489      return col('.') - 1
490    endif
491    normal dd
492    return ['a', 'b']
493  endfunc
494  set completefunc=CompleteFunc2
495  call setline(1, ['', 'abcd', ''])
496  call assert_fails('exe "normal 2G$a\<C-X>\<C-U>"', 'E578:')
497
498  " Jump to a different window from the complete function
499  " TODO: The following test causes an ASAN failure. Once this issue is
500  " addressed, enable the following test.
501  "func! CompleteFunc(findstart, base)
502  "  if a:findstart == 1
503  "    return col('.') - 1
504  "  endif
505  "  wincmd p
506  "  return ['a', 'b']
507  "endfunc
508  "set completefunc=CompleteFunc
509  "new
510  "call assert_fails('exe "normal a\<C-X>\<C-U>"', 'E839:')
511  "close!
512
513  set completefunc&
514  delfunc CompleteFunc
515  delfunc CompleteFunc2
516  close!
517endfunc
518
519" Test for returning non-string values from 'completefunc'
520func Test_completefunc_invalid_data()
521  new
522  func! CompleteFunc(findstart, base)
523    if a:findstart == 1
524      return col('.') - 1
525    endif
526    return [{}, '', 'moon']
527  endfunc
528  set completefunc=CompleteFunc
529  exe "normal i\<C-X>\<C-U>"
530  call assert_equal('moon', getline(1))
531  set completefunc&
532  close!
533endfunc
534
535" Test for errors in using complete() function
536func Test_complete_func_error()
537  call assert_fails('call complete(1, ["a"])', 'E785:')
538  func ListColors()
539    call complete(col('.'), "blue")
540  endfunc
541  call assert_fails('exe "normal i\<C-R>=ListColors()\<CR>"', 'E474:')
542  func ListMonths()
543    call complete(col('.'), test_null_list())
544  endfunc
545  call assert_fails('exe "normal i\<C-R>=ListMonths()\<CR>"', 'E474:')
546  delfunc ListColors
547  delfunc ListMonths
548  call assert_fails('call complete_info({})', 'E714:')
549  call assert_equal([], complete_info(['items']).items)
550endfunc
551
552" Test for completing words following a completed word in a line
553func Test_complete_wrapscan()
554  " complete words from another buffer
555  new
556  call setline(1, ['one two', 'three four'])
557  new
558  setlocal complete=w
559  call feedkeys("itw\<C-N>\<C-X>\<C-N>\<C-X>\<C-N>\<C-X>\<C-N>", 'xt')
560  call assert_equal('two three four', getline(1))
561  close!
562  " complete words from the current buffer
563  setlocal complete=.
564  %d
565  call setline(1, ['one two', ''])
566  call cursor(2, 1)
567  call feedkeys("ion\<C-N>\<C-X>\<C-N>\<C-X>\<C-N>\<C-X>\<C-N>", 'xt')
568  call assert_equal('one two one two', getline(2))
569  close!
570endfunc
571
572" Test for completing special characters
573func Test_complete_special_chars()
574  new
575  call setline(1, 'int .*[-\^$ func float')
576  call feedkeys("oin\<C-X>\<C-P>\<C-X>\<C-P>\<C-X>\<C-P>", 'xt')
577  call assert_equal('int .*[-\^$ func float', getline(2))
578  close!
579endfunc
580
581" Test for completion when text is wrapped across lines.
582func Test_complete_across_line()
583  new
584  call setline(1, ['red green blue', 'one two three'])
585  setlocal textwidth=20
586  exe "normal 2G$a re\<C-X>\<C-P>\<C-X>\<C-P>\<C-X>\<C-P>\<C-X>\<C-P>"
587  call assert_equal(['one two three red', 'green blue one'], getline(2, '$'))
588  close!
589endfunc
590
591" Test for using CTRL-L to add one character when completing matching
592func Test_complete_add_onechar()
593  new
594  call setline(1, ['wool', 'woodwork'])
595  call feedkeys("Gowoo\<C-P>\<C-P>\<C-P>\<C-L>f", 'xt')
596  call assert_equal('woof', getline(3))
597
598  " use 'ignorecase' and backspace to erase characters from the prefix string
599  " and then add letters using CTRL-L
600  %d
601  set ignorecase backspace=2
602  setlocal complete=.
603  call setline(1, ['workhorse', 'workload'])
604  normal Go
605  exe "normal aWOR\<C-P>\<bs>\<bs>\<bs>\<bs>\<bs>\<bs>\<C-L>r\<C-L>\<C-L>"
606  call assert_equal('workh', getline(3))
607  set ignorecase& backspace&
608  close!
609endfunc
610
611" Test insert completion with 'cindent' (adjust the indent)
612func Test_complete_with_cindent()
613  new
614  setlocal cindent
615  call setline(1, ['if (i == 1)', "    j = 2;"])
616  exe "normal Go{\<CR>i\<C-X>\<C-L>\<C-X>\<C-L>\<CR>}"
617  call assert_equal(['{', "\tif (i == 1)", "\t\tj = 2;", '}'], getline(3, '$'))
618
619  %d
620  call setline(1, ['when while', '{', ''])
621  setlocal cinkeys+==while
622  exe "normal Giwh\<C-P> "
623  call assert_equal("\twhile ", getline('$'))
624  close!
625endfunc
626
627" Test for <CTRL-X> <CTRL-V> completion. Complete commands and functions
628func Test_complete_cmdline()
629  new
630  exe "normal icaddb\<C-X>\<C-V>"
631  call assert_equal('caddbuffer', getline(1))
632  exe "normal ocall getqf\<C-X>\<C-V>"
633  call assert_equal('call getqflist(', getline(2))
634  exe "normal oabcxyz(\<C-X>\<C-V>"
635  call assert_equal('abcxyz(', getline(3))
636  close!
637endfunc
638
639" vim: shiftwidth=2 sts=2 expandtab
640