1; This testcase consists of alias relations on 128-bit pointers that
2; should be completely resolvable by basicaa.
3
4; RUN: opt < %s -aa-pipeline=basic-aa -passes=aa-eval -print-no-aliases -print-may-aliases -print-must-aliases -disable-output 2>&1 | FileCheck %s
5
6target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-i128:128:128-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128-p100:128:64:64-p101:128:64:64"
7
8
9; test0 is similar to SimpleCases.ll
10
11%T = type { i32, [10 x i8] }
12
13; CHECK:     Function: test0
14; CHECK-NOT:   MayAlias:
15define void @test0(%T addrspace(100)* %P) {
16  %A = getelementptr %T, %T addrspace(100)* %P, i64 0
17  %B = getelementptr %T, %T addrspace(100)* %P, i64 0, i32 0
18  %C = getelementptr %T, %T addrspace(100)* %P, i64 0, i32 1
19  %D = getelementptr %T, %T addrspace(100)* %P, i64 0, i32 1, i64 0
20  %E = getelementptr %T, %T addrspace(100)* %P, i64 0, i32 1, i64 5
21  load %T, %T addrspace(100)* %A
22  load i32, i32 addrspace(100)* %B
23  load [10 x i8], [10 x i8] addrspace(100)* %C
24  load i8, i8 addrspace(100)* %D
25  load i8, i8 addrspace(100)* %E
26  ret void
27}
28
29; test1 checks that >64 bits of index can be considered.
30; If BasicAA is truncating the arithmetic, it will conclude
31; that %A and %B must alias when in fact they must not.
32
33; CHECK:     Function: test1
34; CHECK-NOT:   MustAlias:
35; CHECK:       NoAlias:
36; CHECK-SAME:  %A
37; CHECK-SAME:  %B
38define void @test1(double addrspace(100)* %P, i128 %i) {
39  ; 1180591620717411303424 is 2**70
40  ;  590295810358705651712 is 2**69
41  %i70 = add i128 %i, 1180591620717411303424
42  %i69 = add i128 %i, 590295810358705651712
43  %A = getelementptr double, double addrspace(100)* %P, i128 %i70
44  %B = getelementptr double, double addrspace(100)* %P, i128 %i69
45  load double, double addrspace(100)* %A
46  load double, double addrspace(100)* %B
47  ret void
48}
49
50; test2 checks that >64 bits of index can be considered
51; and computes the same address in two ways to ensure that
52; they are considered equivalent.
53
54; CHECK: Function: test2
55; CHECK: MustAlias:
56; CHECK-SAME: %A
57; CHECK-SAME: %C
58define void @test2(double addrspace(100)* %P, i128 %i) {
59  ; 1180591620717411303424 is 2**70
60  ;  590295810358705651712 is 2**69
61  %i70 = add i128 %i, 1180591620717411303424
62  %i69 = add i128 %i, 590295810358705651712
63  %j70 = add i128 %i69, 590295810358705651712
64  %A = getelementptr double, double addrspace(100)* %P, i128 %i70
65  %C = getelementptr double, double addrspace(100)* %P, i128 %j70
66  load double, double addrspace(100)* %A
67  load double, double addrspace(100)* %C
68  ret void
69}
70