1" Tests for the getbufinfo(), getwininfo() and gettabinfo() functions
2
3function Test_getbufwintabinfo()
4    edit Xtestfile1
5    edit Xtestfile2
6    let buflist = getbufinfo()
7    call assert_equal(2, len(buflist))
8    call assert_match('Xtestfile1', buflist[0].name)
9    call assert_match('Xtestfile2', getbufinfo('Xtestfile2')[0].name)
10    call assert_equal([], getbufinfo(2016))
11    edit Xtestfile1
12    hide edit Xtestfile2
13    hide enew
14    call assert_equal(3, len(getbufinfo({'bufloaded':1})))
15
16    set tabstop&vim
17    let b:editor = 'vim'
18    let l = getbufinfo('%')
19    call assert_equal(bufnr('%'), l[0].bufnr)
20    call assert_equal('vim', l[0].variables.editor)
21    call assert_notequal(-1, index(l[0].windows, bufwinid('%')))
22
23    " Test for getbufinfo() with 'bufmodified'
24    call assert_equal(0, len(getbufinfo({'bufmodified' : 1})))
25    call setbufline('Xtestfile1', 1, ["Line1"])
26    let l = getbufinfo({'bufmodified' : 1})
27    call assert_equal(1, len(l))
28    call assert_equal(bufnr('Xtestfile1'), l[0].bufnr)
29
30    if has('signs')
31	call append(0, ['Linux', 'Windows', 'Mac'])
32	sign define Mark text=>> texthl=Search
33	exe "sign place 2 line=3 name=Mark buffer=" . bufnr('%')
34	let l = getbufinfo('%')
35	call assert_equal(2, l[0].signs[0].id)
36	call assert_equal(3, l[0].signs[0].lnum)
37	call assert_equal('Mark', l[0].signs[0].name)
38	sign unplace *
39	sign undefine Mark
40	enew!
41    endif
42
43    only
44    let w1_id = win_getid()
45    new
46    let w2_id = win_getid()
47    tabnew | let w3_id = win_getid()
48    new | let w4_id = win_getid()
49    vert new | let w5_id = win_getid()
50    call setwinvar(0, 'signal', 'green')
51    tabfirst
52    let winlist = getwininfo()
53    call assert_equal(5, len(winlist))
54    call assert_equal(winwidth(1), winlist[0].width)
55    call assert_equal(1, winlist[0].wincol)
56    " tabline adds one row in terminal, not in GUI
57    let tablineheight = winlist[0].winrow == 2 ? 1 : 0
58    call assert_equal(tablineheight + 1, winlist[0].winrow)
59
60    call assert_equal(winbufnr(2), winlist[1].bufnr)
61    call assert_equal(winheight(2), winlist[1].height)
62    call assert_equal(1, winlist[1].wincol)
63    call assert_equal(tablineheight + winheight(1) + 2, winlist[1].winrow)
64
65    call assert_equal(1, winlist[2].winnr)
66    call assert_equal(tablineheight + 1, winlist[2].winrow)
67    call assert_equal(1, winlist[2].wincol)
68
69    call assert_equal(winlist[2].width + 2, winlist[3].wincol)
70    call assert_equal(1, winlist[4].wincol)
71
72    call assert_equal(1, winlist[0].tabnr)
73    call assert_equal(1, winlist[1].tabnr)
74    call assert_equal(2, winlist[2].tabnr)
75    call assert_equal(2, winlist[3].tabnr)
76    call assert_equal(2, winlist[4].tabnr)
77
78    call assert_equal('green', winlist[2].variables.signal)
79    call assert_equal(w4_id, winlist[3].winid)
80    let winfo = getwininfo(w5_id)[0]
81    call assert_equal(2, winfo.tabnr)
82    call assert_equal([], getwininfo(3))
83
84    call settabvar(1, 'space', 'build')
85    let tablist = gettabinfo()
86    call assert_equal(2, len(tablist))
87    call assert_equal(3, len(tablist[1].windows))
88    call assert_equal(2, tablist[1].tabnr)
89    call assert_equal('build', tablist[0].variables.space)
90    call assert_equal(w2_id, tablist[0].windows[0])
91    call assert_equal([], gettabinfo(3))
92
93    tabonly | only
94
95    lexpr ''
96    lopen
97    copen
98    let winlist = getwininfo()
99    call assert_false(winlist[0].quickfix)
100    call assert_false(winlist[0].loclist)
101    call assert_true(winlist[1].quickfix)
102    call assert_true(winlist[1].loclist)
103    call assert_true(winlist[2].quickfix)
104    call assert_false(winlist[2].loclist)
105    wincmd t | only
106endfunction
107
108function Test_get_buf_options()
109  let opts = getbufvar(bufnr('%'), '&')
110  call assert_equal(v:t_dict, type(opts))
111  call assert_equal(8, opts.tabstop)
112endfunc
113
114function Test_get_win_options()
115  if has('folding')
116    set foldlevel=999
117  endif
118  set list
119  let opts = getwinvar(1, '&')
120  call assert_equal(v:t_dict, type(opts))
121  call assert_equal(0, opts.linebreak)
122  call assert_equal(1, opts.list)
123  if has('folding')
124    call assert_equal(999, opts.foldlevel)
125  endif
126  if has('signs')
127    call assert_equal('auto', opts.signcolumn)
128  endif
129
130  let opts = gettabwinvar(1, 1, '&')
131  call assert_equal(v:t_dict, type(opts))
132  call assert_equal(0, opts.linebreak)
133  call assert_equal(1, opts.list)
134  if has('signs')
135    call assert_equal('auto', opts.signcolumn)
136  endif
137  set list&
138  if has('folding')
139    set foldlevel=0
140  endif
141endfunc
142