1" Vim plugin for showing matching parens
2" Maintainer:  Bram Moolenaar <[email protected]>
3" Last Change: 2014 Jul 09
4
5" Exit quickly when:
6" - this plugin was already loaded (or disabled)
7" - when 'compatible' is set
8" - the "CursorMoved" autocmd event is not available.
9if exists("g:loaded_matchparen") || &cp || !exists("##CursorMoved")
10  finish
11endif
12let g:loaded_matchparen = 1
13
14if !exists("g:matchparen_timeout")
15  let g:matchparen_timeout = 300
16endif
17if !exists("g:matchparen_insert_timeout")
18  let g:matchparen_insert_timeout = 60
19endif
20
21augroup matchparen
22  " Replace all matchparen autocommands
23  autocmd! CursorMoved,CursorMovedI,WinEnter * call s:Highlight_Matching_Pair()
24  if exists('##TextChanged')
25    autocmd! TextChanged,TextChangedI * call s:Highlight_Matching_Pair()
26  endif
27augroup END
28
29" Skip the rest if it was already done.
30if exists("*s:Highlight_Matching_Pair")
31  finish
32endif
33
34let s:cpo_save = &cpo
35set cpo-=C
36
37" The function that is invoked (very often) to define a ":match" highlighting
38" for any matching paren.
39function! s:Highlight_Matching_Pair()
40  " Remove any previous match.
41  if exists('w:paren_hl_on') && w:paren_hl_on
42    silent! call matchdelete(3)
43    let w:paren_hl_on = 0
44  endif
45
46  " Avoid that we remove the popup menu.
47  " Return when there are no colors (looks like the cursor jumps).
48  if pumvisible() || (&t_Co < 8 && !has("gui_running"))
49    return
50  endif
51
52  " Get the character under the cursor and check if it's in 'matchpairs'.
53  let c_lnum = line('.')
54  let c_col = col('.')
55  let before = 0
56
57  let text = getline(c_lnum)
58  let c = text[c_col - 1]
59  let plist = split(&matchpairs, '.\zs[:,]')
60  let i = index(plist, c)
61  if i < 0
62    " not found, in Insert mode try character before the cursor
63    if c_col > 1 && (mode() == 'i' || mode() == 'R')
64      let before = 1
65      let c = text[c_col - 2]
66      let i = index(plist, c)
67    endif
68    if i < 0
69      " not found, nothing to do
70      return
71    endif
72  endif
73
74  " Figure out the arguments for searchpairpos().
75  if i % 2 == 0
76    let s_flags = 'nW'
77    let c2 = plist[i + 1]
78  else
79    let s_flags = 'nbW'
80    let c2 = c
81    let c = plist[i - 1]
82  endif
83  if c == '['
84    let c = '\['
85    let c2 = '\]'
86  endif
87
88  " Find the match.  When it was just before the cursor move it there for a
89  " moment.
90  if before > 0
91    let save_cursor = getcurpos()
92    call cursor(c_lnum, c_col - before)
93  endif
94
95  " When not in a string or comment ignore matches inside them.
96  " We match "escape" for special items, such as lispEscapeSpecial.
97  let s_skip ='synIDattr(synID(line("."), col("."), 0), "name") ' .
98	\ '=~?  "string\\|character\\|singlequote\\|escape\\|comment"'
99  execute 'if' s_skip '| let s_skip = 0 | endif'
100
101  " Limit the search to lines visible in the window.
102  let stoplinebottom = line('w$')
103  let stoplinetop = line('w0')
104  if i % 2 == 0
105    let stopline = stoplinebottom
106  else
107    let stopline = stoplinetop
108  endif
109
110  " Limit the search time to 300 msec to avoid a hang on very long lines.
111  " This fails when a timeout is not supported.
112  if mode() == 'i' || mode() == 'R'
113    let timeout = exists("b:matchparen_insert_timeout") ? b:matchparen_insert_timeout : g:matchparen_insert_timeout
114  else
115    let timeout = exists("b:matchparen_timeout") ? b:matchparen_timeout : g:matchparen_timeout
116  endif
117  try
118    let [m_lnum, m_col] = searchpairpos(c, '', c2, s_flags, s_skip, stopline, timeout)
119  catch /E118/
120    " Can't use the timeout, restrict the stopline a bit more to avoid taking
121    " a long time on closed folds and long lines.
122    " The "viewable" variables give a range in which we can scroll while
123    " keeping the cursor at the same position.
124    " adjustedScrolloff accounts for very large numbers of scrolloff.
125    let adjustedScrolloff = min([&scrolloff, (line('w$') - line('w0')) / 2])
126    let bottom_viewable = min([line('$'), c_lnum + &lines - adjustedScrolloff - 2])
127    let top_viewable = max([1, c_lnum-&lines+adjustedScrolloff + 2])
128    " one of these stoplines will be adjusted below, but the current values are
129    " minimal boundaries within the current window
130    if i % 2 == 0
131      if has("byte_offset") && has("syntax_items") && &smc > 0
132	let stopbyte = min([line2byte("$"), line2byte(".") + col(".") + &smc * 2])
133	let stopline = min([bottom_viewable, byte2line(stopbyte)])
134      else
135	let stopline = min([bottom_viewable, c_lnum + 100])
136      endif
137      let stoplinebottom = stopline
138    else
139      if has("byte_offset") && has("syntax_items") && &smc > 0
140	let stopbyte = max([1, line2byte(".") + col(".") - &smc * 2])
141	let stopline = max([top_viewable, byte2line(stopbyte)])
142      else
143	let stopline = max([top_viewable, c_lnum - 100])
144      endif
145      let stoplinetop = stopline
146    endif
147    let [m_lnum, m_col] = searchpairpos(c, '', c2, s_flags, s_skip, stopline)
148  endtry
149
150  if before > 0
151    call setpos('.', save_cursor)
152  endif
153
154  " If a match is found setup match highlighting.
155  if m_lnum > 0 && m_lnum >= stoplinetop && m_lnum <= stoplinebottom
156    if exists('*matchaddpos')
157      call matchaddpos('MatchParen', [[c_lnum, c_col - before], [m_lnum, m_col]], 10, 3)
158    else
159      exe '3match MatchParen /\(\%' . c_lnum . 'l\%' . (c_col - before) .
160	    \ 'c\)\|\(\%' . m_lnum . 'l\%' . m_col . 'c\)/'
161    endif
162    let w:paren_hl_on = 1
163  endif
164endfunction
165
166" Define commands that will disable and enable the plugin.
167command! NoMatchParen windo silent! call matchdelete(3) | unlet! g:loaded_matchparen |
168	  \ au! matchparen
169command! DoMatchParen runtime plugin/matchparen.vim | windo doau CursorMoved
170
171let &cpo = s:cpo_save
172unlet s:cpo_save
173