1" Tests for the +clientserver feature.
2
3source check.vim
4CheckFeature job
5
6if !has('clientserver')
7  call assert_fails('call remote_startserver("local")', 'E942:')
8endif
9
10CheckFeature clientserver
11
12source shared.vim
13
14func Check_X11_Connection()
15  if has('x11')
16    if empty($DISPLAY)
17      throw 'Skipped: $DISPLAY is not set'
18    endif
19    try
20      call remote_send('xxx', '')
21    catch
22      if v:exception =~ 'E240:'
23        throw 'Skipped: no connection to the X server'
24      endif
25      " ignore other errors
26    endtry
27  endif
28endfunc
29
30func Test_client_server()
31  let cmd = GetVimCommand()
32  if cmd == ''
33    throw 'GetVimCommand() failed'
34  endif
35  call Check_X11_Connection()
36
37  let name = 'XVIMTEST'
38  let cmd .= ' --servername ' . name
39  let job = job_start(cmd, {'stoponexit': 'kill', 'out_io': 'null'})
40  call WaitForAssert({-> assert_equal("run", job_status(job))})
41
42  " Takes a short while for the server to be active.
43  " When using valgrind it takes much longer.
44  call WaitForAssert({-> assert_match(name, serverlist())})
45
46  eval name->remote_foreground()
47
48  call remote_send(name, ":let testvar = 'yes'\<CR>")
49  call WaitFor('remote_expr("' . name . '", "exists(\"testvar\") ? testvar : \"\"", "", 1) == "yes"')
50  call assert_equal('yes', remote_expr(name, "testvar", "", 2))
51  call assert_fails("let x=remote_expr(name, '2+x')", 'E449:')
52  call assert_fails("let x=remote_expr('[], '2+2')", 'E116:')
53
54  if has('unix') && has('gui') && !has('gui_running')
55    " Running in a terminal and the GUI is available: Tell the server to open
56    " the GUI and check that the remote command still works.
57    " Need to wait for the GUI to start up, otherwise the send hangs in trying
58    " to send to the terminal window.
59    if has('gui_athena') || has('gui_motif')
60      " For those GUIs, ignore the 'failed to create input context' error.
61      call remote_send(name, ":call test_ignore_error('E285') | gui -f\<CR>")
62    else
63      call remote_send(name, ":gui -f\<CR>")
64    endif
65    " Wait for the server to be up and answering requests.
66    sleep 100m
67    call WaitForAssert({-> assert_true(name->remote_expr("v:version", "", 1) != "")})
68
69    call remote_send(name, ":let testvar = 'maybe'\<CR>")
70    call WaitForAssert({-> assert_equal('maybe', remote_expr(name, "testvar", "", 2))})
71  endif
72
73  call assert_fails('call remote_send("XXX", ":let testvar = ''yes''\<CR>")', 'E241')
74
75  " Expression evaluated locally.
76  if v:servername == ''
77    eval 'MYSELF'->remote_startserver()
78    " May get MYSELF1 when running the test again.
79    call assert_match('MYSELF', v:servername)
80    call assert_fails("call remote_startserver('MYSELF')", 'E941:')
81  endif
82  let g:testvar = 'myself'
83  call assert_equal('myself', remote_expr(v:servername, 'testvar'))
84  call remote_send(v:servername, ":let g:testvar2 = 75\<CR>")
85  call feedkeys('', 'x')
86  call assert_equal(75, g:testvar2)
87  call assert_fails('let v = remote_expr(v:servername, "/2")', ['E15:.*/2'])
88
89  call remote_send(name, ":call server2client(expand('<client>'), 'got it')\<CR>", 'g:myserverid')
90  call assert_equal('got it', g:myserverid->remote_read(2))
91
92  call remote_send(name, ":eval expand('<client>')->server2client('another')\<CR>", 'g:myserverid')
93  let peek_result = 'nothing'
94  let r = g:myserverid->remote_peek('peek_result')
95  " unpredictable whether the result is already available.
96  if r > 0
97    call assert_equal('another', peek_result)
98  elseif r == 0
99    call assert_equal('nothing', peek_result)
100  else
101    call assert_report('remote_peek() failed')
102  endif
103  let g:peek_result = 'empty'
104  call WaitFor('remote_peek(g:myserverid, "g:peek_result") > 0')
105  call assert_equal('another', g:peek_result)
106  call assert_equal('another', remote_read(g:myserverid, 2))
107
108  if !has('gui_running')
109    " In GUI vim, the following tests display a dialog box
110
111    let cmd = GetVimProg() .. ' --servername ' .. name
112
113    " Run a separate instance to send a command to the server
114    call remote_expr(name, 'execute("only")')
115    call system(cmd .. ' --remote-send ":new Xfile<CR>"')
116    call assert_equal('2', remote_expr(name, 'winnr("$")'))
117    call assert_equal('Xfile', remote_expr(name, 'winbufnr(1)->bufname()'))
118    call remote_expr(name, 'execute("only")')
119
120    " Invoke a remote-expr. On MS-Windows, the returned value has a carriage
121    " return.
122    let l = system(cmd .. ' --remote-expr "2 + 2"')
123    call assert_equal(['4'], split(l, "\n"))
124
125    " Edit multiple files using --remote
126    call system(cmd .. ' --remote Xfile1 Xfile2 Xfile3')
127    call assert_equal("Xfile1\nXfile2\nXfile3\n", remote_expr(name, 'argv()'))
128    eval name->remote_send(":%bw!\<CR>")
129
130    " Edit files in separate tab pages
131    call system(cmd .. ' --remote-tab Xfile1 Xfile2 Xfile3')
132    call WaitForAssert({-> assert_equal('3', remote_expr(name, 'tabpagenr("$")'))})
133    call assert_equal('Xfile2', remote_expr(name, 'bufname(tabpagebuflist(2)[0])'))
134    eval name->remote_send(":%bw!\<CR>")
135
136    " Edit a file using --remote-wait
137    eval name->remote_send(":source $VIMRUNTIME/plugin/rrhelper.vim\<CR>")
138    call system(cmd .. ' --remote-wait +enew Xfile1')
139    call assert_equal("Xfile1", remote_expr(name, 'bufname("#")'))
140    eval name->remote_send(":%bw!\<CR>")
141
142    " Edit files using --remote-tab-wait
143    call system(cmd .. ' --remote-tabwait +tabonly\|enew Xfile1 Xfile2')
144    call assert_equal('1', remote_expr(name, 'tabpagenr("$")'))
145    eval name->remote_send(":%bw!\<CR>")
146
147    " Error cases
148    if v:lang == "C" || v:lang =~ '^[Ee]n'
149      let l = split(system(cmd .. ' --remote +pwd'), "\n")
150      call assert_equal("Argument missing after: \"+pwd\"", l[1])
151    endif
152    let l = system(cmd .. ' --remote-expr "abcd"')
153    call assert_match('^E449: ', l)
154  endif
155
156  eval name->remote_send(":%bw!\<CR>")
157  eval name->remote_send(":qa!\<CR>")
158  try
159    call WaitForAssert({-> assert_equal("dead", job_status(job))})
160  finally
161    if job_status(job) != 'dead'
162      call assert_report('Server did not exit')
163      call job_stop(job, 'kill')
164    endif
165  endtry
166
167  call assert_fails('call remote_startserver([])', 'E730:')
168  call assert_fails("let x = remote_peek([])", 'E730:')
169  call assert_fails("let x = remote_read('vim10')",
170        \ has('unix') ? ['E573:.*vim10'] : 'E277:')
171  call assert_fails("call server2client('abc', 'xyz')",
172        \ has('unix') ? ['E573:.*abc'] : 'E258:')
173endfunc
174
175" Uncomment this line to get a debugging log
176" call ch_logfile('channellog', 'w')
177
178" vim: shiftwidth=2 sts=2 expandtab
179