1// RUN: mlir-opt %s --sparse-compiler | \
2// RUN: mlir-cpu-runner -e entry -entry-point-result=void \
3// RUN:  -shared-libs=%mlir_integration_test_dir/libmlir_c_runner_utils%shlibext | \
4// RUN: FileCheck %s
5
6#CSR = #sparse_tensor.encoding<{
7  dimLevelType = [ "dense", "compressed" ],
8  dimOrdering = affine_map<(i,j) -> (i,j)>
9}>
10
11#DCSR = #sparse_tensor.encoding<{
12  dimLevelType = [ "compressed", "compressed" ],
13  dimOrdering = affine_map<(i,j) -> (i,j)>
14}>
15
16module {
17  //
18  // Computes C = A x B with all matrices dense.
19  //
20  func.func @matmul1(%A: tensor<4x8xf64>,
21                %B: tensor<8x4xf64>) -> tensor<4x4xf64> {
22    %C = arith.constant dense<0.0> : tensor<4x4xf64>
23    %D = linalg.matmul
24      ins(%A, %B: tensor<4x8xf64>, tensor<8x4xf64>)
25         outs(%C: tensor<4x4xf64>) -> tensor<4x4xf64>
26    return %D: tensor<4x4xf64>
27  }
28
29  //
30  // Computes C = A x B with all matrices sparse (SpMSpM) in CSR.
31  //
32  func.func @matmul2(%A: tensor<4x8xf64, #CSR>,
33                %B: tensor<8x4xf64, #CSR>) -> tensor<4x4xf64, #CSR> {
34    %C = bufferization.alloc_tensor() : tensor<4x4xf64, #CSR>
35    %D = linalg.matmul
36      ins(%A, %B: tensor<4x8xf64, #CSR>, tensor<8x4xf64, #CSR>)
37         outs(%C: tensor<4x4xf64, #CSR>) -> tensor<4x4xf64, #CSR>
38    return %D: tensor<4x4xf64, #CSR>
39  }
40
41  //
42  // Computes C = A x B with all matrices sparse (SpMSpM) in DCSR.
43  //
44  func.func @matmul3(%A: tensor<4x8xf64, #DCSR>,
45                %B: tensor<8x4xf64, #DCSR>) -> tensor<4x4xf64, #DCSR> {
46    %C = bufferization.alloc_tensor() : tensor<4x4xf64, #DCSR>
47    %D = linalg.matmul
48      ins(%A, %B: tensor<4x8xf64, #DCSR>, tensor<8x4xf64, #DCSR>)
49         outs(%C: tensor<4x4xf64, #DCSR>) -> tensor<4x4xf64, #DCSR>
50    return %D: tensor<4x4xf64, #DCSR>
51  }
52
53  //
54  // Main driver.
55  //
56  func.func @entry() {
57    %c0 = arith.constant 0 : index
58    %d1 = arith.constant -1.0 : f64
59
60    // Initialize various matrices, dense for stress testing,
61    // and sparse to verify correct nonzero structure.
62    %da = arith.constant dense<[
63        [ 1.1, 2.1, 3.1, 4.1, 5.1, 6.1, 7.1, 8.1 ],
64        [ 1.2, 2.2, 3.2, 4.2, 5.2, 6.2, 7.2, 8.2 ],
65        [ 1.3, 2.3, 3.3, 4.3, 5.3, 6.3, 7.3, 8.3 ],
66        [ 1.4, 2.4, 3.4, 4.4, 5.4, 6.4, 7.4, 8.4 ]
67    ]> : tensor<4x8xf64>
68    %db = arith.constant dense<[
69        [ 10.1, 11.1, 12.1, 13.1 ],
70        [ 10.2, 11.2, 12.2, 13.2 ],
71        [ 10.3, 11.3, 12.3, 13.3 ],
72        [ 10.4, 11.4, 12.4, 13.4 ],
73        [ 10.5, 11.5, 12.5, 13.5 ],
74        [ 10.6, 11.6, 12.6, 13.6 ],
75        [ 10.7, 11.7, 12.7, 13.7 ],
76        [ 10.8, 11.8, 12.8, 13.8 ]
77    ]> : tensor<8x4xf64>
78    %sa = arith.constant dense<[
79        [ 0.0, 2.1, 0.0, 0.0, 0.0, 6.1, 0.0, 0.0 ],
80        [ 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 ],
81        [ 0.0, 2.3, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 ],
82        [ 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 1.0 ]
83    ]> : tensor<4x8xf64>
84    %sb = arith.constant dense<[
85        [ 0.0, 0.0, 0.0, 1.0 ],
86        [ 0.0, 0.0, 2.0, 0.0 ],
87        [ 0.0, 3.0, 0.0, 0.0 ],
88        [ 4.0, 0.0, 0.0, 0.0 ],
89        [ 0.0, 0.0, 0.0, 0.0 ],
90        [ 0.0, 5.0, 0.0, 0.0 ],
91        [ 0.0, 0.0, 6.0, 0.0 ],
92        [ 0.0, 0.0, 7.0, 8.0 ]
93    ]> : tensor<8x4xf64>
94
95    // Convert all these matrices to sparse format.
96    %a1 = sparse_tensor.convert %da : tensor<4x8xf64> to tensor<4x8xf64, #CSR>
97    %a2 = sparse_tensor.convert %da : tensor<4x8xf64> to tensor<4x8xf64, #DCSR>
98    %a3 = sparse_tensor.convert %sa : tensor<4x8xf64> to tensor<4x8xf64, #CSR>
99    %a4 = sparse_tensor.convert %sa : tensor<4x8xf64> to tensor<4x8xf64, #DCSR>
100    %b1 = sparse_tensor.convert %db : tensor<8x4xf64> to tensor<8x4xf64, #CSR>
101    %b2 = sparse_tensor.convert %db : tensor<8x4xf64> to tensor<8x4xf64, #DCSR>
102    %b3 = sparse_tensor.convert %sb : tensor<8x4xf64> to tensor<8x4xf64, #CSR>
103    %b4 = sparse_tensor.convert %sb : tensor<8x4xf64> to tensor<8x4xf64, #DCSR>
104
105    // Call kernels with dense.
106    %0 = call @matmul1(%da, %db)
107       : (tensor<4x8xf64>, tensor<8x4xf64>) -> tensor<4x4xf64>
108    %1 = call @matmul2(%a1, %b1)
109       : (tensor<4x8xf64, #CSR>,
110          tensor<8x4xf64, #CSR>) -> tensor<4x4xf64, #CSR>
111    %2 = call @matmul3(%a2, %b2)
112       : (tensor<4x8xf64, #DCSR>,
113          tensor<8x4xf64, #DCSR>) -> tensor<4x4xf64, #DCSR>
114
115    // Call kernels with one sparse.
116    %3 = call @matmul1(%sa, %db)
117       : (tensor<4x8xf64>, tensor<8x4xf64>) -> tensor<4x4xf64>
118    %4 = call @matmul2(%a3, %b1)
119       : (tensor<4x8xf64, #CSR>,
120          tensor<8x4xf64, #CSR>) -> tensor<4x4xf64, #CSR>
121    %5 = call @matmul3(%a4, %b2)
122       : (tensor<4x8xf64, #DCSR>,
123          tensor<8x4xf64, #DCSR>) -> tensor<4x4xf64, #DCSR>
124
125    // Call kernels with sparse.
126    %6 = call @matmul1(%sa, %sb)
127       : (tensor<4x8xf64>, tensor<8x4xf64>) -> tensor<4x4xf64>
128    %7 = call @matmul2(%a3, %b3)
129       : (tensor<4x8xf64, #CSR>,
130          tensor<8x4xf64, #CSR>) -> tensor<4x4xf64, #CSR>
131    %8 = call @matmul3(%a4, %b4)
132       : (tensor<4x8xf64, #DCSR>,
133          tensor<8x4xf64, #DCSR>) -> tensor<4x4xf64, #DCSR>
134
135    //
136    // CHECK:    ( ( 388.76, 425.56, 462.36, 499.16 ),
137    // CHECK-SAME: ( 397.12, 434.72, 472.32, 509.92 ),
138    // CHECK-SAME: ( 405.48, 443.88, 482.28, 520.68 ),
139    // CHECK-SAME: ( 413.84, 453.04, 492.24, 531.44 ) )
140    //
141    %m0 = bufferization.to_memref %0 : memref<4x4xf64>
142    %v0 = vector.transfer_read %m0[%c0, %c0], %d1 : memref<4x4xf64>, vector<4x4xf64>
143    vector.print %v0 : vector<4x4xf64>
144
145    //
146    // CHECK:    ( ( 388.76, 425.56, 462.36, 499.16 ),
147    // CHECK-SAME: ( 397.12, 434.72, 472.32, 509.92 ),
148    // CHECK-SAME: ( 405.48, 443.88, 482.28, 520.68 ),
149    // CHECK-SAME: ( 413.84, 453.04, 492.24, 531.44 ) )
150    //
151    %c1 = sparse_tensor.convert %1 : tensor<4x4xf64, #CSR> to tensor<4x4xf64>
152    %m1 = bufferization.to_memref %c1 : memref<4x4xf64>
153    %v1 = vector.transfer_read %m1[%c0, %c0], %d1 : memref<4x4xf64>, vector<4x4xf64>
154    vector.print %v1 : vector<4x4xf64>
155
156    //
157    // CHECK:    ( ( 388.76, 425.56, 462.36, 499.16 ),
158    // CHECK-SAME: ( 397.12, 434.72, 472.32, 509.92 ),
159    // CHECK-SAME: ( 405.48, 443.88, 482.28, 520.68 ),
160    // CHECK-SAME: ( 413.84, 453.04, 492.24, 531.44 ) )
161    //
162    %c2 = sparse_tensor.convert %2 : tensor<4x4xf64, #DCSR> to tensor<4x4xf64>
163    %m2 = bufferization.to_memref %c2 : memref<4x4xf64>
164    %v2 = vector.transfer_read %m2[%c0, %c0], %d1 : memref<4x4xf64>, vector<4x4xf64>
165    vector.print %v2 : vector<4x4xf64>
166
167    //
168    // CHECK:    ( ( 86.08, 94.28, 102.48, 110.68 ),
169    // CHECK-SAME: ( 0, 0, 0, 0 ),
170    // CHECK-SAME: ( 23.46, 25.76, 28.06, 30.36 ),
171    // CHECK-SAME: ( 10.8, 11.8, 12.8, 13.8 ) )
172    //
173    %m3 = bufferization.to_memref %3 : memref<4x4xf64>
174    %v3 = vector.transfer_read %m3[%c0, %c0], %d1 : memref<4x4xf64>, vector<4x4xf64>
175    vector.print %v3 : vector<4x4xf64>
176
177    //
178    // CHECK:    ( ( 86.08, 94.28, 102.48, 110.68 ),
179    // CHECK-SAME: ( 0, 0, 0, 0 ),
180    // CHECK-SAME: ( 23.46, 25.76, 28.06, 30.36 ),
181    // CHECK-SAME: ( 10.8, 11.8, 12.8, 13.8 ) )
182    //
183    %c4 = sparse_tensor.convert %4 : tensor<4x4xf64, #CSR> to tensor<4x4xf64>
184    %m4 = bufferization.to_memref %c4 : memref<4x4xf64>
185    %v4 = vector.transfer_read %m4[%c0, %c0], %d1 : memref<4x4xf64>, vector<4x4xf64>
186    vector.print %v4 : vector<4x4xf64>
187
188    //
189    // CHECK:    ( ( 86.08, 94.28, 102.48, 110.68 ),
190    // CHECK-SAME: ( 0, 0, 0, 0 ),
191    // CHECK-SAME: ( 23.46, 25.76, 28.06, 30.36 ),
192    // CHECK-SAME: ( 10.8, 11.8, 12.8, 13.8 ) )
193    //
194    %c5 = sparse_tensor.convert %5 : tensor<4x4xf64, #DCSR> to tensor<4x4xf64>
195    %m5 = bufferization.to_memref %c5 : memref<4x4xf64>
196    %v5 = vector.transfer_read %m5[%c0, %c0], %d1 : memref<4x4xf64>, vector<4x4xf64>
197    vector.print %v5 : vector<4x4xf64>
198
199    //
200    // CHECK: ( ( 0, 30.5, 4.2, 0 ), ( 0, 0, 0, 0 ), ( 0, 0, 4.6, 0 ), ( 0, 0, 7, 8 ) )
201    //
202    %m6 = bufferization.to_memref %6 : memref<4x4xf64>
203    %v6 = vector.transfer_read %m6[%c0, %c0], %d1 : memref<4x4xf64>, vector<4x4xf64>
204    vector.print %v6 : vector<4x4xf64>
205
206    //
207    // CHECK: ( ( 0, 30.5, 4.2, 0 ), ( 0, 0, 0, 0 ), ( 0, 0, 4.6, 0 ), ( 0, 0, 7, 8 ) )
208    //
209    %c7 = sparse_tensor.convert %7 : tensor<4x4xf64, #CSR> to tensor<4x4xf64>
210    %m7 = bufferization.to_memref %c7 : memref<4x4xf64>
211    %v7 = vector.transfer_read %m7[%c0, %c0], %d1 : memref<4x4xf64>, vector<4x4xf64>
212    vector.print %v7 : vector<4x4xf64>
213
214    //
215    // CHECK: ( ( 0, 30.5, 4.2, 0 ), ( 0, 0, 0, 0 ), ( 0, 0, 4.6, 0 ), ( 0, 0, 7, 8 ) )
216    //
217    %c8 = sparse_tensor.convert %8 : tensor<4x4xf64, #DCSR> to tensor<4x4xf64>
218    %m8 = bufferization.to_memref %c8 : memref<4x4xf64>
219    %v8 = vector.transfer_read %m8[%c0, %c0], %d1 : memref<4x4xf64>, vector<4x4xf64>
220    vector.print %v8 : vector<4x4xf64>
221
222    //
223    // Sanity check on nonzeros.
224    //
225    // CHECK: ( 30.5, 4.2, 4.6, 7, 8, -1, -1, -1 )
226    // CHECK: ( 30.5, 4.2, 4.6, 7, 8, -1, -1, -1 )
227    //
228    %val7 = sparse_tensor.values %7 : tensor<4x4xf64, #CSR> to memref<?xf64>
229    %val8 = sparse_tensor.values %8 : tensor<4x4xf64, #DCSR> to memref<?xf64>
230    %nz7 = vector.transfer_read %val7[%c0], %d1 : memref<?xf64>, vector<8xf64>
231    %nz8 = vector.transfer_read %val8[%c0], %d1 : memref<?xf64>, vector<8xf64>
232    vector.print %nz7 : vector<8xf64>
233    vector.print %nz8 : vector<8xf64>
234
235    // Release the resources.
236    sparse_tensor.release %a1 : tensor<4x8xf64, #CSR>
237    sparse_tensor.release %a2 : tensor<4x8xf64, #DCSR>
238    sparse_tensor.release %a3 : tensor<4x8xf64, #CSR>
239    sparse_tensor.release %a4 : tensor<4x8xf64, #DCSR>
240    sparse_tensor.release %b1 : tensor<8x4xf64, #CSR>
241    sparse_tensor.release %b2 : tensor<8x4xf64, #DCSR>
242    sparse_tensor.release %b3 : tensor<8x4xf64, #CSR>
243    sparse_tensor.release %b4 : tensor<8x4xf64, #DCSR>
244    sparse_tensor.release %1 : tensor<4x4xf64, #CSR>
245    sparse_tensor.release %2 : tensor<4x4xf64, #DCSR>
246    sparse_tensor.release %4 : tensor<4x4xf64, #CSR>
247    sparse_tensor.release %5 : tensor<4x4xf64, #DCSR>
248    sparse_tensor.release %7 : tensor<4x4xf64, #CSR>
249    sparse_tensor.release %8 : tensor<4x4xf64, #DCSR>
250    memref.dealloc %m0 : memref<4x4xf64>
251    memref.dealloc %m1 : memref<4x4xf64>
252    memref.dealloc %m2 : memref<4x4xf64>
253    memref.dealloc %m3 : memref<4x4xf64>
254    memref.dealloc %m4 : memref<4x4xf64>
255    memref.dealloc %m5 : memref<4x4xf64>
256    memref.dealloc %m6 : memref<4x4xf64>
257    memref.dealloc %m7 : memref<4x4xf64>
258    memref.dealloc %m8 : memref<4x4xf64>
259
260    return
261  }
262}
263