1" Tests for the +clientserver feature.
2
3source check.vim
4CheckFeature job
5CheckFeature clientserver
6
7source shared.vim
8
9func Check_X11_Connection()
10  if has('x11')
11    if empty($DISPLAY)
12      throw 'Skipped: $DISPLAY is not set'
13    endif
14    try
15      call remote_send('xxx', '')
16    catch
17      if v:exception =~ 'E240:'
18        throw 'Skipped: no connection to the X server'
19      endif
20      " ignore other errors
21    endtry
22  endif
23endfunc
24
25func Test_client_server()
26  let cmd = GetVimCommand()
27  if cmd == ''
28    return
29  endif
30  call Check_X11_Connection()
31
32  let name = 'XVIMTEST'
33  let cmd .= ' --servername ' . name
34  let job = job_start(cmd, {'stoponexit': 'kill', 'out_io': 'null'})
35  call WaitForAssert({-> assert_equal("run", job_status(job))})
36
37  " Takes a short while for the server to be active.
38  " When using valgrind it takes much longer.
39  call WaitForAssert({-> assert_match(name, serverlist())})
40
41  eval name->remote_foreground()
42
43  call remote_send(name, ":let testvar = 'yes'\<CR>")
44  call WaitFor('remote_expr("' . name . '", "exists(\"testvar\") ? testvar : \"\"", "", 1) == "yes"')
45  call assert_equal('yes', remote_expr(name, "testvar", "", 2))
46  call assert_fails("let x=remote_expr(name, '2+x')", 'E449:')
47  call assert_fails("let x=remote_expr('[], '2+2')", 'E116:')
48
49  if has('unix') && has('gui') && !has('gui_running')
50    " Running in a terminal and the GUI is available: Tell the server to open
51    " the GUI and check that the remote command still works.
52    " Need to wait for the GUI to start up, otherwise the send hangs in trying
53    " to send to the terminal window.
54    if has('gui_athena') || has('gui_motif')
55      " For those GUIs, ignore the 'failed to create input context' error.
56      call remote_send(name, ":call test_ignore_error('E285') | gui -f\<CR>")
57    else
58      call remote_send(name, ":gui -f\<CR>")
59    endif
60    " Wait for the server to be up and answering requests.
61    sleep 100m
62    call WaitForAssert({-> assert_true(name->remote_expr("v:version", "", 1) != "")})
63
64    call remote_send(name, ":let testvar = 'maybe'\<CR>")
65    call WaitForAssert({-> assert_equal('maybe', remote_expr(name, "testvar", "", 2))})
66  endif
67
68  call assert_fails('call remote_send("XXX", ":let testvar = ''yes''\<CR>")', 'E241')
69
70  " Expression evaluated locally.
71  if v:servername == ''
72    eval 'MYSELF'->remote_startserver()
73    " May get MYSELF1 when running the test again.
74    call assert_match('MYSELF', v:servername)
75    call assert_fails("call remote_startserver('MYSELF')", 'E941:')
76  endif
77  let g:testvar = 'myself'
78  call assert_equal('myself', remote_expr(v:servername, 'testvar'))
79  call remote_send(v:servername, ":let g:testvar2 = 75\<CR>")
80  call feedkeys('', 'x')
81  call assert_equal(75, g:testvar2)
82  call assert_fails('let v = remote_expr(v:servername, "/2")', 'E449:')
83
84  call remote_send(name, ":call server2client(expand('<client>'), 'got it')\<CR>", 'g:myserverid')
85  call assert_equal('got it', g:myserverid->remote_read(2))
86
87  call remote_send(name, ":eval expand('<client>')->server2client('another')\<CR>", 'g:myserverid')
88  let peek_result = 'nothing'
89  let r = g:myserverid->remote_peek('peek_result')
90  " unpredictable whether the result is already available.
91  if r > 0
92    call assert_equal('another', peek_result)
93  elseif r == 0
94    call assert_equal('nothing', peek_result)
95  else
96    call assert_report('remote_peek() failed')
97  endif
98  let g:peek_result = 'empty'
99  call WaitFor('remote_peek(g:myserverid, "g:peek_result") > 0')
100  call assert_equal('another', g:peek_result)
101  call assert_equal('another', remote_read(g:myserverid, 2))
102
103  if !has('gui_running')
104    " In GUI vim, the following tests display a dialog box
105
106    let cmd = GetVimProg() .. ' --servername ' .. name
107
108    " Run a separate instance to send a command to the server
109    call remote_expr(name, 'execute("only")')
110    call system(cmd .. ' --remote-send ":new Xfile<CR>"')
111    call assert_equal('2', remote_expr(name, 'winnr("$")'))
112    call assert_equal('Xfile', remote_expr(name, 'winbufnr(1)->bufname()'))
113    call remote_expr(name, 'execute("only")')
114
115    " Invoke a remote-expr. On MS-Windows, the returned value has a carriage
116    " return.
117    let l = system(cmd .. ' --remote-expr "2 + 2"')
118    call assert_equal(['4'], split(l, "\n"))
119
120    " Edit multiple files using --remote
121    call system(cmd .. ' --remote Xfile1 Xfile2 Xfile3')
122    call assert_equal("Xfile1\nXfile2\nXfile3\n", remote_expr(name, 'argv()'))
123    eval name->remote_send(":%bw!\<CR>")
124
125    " Edit files in separate tab pages
126    call system(cmd .. ' --remote-tab Xfile1 Xfile2 Xfile3')
127    call assert_equal('3', remote_expr(name, 'tabpagenr("$")'))
128    call assert_equal('Xfile2', remote_expr(name, 'bufname(tabpagebuflist(2)[0])'))
129    eval name->remote_send(":%bw!\<CR>")
130
131    " Edit a file using --remote-wait
132    eval name->remote_send(":source $VIMRUNTIME/plugin/rrhelper.vim\<CR>")
133    call system(cmd .. ' --remote-wait +enew Xfile1')
134    call assert_equal("Xfile1", remote_expr(name, 'bufname("#")'))
135    eval name->remote_send(":%bw!\<CR>")
136
137    " Edit files using --remote-tab-wait
138    call system(cmd .. ' --remote-tabwait +tabonly\|enew Xfile1 Xfile2')
139    call assert_equal('1', remote_expr(name, 'tabpagenr("$")'))
140    eval name->remote_send(":%bw!\<CR>")
141
142    " Error cases
143    if v:lang == "C" || v:lang =~ '^[Ee]n'
144      let l = split(system(cmd .. ' --remote +pwd'), "\n")
145      call assert_equal("Argument missing after: \"+pwd\"", l[1])
146    endif
147    let l = system(cmd .. ' --remote-expr "abcd"')
148    call assert_match('^E449: ', l)
149  endif
150
151  eval name->remote_send(":%bw!\<CR>")
152  eval name->remote_send(":qa!\<CR>")
153  try
154    call WaitForAssert({-> assert_equal("dead", job_status(job))})
155  finally
156    if job_status(job) != 'dead'
157      call assert_report('Server did not exit')
158      call job_stop(job, 'kill')
159    endif
160  endtry
161
162  call assert_fails("let x = remote_peek([])", 'E730:')
163  call assert_fails("let x = remote_read('vim10')", 'E277:')
164endfunc
165
166" Uncomment this line to get a debugging log
167" call ch_logfile('channellog', 'w')
168
169" vim: shiftwidth=2 sts=2 expandtab
170