1" Tests for the +clientserver feature.
2
3source check.vim
4CheckFeature job
5
6if !has('clientserver')
7  call assert_fails('call remote_startserver("local")', 'E942:')
8endif
9
10CheckFeature clientserver
11
12source shared.vim
13
14func Check_X11_Connection()
15  if has('x11')
16    if empty($DISPLAY)
17      throw 'Skipped: $DISPLAY is not set'
18    endif
19    try
20      call remote_send('xxx', '')
21    catch
22      if v:exception =~ 'E240:'
23        throw 'Skipped: no connection to the X server'
24      endif
25      " ignore other errors
26    endtry
27  endif
28endfunc
29
30func Test_client_server()
31  let cmd = GetVimCommand()
32  if cmd == ''
33    throw 'GetVimCommand() failed'
34  endif
35  call Check_X11_Connection()
36
37  let name = 'XVIMTEST'
38  let cmd .= ' --servername ' . name
39  let job = job_start(cmd, {'stoponexit': 'kill', 'out_io': 'null'})
40  call WaitForAssert({-> assert_equal("run", job_status(job))})
41
42  " Takes a short while for the server to be active.
43  " When using valgrind it takes much longer.
44  call WaitForAssert({-> assert_match(name, serverlist())})
45
46  eval name->remote_foreground()
47
48  call remote_send(name, ":let testvar = 'yes'\<CR>")
49  call WaitFor('remote_expr("' . name . '", "exists(\"testvar\") ? testvar : \"\"", "", 1) == "yes"')
50  call assert_equal('yes', remote_expr(name, "testvar", "", 2))
51  call assert_fails("let x=remote_expr(name, '2+x')", 'E449:')
52  call assert_fails("let x=remote_expr('[], '2+2')", 'E116:')
53
54  if has('unix') && has('gui') && !has('gui_running')
55    " Running in a terminal and the GUI is available: Tell the server to open
56    " the GUI and check that the remote command still works.
57    " Need to wait for the GUI to start up, otherwise the send hangs in trying
58    " to send to the terminal window.
59    if has('gui_athena') || has('gui_motif')
60      " For those GUIs, ignore the 'failed to create input context' error.
61      call remote_send(name, ":call test_ignore_error('E285') | gui -f\<CR>")
62    else
63      call remote_send(name, ":gui -f\<CR>")
64    endif
65    " Wait for the server to be up and answering requests.
66    " When using valgrind this can be very, very slow.
67    sleep 1
68    call WaitForAssert({-> assert_match('\d', name->remote_expr("v:version", "", 1))}, 10000)
69
70    call remote_send(name, ":let testvar = 'maybe'\<CR>")
71    call WaitForAssert({-> assert_equal('maybe', remote_expr(name, "testvar", "", 2))})
72  endif
73
74  call assert_fails('call remote_send("XXX", ":let testvar = ''yes''\<CR>")', 'E241:')
75
76  call writefile(['one'], 'Xclientfile')
77  let cmd = GetVimProg() .. ' --servername ' .. name .. ' --remote Xclientfile'
78  call system(cmd)
79  call WaitForAssert({-> assert_equal('Xclientfile', remote_expr(name, "bufname()", "", 2))})
80  call WaitForAssert({-> assert_equal('one', remote_expr(name, "getline(1)", "", 2))})
81  call writefile(['one', 'two'], 'Xclientfile')
82  call system(cmd)
83  call WaitForAssert({-> assert_equal('two', remote_expr(name, "getline(2)", "", 2))})
84
85  " Expression evaluated locally.
86  if v:servername == ''
87    eval 'MYSELF'->remote_startserver()
88    " May get MYSELF1 when running the test again.
89    call assert_match('MYSELF', v:servername)
90    call assert_fails("call remote_startserver('MYSELF')", 'E941:')
91  endif
92  let g:testvar = 'myself'
93  call assert_equal('myself', remote_expr(v:servername, 'testvar'))
94  call remote_send(v:servername, ":let g:testvar2 = 75\<CR>")
95  call feedkeys('', 'x')
96  call assert_equal(75, g:testvar2)
97  call assert_fails('let v = remote_expr(v:servername, "/2")', ['E15:.*/2'])
98
99  call remote_send(name, ":call server2client(expand('<client>'), 'got it')\<CR>", 'g:myserverid')
100  call assert_equal('got it', g:myserverid->remote_read(2))
101
102  call remote_send(name, ":eval expand('<client>')->server2client('another')\<CR>", 'g:myserverid')
103  let peek_result = 'nothing'
104  let r = g:myserverid->remote_peek('peek_result')
105  " unpredictable whether the result is already available.
106  if r > 0
107    call assert_equal('another', peek_result)
108  elseif r == 0
109    call assert_equal('nothing', peek_result)
110  else
111    call assert_report('remote_peek() failed')
112  endif
113  let g:peek_result = 'empty'
114  call WaitFor('remote_peek(g:myserverid, "g:peek_result") > 0')
115  call assert_equal('another', g:peek_result)
116  call assert_equal('another', remote_read(g:myserverid, 2))
117
118  if !has('gui_running')
119    " In GUI vim, the following tests display a dialog box
120
121    let cmd = GetVimProg() .. ' --servername ' .. name
122
123    " Run a separate instance to send a command to the server
124    call remote_expr(name, 'execute("only")')
125    call system(cmd .. ' --remote-send ":new Xfile<CR>"')
126    call assert_equal('2', remote_expr(name, 'winnr("$")'))
127    call assert_equal('Xfile', remote_expr(name, 'winbufnr(1)->bufname()'))
128    call remote_expr(name, 'execute("only")')
129
130    " Invoke a remote-expr. On MS-Windows, the returned value has a carriage
131    " return.
132    let l = system(cmd .. ' --remote-expr "2 + 2"')
133    call assert_equal(['4'], split(l, "\n"))
134
135    " Edit multiple files using --remote
136    call system(cmd .. ' --remote Xfile1 Xfile2 Xfile3')
137    call assert_match(".*Xfile1\n.*Xfile2\n.*Xfile3\n", remote_expr(name, 'argv()'))
138    eval name->remote_send(":%bw!\<CR>")
139
140    " Edit files in separate tab pages
141    call system(cmd .. ' --remote-tab Xfile1 Xfile2 Xfile3')
142    call WaitForAssert({-> assert_equal('3', remote_expr(name, 'tabpagenr("$")'))})
143    call assert_match('.*\<Xfile2', remote_expr(name, 'bufname(tabpagebuflist(2)[0])'))
144    eval name->remote_send(":%bw!\<CR>")
145
146    " Edit a file using --remote-wait
147    eval name->remote_send(":source $VIMRUNTIME/plugin/rrhelper.vim\<CR>")
148    call system(cmd .. ' --remote-wait +enew Xfile1')
149    call assert_match('.*\<Xfile1', remote_expr(name, 'bufname("#")'))
150    eval name->remote_send(":%bw!\<CR>")
151
152    " Edit files using --remote-tab-wait
153    call system(cmd .. ' --remote-tabwait +tabonly\|enew Xfile1 Xfile2')
154    call assert_equal('1', remote_expr(name, 'tabpagenr("$")'))
155    eval name->remote_send(":%bw!\<CR>")
156
157    " Error cases
158    if v:lang == "C" || v:lang =~ '^[Ee]n'
159      let l = split(system(cmd .. ' --remote +pwd'), "\n")
160      call assert_equal("Argument missing after: \"+pwd\"", l[1])
161    endif
162    let l = system(cmd .. ' --remote-expr "abcd"')
163    call assert_match('^E449: ', l)
164  endif
165
166  eval name->remote_send(":%bw!\<CR>")
167  eval name->remote_send(":qa!\<CR>")
168  try
169    call WaitForAssert({-> assert_equal("dead", job_status(job))})
170  finally
171    if job_status(job) != 'dead'
172      call assert_report('Server did not exit')
173      call job_stop(job, 'kill')
174    endif
175  endtry
176
177  call assert_fails('call remote_startserver([])', 'E730:')
178  call assert_fails("let x = remote_peek([])", 'E730:')
179  call assert_fails("let x = remote_read('vim10')",
180        \ has('unix') ? ['E573:.*vim10'] : 'E277:')
181  call assert_fails("call server2client('abc', 'xyz')",
182        \ has('unix') ? ['E573:.*abc'] : 'E258:')
183endfunc
184
185" Uncomment this line to get a debugging log
186" call ch_logfile('channellog', 'w')
187
188" vim: shiftwidth=2 sts=2 expandtab
189