1" plain TeX filetype plugin
2" Language:     plain TeX (ft=plaintex)
3" Maintainer:   Benji Fisher, Ph.D. <[email protected]>
4" Version:	1.0
5" Last Change:	Wed 22 Mar 2006 09:36:32 AM EST
6
7" Only do this when not done yet for this buffer.
8if exists("b:did_ftplugin")
9  finish
10endif
11
12" Don't load another plugin for this buffer.
13let b:did_ftplugin = 1
14
15" Avoid problems if running in 'compatible' mode.
16let s:save_cpo = &cpo
17set cpo&vim
18
19" Set 'comments' to format dashed lists in comments
20setlocal com=sO:%\ -,mO:%\ \ ,eO:%%,:%
21
22" Set 'commentstring' to recognize the % comment character:
23" (Thanks to Ajit Thakkar.)
24setlocal cms=%%s
25
26" Allow "[d" to be used to find a macro definition:
27let &l:define='\\\([egx]\|char\|mathchar\|count\|dimen\|muskip\|skip\|toks\)\='
28	\ .	'def\|\\font\|\\\(future\)\=let'
29	\ . '\|\\new\(count\|dimen\|skip\|muskip\|box\|toks\|read\|write'
30	\ .	'\|fam\|insert\)'
31
32" Tell Vim to recognize \input bar :
33let &l:include = '\\input'
34setlocal suffixesadd=.tex
35
36" The following lines enable the macros/matchit.vim plugin for
37" extended matching with the % key.
38" There is no default meaning for \(...\) etc., but many users define one.
39if exists("loaded_matchit")
40  let b:match_ignorecase = 0
41    \ | let b:match_skip = 'r:\\\@<!\%(\\\\\)*%'
42    \ | let b:match_words = '(:),\[:],{:},\\(:\\),\\\[:\\],' .
43    \ '\\begin\s*\({\a\+\*\=}\):\\end\s*\1'
44endif " exists("loaded_matchit")
45
46let &cpo = s:save_cpo
47
48" vim:sts=2:sw=2:
49