1" Vim plugin for showing matching parens
2" Maintainer:  Bram Moolenaar <[email protected]>
3" Last Change: 2013 May 08
4
5" Exit quickly when:
6" - this plugin was already loaded (or disabled)
7" - when 'compatible' is set
8" - the "CursorMoved" autocmd event is not available.
9if exists("g:loaded_matchparen") || &cp || !exists("##CursorMoved")
10  finish
11endif
12let g:loaded_matchparen = 1
13
14if !exists("g:matchparen_timeout")
15  let g:matchparen_timeout = 300
16endif
17if !exists("g:matchparen_insert_timeout")
18  let g:matchparen_insert_timeout = 60
19endif
20
21augroup matchparen
22  " Replace all matchparen autocommands
23  autocmd! CursorMoved,CursorMovedI,WinEnter * call s:Highlight_Matching_Pair()
24  if exists('##TextChanged')
25    autocmd! TextChanged,TextChangedI * call s:Highlight_Matching_Pair()
26  endif
27augroup END
28
29" Skip the rest if it was already done.
30if exists("*s:Highlight_Matching_Pair")
31  finish
32endif
33
34let s:cpo_save = &cpo
35set cpo-=C
36
37" The function that is invoked (very often) to define a ":match" highlighting
38" for any matching paren.
39function! s:Highlight_Matching_Pair()
40  " Remove any previous match.
41  if exists('w:paren_hl_on') && w:paren_hl_on
42    3match none
43    let w:paren_hl_on = 0
44  endif
45
46  " Avoid that we remove the popup menu.
47  " Return when there are no colors (looks like the cursor jumps).
48  if pumvisible() || (&t_Co < 8 && !has("gui_running"))
49    return
50  endif
51
52  " Get the character under the cursor and check if it's in 'matchpairs'.
53  let c_lnum = line('.')
54  let c_col = col('.')
55  let before = 0
56
57  let c = getline(c_lnum)[c_col - 1]
58  let plist = split(&matchpairs, '.\zs[:,]')
59  let i = index(plist, c)
60  if i < 0
61    " not found, in Insert mode try character before the cursor
62    if c_col > 1 && (mode() == 'i' || mode() == 'R')
63      let before = 1
64      let c = getline(c_lnum)[c_col - 2]
65      let i = index(plist, c)
66    endif
67    if i < 0
68      " not found, nothing to do
69      return
70    endif
71  endif
72
73  " Figure out the arguments for searchpairpos().
74  if i % 2 == 0
75    let s_flags = 'nW'
76    let c2 = plist[i + 1]
77  else
78    let s_flags = 'nbW'
79    let c2 = c
80    let c = plist[i - 1]
81  endif
82  if c == '['
83    let c = '\['
84    let c2 = '\]'
85  endif
86
87  " Find the match.  When it was just before the cursor move it there for a
88  " moment.
89  if before > 0
90    let save_cursor = winsaveview()
91    call cursor(c_lnum, c_col - before)
92  endif
93
94  " When not in a string or comment ignore matches inside them.
95  " We match "escape" for special items, such as lispEscapeSpecial.
96  let s_skip ='synIDattr(synID(line("."), col("."), 0), "name") ' .
97	\ '=~?  "string\\|character\\|singlequote\\|escape\\|comment"'
98  execute 'if' s_skip '| let s_skip = 0 | endif'
99
100  " Limit the search to lines visible in the window.
101  let stoplinebottom = line('w$')
102  let stoplinetop = line('w0')
103  if i % 2 == 0
104    let stopline = stoplinebottom
105  else
106    let stopline = stoplinetop
107  endif
108
109  " Limit the search time to 300 msec to avoid a hang on very long lines.
110  " This fails when a timeout is not supported.
111  if mode() == 'i' || mode() == 'R'
112    let timeout = exists("b:matchparen_insert_timeout") ? b:matchparen_insert_timeout : g:matchparen_insert_timeout
113  else
114    let timeout = exists("b:matchparen_timeout") ? b:matchparen_timeout : g:matchparen_timeout
115  endif
116  try
117    let [m_lnum, m_col] = searchpairpos(c, '', c2, s_flags, s_skip, stopline, timeout)
118  catch /E118/
119    " Can't use the timeout, restrict the stopline a bit more to avoid taking
120    " a long time on closed folds and long lines.
121    " The "viewable" variables give a range in which we can scroll while
122    " keeping the cursor at the same position.
123    " adjustedScrolloff accounts for very large numbers of scrolloff.
124    let adjustedScrolloff = min([&scrolloff, (line('w$') - line('w0')) / 2])
125    let bottom_viewable = min([line('$'), c_lnum + &lines - adjustedScrolloff - 2])
126    let top_viewable = max([1, c_lnum-&lines+adjustedScrolloff + 2])
127    " one of these stoplines will be adjusted below, but the current values are
128    " minimal boundaries within the current window
129    if i % 2 == 0
130      if has("byte_offset") && has("syntax_items") && &smc > 0
131	let stopbyte = min([line2byte("$"), line2byte(".") + col(".") + &smc * 2])
132	let stopline = min([bottom_viewable, byte2line(stopbyte)])
133      else
134	let stopline = min([bottom_viewable, c_lnum + 100])
135      endif
136      let stoplinebottom = stopline
137    else
138      if has("byte_offset") && has("syntax_items") && &smc > 0
139	let stopbyte = max([1, line2byte(".") + col(".") - &smc * 2])
140	let stopline = max([top_viewable, byte2line(stopbyte)])
141      else
142	let stopline = max([top_viewable, c_lnum - 100])
143      endif
144      let stoplinetop = stopline
145    endif
146    let [m_lnum, m_col] = searchpairpos(c, '', c2, s_flags, s_skip, stopline)
147  endtry
148
149  if before > 0
150    call winrestview(save_cursor)
151  endif
152
153  " If a match is found setup match highlighting.
154  if m_lnum > 0 && m_lnum >= stoplinetop && m_lnum <= stoplinebottom
155    exe '3match MatchParen /\(\%' . c_lnum . 'l\%' . (c_col - before) .
156	  \ 'c\)\|\(\%' . m_lnum . 'l\%' . m_col . 'c\)/'
157    let w:paren_hl_on = 1
158  endif
159endfunction
160
161" Define commands that will disable and enable the plugin.
162command! NoMatchParen windo 3match none | unlet! g:loaded_matchparen |
163	  \ au! matchparen
164command! DoMatchParen runtime plugin/matchparen.vim | windo doau CursorMoved
165
166let &cpo = s:cpo_save
167unlet s:cpo_save
168