1" Test the :compiler command
2
3func Test_compiler()
4  if !executable('perl')
5    return
6  endif
7
8  " $LANG changes the output of Perl.
9  if $LANG != ''
10    unlet $LANG
11  endif
12
13  " %:S does not work properly with 'shellslash' set
14  let save_shellslash = &shellslash
15  set noshellslash
16
17  e Xfoo.pl
18  compiler perl
19  call assert_equal('perl', b:current_compiler)
20  call assert_fails('let g:current_compiler', 'E121:')
21
22  call setline(1, ['#!/usr/bin/perl -w', 'use strict;', 'my $foo=1'])
23  w!
24  call feedkeys(":make\<CR>\<CR>", 'tx')
25  call assert_fails('clist', 'E42:')
26
27  call setline(1, ['#!/usr/bin/perl -w', 'use strict;', '$foo=1'])
28  w!
29  call feedkeys(":make\<CR>\<CR>", 'tx')
30  let a=execute('clist')
31  call assert_match("\n 1 Xfoo.pl:3: Global symbol \"\$foo\" "
32  \ .               "requires explicit package name", a)
33
34  let &shellslash = save_shellslash
35  call delete('Xfoo.pl')
36  bw!
37endfunc
38
39func Test_compiler_without_arg()
40  let a=split(execute('compiler'))
41  call assert_match('^.*runtime/compiler/ant.vim$',   a[0])
42  call assert_match('^.*runtime/compiler/bcc.vim$',   a[1])
43  call assert_match('^.*runtime/compiler/xmlwf.vim$', a[-1])
44endfunc
45
46func Test_compiler_completion()
47  call feedkeys(":compiler \<C-A>\<C-B>\"\<CR>", 'tx')
48  call assert_match('^"compiler ant bcc .* xmlwf$', @:)
49
50  call feedkeys(":compiler p\<C-A>\<C-B>\"\<CR>", 'tx')
51  call assert_equal('"compiler pbx perl php pylint pyunit', @:)
52
53  call feedkeys(":compiler! p\<C-A>\<C-B>\"\<CR>", 'tx')
54  call assert_equal('"compiler! pbx perl php pylint pyunit', @:)
55endfunc
56
57func Test_compiler_error()
58  call assert_fails('compiler doesnotexist', 'E666:')
59endfunc
60