1" Tests for the +clientserver feature.
2
3source check.vim
4CheckFeature job
5
6if !has('clientserver')
7  call assert_fails('call remote_startserver("local")', 'E942:')
8endif
9
10CheckFeature clientserver
11
12source shared.vim
13
14func Check_X11_Connection()
15  if has('x11')
16    if empty($DISPLAY)
17      throw 'Skipped: $DISPLAY is not set'
18    endif
19    try
20      call remote_send('xxx', '')
21    catch
22      if v:exception =~ 'E240:'
23        throw 'Skipped: no connection to the X server'
24      endif
25      " ignore other errors
26    endtry
27  endif
28endfunc
29
30func Test_client_server()
31  let cmd = GetVimCommand()
32  if cmd == ''
33    throw 'GetVimCommand() failed'
34  endif
35  call Check_X11_Connection()
36
37  let name = 'XVIMTEST'
38  let cmd .= ' --servername ' . name
39  let job = job_start(cmd, {'stoponexit': 'kill', 'out_io': 'null'})
40  call WaitForAssert({-> assert_equal("run", job_status(job))})
41
42  " Takes a short while for the server to be active.
43  " When using valgrind it takes much longer.
44  call WaitForAssert({-> assert_match(name, serverlist())})
45
46  eval name->remote_foreground()
47
48  call remote_send(name, ":let testvar = 'yes'\<CR>")
49  call WaitFor('remote_expr("' . name . '", "exists(\"testvar\") ? testvar : \"\"", "", 1) == "yes"')
50  call assert_equal('yes', remote_expr(name, "testvar", "", 2))
51  call assert_fails("let x=remote_expr(name, '2+x')", 'E449:')
52  call assert_fails("let x=remote_expr('[], '2+2')", 'E116:')
53
54  if has('unix') && has('gui') && !has('gui_running')
55    " Running in a terminal and the GUI is available: Tell the server to open
56    " the GUI and check that the remote command still works.
57    " Need to wait for the GUI to start up, otherwise the send hangs in trying
58    " to send to the terminal window.
59    if has('gui_athena') || has('gui_motif')
60      " For those GUIs, ignore the 'failed to create input context' error.
61      call remote_send(name, ":call test_ignore_error('E285') | gui -f\<CR>")
62    else
63      call remote_send(name, ":gui -f\<CR>")
64    endif
65    " Wait for the server to be up and answering requests.
66    " When using valgrind this can be very, very slow.
67    sleep 1
68    call WaitForAssert({-> assert_match('\d', name->remote_expr("v:version", "", 1))}, 10000)
69
70    call remote_send(name, ":let testvar = 'maybe'\<CR>")
71    call WaitForAssert({-> assert_equal('maybe', remote_expr(name, "testvar", "", 2))})
72  endif
73
74  call assert_fails('call remote_send("XXX", ":let testvar = ''yes''\<CR>")', 'E241:')
75
76  call writefile(['one'], 'Xclientfile')
77  let cmd = GetVimProg() .. ' --servername ' .. name .. ' --remote Xclientfile'
78  call system(cmd)
79  call WaitForAssert({-> assert_equal('Xclientfile', remote_expr(name, "bufname()", "", 2))})
80  call WaitForAssert({-> assert_equal('one', remote_expr(name, "getline(1)", "", 2))})
81  call writefile(['one', 'two'], 'Xclientfile')
82  call system(cmd)
83  call WaitForAssert({-> assert_equal('two', remote_expr(name, "getline(2)", "", 2))})
84  call delete('Xclientfile')
85
86  " Expression evaluated locally.
87  if v:servername == ''
88    eval 'MYSELF'->remote_startserver()
89    " May get MYSELF1 when running the test again.
90    call assert_match('MYSELF', v:servername)
91    call assert_fails("call remote_startserver('MYSELF')", 'E941:')
92  endif
93  let g:testvar = 'myself'
94  call assert_equal('myself', remote_expr(v:servername, 'testvar'))
95  call remote_send(v:servername, ":let g:testvar2 = 75\<CR>")
96  call feedkeys('', 'x')
97  call assert_equal(75, g:testvar2)
98  call assert_fails('let v = remote_expr(v:servername, "/2")', ['E15:.*/2'])
99
100  call remote_send(name, ":call server2client(expand('<client>'), 'got it')\<CR>", 'g:myserverid')
101  call assert_equal('got it', g:myserverid->remote_read(2))
102
103  call remote_send(name, ":eval expand('<client>')->server2client('another')\<CR>", 'g:myserverid')
104  let peek_result = 'nothing'
105  let r = g:myserverid->remote_peek('peek_result')
106  " unpredictable whether the result is already available.
107  if r > 0
108    call assert_equal('another', peek_result)
109  elseif r == 0
110    call assert_equal('nothing', peek_result)
111  else
112    call assert_report('remote_peek() failed')
113  endif
114  let g:peek_result = 'empty'
115  call WaitFor('remote_peek(g:myserverid, "g:peek_result") > 0')
116  call assert_equal('another', g:peek_result)
117  call assert_equal('another', remote_read(g:myserverid, 2))
118
119  if !has('gui_running')
120    " In GUI vim, the following tests display a dialog box
121
122    let cmd = GetVimProg() .. ' --servername ' .. name
123
124    " Run a separate instance to send a command to the server
125    call remote_expr(name, 'execute("only")')
126    call system(cmd .. ' --remote-send ":new Xfile<CR>"')
127    call assert_equal('2', remote_expr(name, 'winnr("$")'))
128    call assert_equal('Xfile', remote_expr(name, 'winbufnr(1)->bufname()'))
129    call remote_expr(name, 'execute("only")')
130
131    " Invoke a remote-expr. On MS-Windows, the returned value has a carriage
132    " return.
133    let l = system(cmd .. ' --remote-expr "2 + 2"')
134    call assert_equal(['4'], split(l, "\n"))
135
136    " Edit multiple files using --remote
137    call system(cmd .. ' --remote Xfile1 Xfile2 Xfile3')
138    call assert_match(".*Xfile1\n.*Xfile2\n.*Xfile3\n", remote_expr(name, 'argv()'))
139    eval name->remote_send(":%bw!\<CR>")
140
141    " Edit files in separate tab pages
142    call system(cmd .. ' --remote-tab Xfile1 Xfile2 Xfile3')
143    call WaitForAssert({-> assert_equal('3', remote_expr(name, 'tabpagenr("$")'))})
144    call assert_match('.*\<Xfile2', remote_expr(name, 'bufname(tabpagebuflist(2)[0])'))
145    eval name->remote_send(":%bw!\<CR>")
146
147    " Edit a file using --remote-wait
148    eval name->remote_send(":source $VIMRUNTIME/plugin/rrhelper.vim\<CR>")
149    call system(cmd .. ' --remote-wait +enew Xfile1')
150    call assert_match('.*\<Xfile1', remote_expr(name, 'bufname("#")'))
151    eval name->remote_send(":%bw!\<CR>")
152
153    " Edit files using --remote-tab-wait
154    call system(cmd .. ' --remote-tabwait +tabonly\|enew Xfile1 Xfile2')
155    call assert_equal('1', remote_expr(name, 'tabpagenr("$")'))
156    eval name->remote_send(":%bw!\<CR>")
157
158    " Error cases
159    if v:lang == "C" || v:lang =~ '^[Ee]n'
160      let l = split(system(cmd .. ' --remote +pwd'), "\n")
161      call assert_equal("Argument missing after: \"+pwd\"", l[1])
162    endif
163    let l = system(cmd .. ' --remote-expr "abcd"')
164    call assert_match('^E449: ', l)
165  endif
166
167  eval name->remote_send(":%bw!\<CR>")
168  eval name->remote_send(":qa!\<CR>")
169  try
170    call WaitForAssert({-> assert_equal("dead", job_status(job))})
171  finally
172    if job_status(job) != 'dead'
173      call assert_report('Server did not exit')
174      call job_stop(job, 'kill')
175    endif
176  endtry
177
178  call assert_fails('call remote_startserver([])', 'E730:')
179  call assert_fails("let x = remote_peek([])", 'E730:')
180  call assert_fails("let x = remote_read('vim10')",
181        \ has('unix') ? ['E573:.*vim10'] : 'E277:')
182  call assert_fails("call server2client('abc', 'xyz')",
183        \ has('unix') ? ['E573:.*abc'] : 'E258:')
184endfunc
185
186" Uncomment this line to get a debugging log
187" call ch_logfile('channellog', 'w')
188
189" vim: shiftwidth=2 sts=2 expandtab
190