1// RUN: mlir-opt %s -pass-pipeline="func.func(test-vector-to-forloop,convert-vector-to-scf,lower-affine,convert-scf-to-cf),convert-vector-to-llvm,convert-memref-to-llvm,convert-func-to-llvm,reconcile-unrealized-casts" | \
2// RUN: mlir-cpu-runner -e main -entry-point-result=void  \
3// RUN:   -shared-libs=%mlir_integration_test_dir/libmlir_runner_utils%shlibext | \
4// RUN: FileCheck %s
5
6// RUN: mlir-opt %s -pass-pipeline="func.func(convert-vector-to-scf,lower-affine,convert-scf-to-cf),convert-vector-to-llvm,convert-memref-to-llvm,convert-func-to-llvm,reconcile-unrealized-casts" | mlir-cpu-runner -e main \
7// RUN: -entry-point-result=void \
8// RUN: -shared-libs=%mlir_integration_test_dir/libmlir_runner_utils%shlibext | \
9// RUN: FileCheck %s
10
11// RUN: mlir-opt %s -pass-pipeline="func.func(test-vector-to-forloop)" | FileCheck %s -check-prefix=TRANSFORM
12
13
14func.func private @print_memref_f32(memref<*xf32>)
15
16func.func @alloc_1d_filled_inc_f32(%arg0: index, %arg1: f32) -> memref<?xf32> {
17  %c0 = arith.constant 0 : index
18  %c1 = arith.constant 1 : index
19  %0 = memref.alloc(%arg0) : memref<?xf32>
20  scf.for %arg2 = %c0 to %arg0 step %c1 {
21    %tmp = arith.index_cast %arg2 : index to i32
22    %tmp1 = arith.sitofp %tmp : i32 to f32
23    %tmp2 = arith.addf %tmp1, %arg1 : f32
24    memref.store %tmp2, %0[%arg2] : memref<?xf32>
25  }
26  return %0 : memref<?xf32>
27}
28
29// Large vector addf that can be broken down into a loop of smaller vector addf.
30func.func @main() {
31  %cf0 = arith.constant 0.0 : f32
32  %cf1 = arith.constant 1.0 : f32
33  %cf2 = arith.constant 2.0 : f32
34  %c0 = arith.constant 0 : index
35  %c1 = arith.constant 1 : index
36  %c32 = arith.constant 32 : index
37  %c64 = arith.constant 64 : index
38  %out = memref.alloc(%c64) : memref<?xf32>
39  %in1 = call @alloc_1d_filled_inc_f32(%c64, %cf1) : (index, f32) -> memref<?xf32>
40  %in2 = call @alloc_1d_filled_inc_f32(%c64, %cf2) : (index, f32) -> memref<?xf32>
41  // Check that the tansformatio correctly happened.
42  // TRANSFORM: scf.for
43  // TRANSFORM:   vector.transfer_read {{.*}} : memref<?xf32>, vector<2xf32>
44  // TRANSFORM:   vector.transfer_read {{.*}} : memref<?xf32>, vector<2xf32>
45  // TRANSFORM:   %{{.*}} = arith.addf %{{.*}}, %{{.*}} : vector<2xf32>
46  // TRANSFORM:   vector.transfer_write {{.*}} : vector<2xf32>, memref<?xf32>
47  // TRANSFORM: }
48  %a = vector.transfer_read %in1[%c0], %cf0: memref<?xf32>, vector<64xf32>
49  %b = vector.transfer_read %in2[%c0], %cf0: memref<?xf32>, vector<64xf32>
50  %acc = arith.addf %a, %b: vector<64xf32>
51  vector.transfer_write %acc, %out[%c0]: vector<64xf32>, memref<?xf32>
52  %converted = memref.cast %out : memref<?xf32> to memref<*xf32>
53  call @print_memref_f32(%converted): (memref<*xf32>) -> ()
54  // CHECK:      Unranked{{.*}}data =
55  // CHECK:      [
56  // CHECK-SAME:  3,  5,  7,  9,  11,  13,  15,  17,  19,  21,  23,  25,  27,
57  // CHECK-SAME:  29,  31,  33,  35,  37,  39,  41,  43,  45,  47,  49,  51,
58  // CHECK-SAME:  53,  55,  57,  59,  61,  63,  65,  67,  69,  71,  73,  75,
59  // CHECK-SAME:  77,  79,  81,  83,  85,  87,  89,  91,  93,  95,  97,  99,
60  // CHECK-SAME:  101,  103,  105,  107,  109,  111,  113,  115,  117,  119,
61  // CHECK-SAME:  121,  123,  125,  127,  129]
62  memref.dealloc %out : memref<?xf32>
63  memref.dealloc %in1 : memref<?xf32>
64  memref.dealloc %in2 : memref<?xf32>
65  return
66}
67