1" Tests for the +clientserver feature.
2
3source check.vim
4CheckFeature job
5
6if !has('clientserver')
7  call assert_fails('call remote_startserver("local")', 'E942:')
8endif
9
10CheckFeature clientserver
11
12source shared.vim
13
14func Check_X11_Connection()
15  if has('x11')
16    CheckEnv DISPLAY
17    try
18      call remote_send('xxx', '')
19    catch
20      if v:exception =~ 'E240:'
21        throw 'Skipped: no connection to the X server'
22      endif
23      " ignore other errors
24    endtry
25  endif
26endfunc
27
28func Test_client_server()
29  let cmd = GetVimCommand()
30  if cmd == ''
31    throw 'GetVimCommand() failed'
32  endif
33  call Check_X11_Connection()
34
35  let name = 'XVIMTEST'
36  let cmd .= ' --servername ' . name
37  let job = job_start(cmd, {'stoponexit': 'kill', 'out_io': 'null'})
38  call WaitForAssert({-> assert_equal("run", job_status(job))})
39
40  " Takes a short while for the server to be active.
41  " When using valgrind it takes much longer.
42  call WaitForAssert({-> assert_match(name, serverlist())})
43
44  if !has('win32')
45    if RunVim([], [], '--serverlist >Xtest_serverlist')
46      let lines = readfile('Xtest_serverlist')
47      call assert_true(index(lines, 'XVIMTEST') >= 0)
48    endif
49    call delete('Xtest_serverlist')
50  endif
51
52  eval name->remote_foreground()
53
54  call remote_send(name, ":let testvar = 'yes'\<CR>")
55  call WaitFor('remote_expr("' . name . '", "exists(\"testvar\") ? testvar : \"\"", "", 1) == "yes"')
56  call assert_equal('yes', remote_expr(name, "testvar", "", 2))
57  call assert_fails("let x=remote_expr(name, '2+x')", 'E449:')
58  call assert_fails("let x=remote_expr('[], '2+2')", 'E116:')
59
60  if has('unix') && has('gui') && !has('gui_running')
61    " Running in a terminal and the GUI is available: Tell the server to open
62    " the GUI and check that the remote command still works.
63    " Need to wait for the GUI to start up, otherwise the send hangs in trying
64    " to send to the terminal window.
65    if has('gui_athena') || has('gui_motif')
66      " For those GUIs, ignore the 'failed to create input context' error.
67      call remote_send(name, ":call test_ignore_error('E285') | gui -f\<CR>")
68    else
69      call remote_send(name, ":gui -f\<CR>")
70    endif
71    " Wait for the server to be up and answering requests.
72    " When using valgrind this can be very, very slow.
73    sleep 1
74    call WaitForAssert({-> assert_match('\d', name->remote_expr("v:version", "", 1))}, 10000)
75
76    call remote_send(name, ":let testvar = 'maybe'\<CR>")
77    call WaitForAssert({-> assert_equal('maybe', remote_expr(name, "testvar", "", 2))})
78  endif
79
80  call assert_fails('call remote_send("XXX", ":let testvar = ''yes''\<CR>")', 'E241:')
81
82  call writefile(['one'], 'Xclientfile')
83  let cmd = GetVimProg() .. ' --servername ' .. name .. ' --remote Xclientfile'
84  call system(cmd)
85  call WaitForAssert({-> assert_equal('Xclientfile', remote_expr(name, "bufname()", "", 2))})
86  call WaitForAssert({-> assert_equal('one', remote_expr(name, "getline(1)", "", 2))})
87  call writefile(['one', 'two'], 'Xclientfile')
88  call system(cmd)
89  call WaitForAssert({-> assert_equal('two', remote_expr(name, "getline(2)", "", 2))})
90  call delete('Xclientfile')
91
92  " Expression evaluated locally.
93  if v:servername == ''
94    eval 'MYSELF'->remote_startserver()
95    " May get MYSELF1 when running the test again.
96    call assert_match('MYSELF', v:servername)
97    call assert_fails("call remote_startserver('MYSELF')", 'E941:')
98  endif
99  let g:testvar = 'myself'
100  call assert_equal('myself', remote_expr(v:servername, 'testvar'))
101  call remote_send(v:servername, ":let g:testvar2 = 75\<CR>")
102  call feedkeys('', 'x')
103  call assert_equal(75, g:testvar2)
104  call assert_fails('let v = remote_expr(v:servername, "/2")', ['E15:.*/2'])
105
106  call remote_send(name, ":call server2client(expand('<client>'), 'got it')\<CR>", 'g:myserverid')
107  call assert_equal('got it', g:myserverid->remote_read(2))
108
109  call remote_send(name, ":eval expand('<client>')->server2client('another')\<CR>", 'g:myserverid')
110  let peek_result = 'nothing'
111  let r = g:myserverid->remote_peek('peek_result')
112  " unpredictable whether the result is already available.
113  if r > 0
114    call assert_equal('another', peek_result)
115  elseif r == 0
116    call assert_equal('nothing', peek_result)
117  else
118    call assert_report('remote_peek() failed')
119  endif
120  let g:peek_result = 'empty'
121  call WaitFor('remote_peek(g:myserverid, "g:peek_result") > 0')
122  call assert_equal('another', g:peek_result)
123  call assert_equal('another', remote_read(g:myserverid, 2))
124
125  if !has('gui_running')
126    " In GUI vim, the following tests display a dialog box
127
128    let cmd = GetVimProg() .. ' --servername ' .. name
129
130    " Run a separate instance to send a command to the server
131    call remote_expr(name, 'execute("only")')
132    call system(cmd .. ' --remote-send ":new Xfile<CR>"')
133    call assert_equal('2', remote_expr(name, 'winnr("$")'))
134    call assert_equal('Xfile', remote_expr(name, 'winbufnr(1)->bufname()'))
135    call remote_expr(name, 'execute("only")')
136
137    " Invoke a remote-expr. On MS-Windows, the returned value has a carriage
138    " return.
139    let l = system(cmd .. ' --remote-expr "2 + 2"')
140    call assert_equal(['4'], split(l, "\n"))
141
142    " Edit multiple files using --remote
143    call system(cmd .. ' --remote Xfile1 Xfile2 Xfile3')
144    call assert_match(".*Xfile1\n.*Xfile2\n.*Xfile3\n", remote_expr(name, 'argv()'))
145    eval name->remote_send(":%bw!\<CR>")
146
147    " Edit files in separate tab pages
148    call system(cmd .. ' --remote-tab Xfile1 Xfile2 Xfile3')
149    call WaitForAssert({-> assert_equal('3', remote_expr(name, 'tabpagenr("$")'))})
150    call assert_match('.*\<Xfile2', remote_expr(name, 'bufname(tabpagebuflist(2)[0])'))
151    eval name->remote_send(":%bw!\<CR>")
152
153    " Edit a file using --remote-wait
154    eval name->remote_send(":source $VIMRUNTIME/plugin/rrhelper.vim\<CR>")
155    call system(cmd .. ' --remote-wait +enew Xfile1')
156    call assert_match('.*\<Xfile1', remote_expr(name, 'bufname("#")'))
157    eval name->remote_send(":%bw!\<CR>")
158
159    " Edit files using --remote-tab-wait
160    call system(cmd .. ' --remote-tabwait +tabonly\|enew Xfile1 Xfile2')
161    call assert_equal('1', remote_expr(name, 'tabpagenr("$")'))
162    eval name->remote_send(":%bw!\<CR>")
163
164    " Error cases
165    if v:lang == "C" || v:lang =~ '^[Ee]n'
166      let l = split(system(cmd .. ' --remote +pwd'), "\n")
167      call assert_equal("Argument missing after: \"+pwd\"", l[1])
168    endif
169    let l = system(cmd .. ' --remote-expr "abcd"')
170    call assert_match('^E449: ', l)
171  endif
172
173  eval name->remote_send(":%bw!\<CR>")
174  eval name->remote_send(":qa!\<CR>")
175  try
176    call WaitForAssert({-> assert_equal("dead", job_status(job))})
177  finally
178    if job_status(job) != 'dead'
179      call assert_report('Server did not exit')
180      call job_stop(job, 'kill')
181    endif
182  endtry
183
184  call assert_fails('call remote_startserver([])', 'E730:')
185  call assert_fails("let x = remote_peek([])", 'E730:')
186  call assert_fails("let x = remote_read('vim10')",
187        \ has('unix') ? ['E573:.*vim10'] : 'E277:')
188  call assert_fails("call server2client('abc', 'xyz')",
189        \ has('unix') ? ['E573:.*abc'] : 'E258:')
190endfunc
191
192" Uncomment this line to get a debugging log
193" call ch_logfile('channellog', 'w')
194
195" vim: shiftwidth=2 sts=2 expandtab
196