1" Tests for the +clientserver feature.
2
3if !has('job') || !has('clientserver')
4  finish
5endif
6
7source shared.vim
8
9func Test_client_server()
10  let cmd = GetVimCommand()
11  if cmd == ''
12    return
13  endif
14  if has('x11')
15    if empty($DISPLAY)
16      throw 'Skipped: $DISPLAY is not set'
17    endif
18    try
19      call remote_send('xxx', '')
20    catch
21      if v:exception =~ 'E240:'
22	throw 'Skipped: no connection to the X server'
23      endif
24      " ignore other errors
25    endtry
26  endif
27
28  let name = 'XVIMTEST'
29  let cmd .= ' --servername ' . name
30  let g:job = job_start(cmd, {'stoponexit': 'kill', 'out_io': 'null'})
31  call WaitFor('job_status(g:job) == "run"')
32  if job_status(g:job) != 'run'
33    call assert_report('Cannot run the Vim server')
34    return
35  endif
36
37  " Takes a short while for the server to be active.
38  call WaitFor('serverlist() =~ "' . name . '"')
39  call assert_match(name, serverlist())
40
41  call remote_foreground(name)
42
43  call remote_send(name, ":let testvar = 'yes'\<CR>")
44  call WaitFor('remote_expr("' . name . '", "testvar", "", 1) == "yes"')
45  call assert_equal('yes', remote_expr(name, "testvar", "", 2))
46
47  if has('unix') && has('gui') && !has('gui_running')
48    " Running in a terminal and the GUI is avaiable: Tell the server to open
49    " the GUI and check that the remote command still works.
50    " Need to wait for the GUI to start up, otherwise the send hangs in trying
51    " to send to the terminal window.
52    if has('gui_athena') || has('gui_motif')
53      " For those GUIs, ignore the 'failed to create input context' error.
54      call remote_send(name, ":call test_ignore_error('E285') | gui -f\<CR>")
55    else
56      call remote_send(name, ":gui -f\<CR>")
57    endif
58    " Wait for the server to be up and answering requests.
59    call WaitFor('remote_expr("' . name . '", "v:version", "", 1) != ""')
60
61    call remote_send(name, ":let testvar = 'maybe'\<CR>")
62    call WaitFor('remote_expr("' . name . '", "testvar", "", 1) == "maybe"')
63    call assert_equal('maybe', remote_expr(name, "testvar", "", 2))
64  endif
65
66  call assert_fails('call remote_send("XXX", ":let testvar = ''yes''\<CR>")', 'E241')
67
68  " Expression evaluated locally.
69  if v:servername == ''
70    call remote_startserver('MYSELF')
71    " May get MYSELF1 when running the test again.
72    call assert_match('MYSELF', v:servername)
73  endif
74  let g:testvar = 'myself'
75  call assert_equal('myself', remote_expr(v:servername, 'testvar'))
76
77  call remote_send(name, ":call server2client(expand('<client>'), 'got it')\<CR>", 'g:myserverid')
78  call assert_equal('got it', remote_read(g:myserverid, 2))
79
80  call remote_send(name, ":call server2client(expand('<client>'), 'another')\<CR>", 'g:myserverid')
81  let peek_result = 'nothing'
82  let r = remote_peek(g:myserverid, 'peek_result')
83  " unpredictable whether the result is already avaialble.
84  if r > 0
85    call assert_equal('another', peek_result)
86  elseif r == 0
87    call assert_equal('nothing', peek_result)
88  else
89    call assert_report('remote_peek() failed')
90  endif
91  let g:peek_result = 'empty'
92  call WaitFor('remote_peek(g:myserverid, "g:peek_result") > 0')
93  call assert_equal('another', g:peek_result)
94  call assert_equal('another', remote_read(g:myserverid, 2))
95
96  call remote_send(name, ":qa!\<CR>")
97  call WaitFor('job_status(g:job) == "dead"')
98  if job_status(g:job) != 'dead'
99    call assert_report('Server did not exit')
100    call job_stop(g:job, 'kill')
101  endif
102endfunc
103
104" Uncomment this line to get a debugging log
105" call ch_logfile('channellog', 'w')
106