1//===- WebAssemblyInstrControl.td-WebAssembly control-flow ------*- tablegen -*-
2//
3//                     The LLVM Compiler Infrastructure
4//
5// This file is distributed under the University of Illinois Open Source
6// License. See LICENSE.TXT for details.
7//
8//===----------------------------------------------------------------------===//
9///
10/// \file
11/// WebAssembly control-flow code-gen constructs.
12///
13//===----------------------------------------------------------------------===//
14
15let isBranch = 1, isTerminator = 1, hasCtrlDep = 1 in {
16// The condition operand is a boolean value which WebAssembly represents as i32.
17defm BR_IF : I<(outs), (ins bb_op:$dst, I32:$cond),
18               (outs), (ins bb_op:$dst),
19               [(brcond I32:$cond, bb:$dst)],
20                "br_if   \t$dst, $cond", "br_if   \t$dst", 0x0d>;
21let isCodeGenOnly = 1 in
22defm BR_UNLESS : I<(outs), (ins bb_op:$dst, I32:$cond),
23                   (outs), (ins bb_op:$dst), []>;
24let isBarrier = 1 in {
25defm BR   : NRI<(outs), (ins bb_op:$dst),
26                [(br bb:$dst)],
27                "br      \t$dst", 0x0c>;
28} // isBarrier = 1
29} // isBranch = 1, isTerminator = 1, hasCtrlDep = 1
30
31def : Pat<(brcond (i32 (setne I32:$cond, 0)), bb:$dst),
32          (BR_IF bb_op:$dst, I32:$cond)>;
33def : Pat<(brcond (i32 (seteq I32:$cond, 0)), bb:$dst),
34          (BR_UNLESS bb_op:$dst, I32:$cond)>;
35
36// TODO: SelectionDAG's lowering insists on using a pointer as the index for
37// jump tables, so in practice we don't ever use BR_TABLE_I64 in wasm32 mode
38// currently.
39// Set TSFlags{0} to 1 to indicate that the variable_ops are immediates.
40// Set TSFlags{1} to 1 to indicate that the immediates represent labels.
41// FIXME: this can't inherit from I<> since there is no way to inherit from a
42// multiclass and still have the let statements.
43let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
44let isCodeGenOnly = 1 in
45def BR_TABLE_I32 : NI<(outs), (ins I32:$index, variable_ops),
46                      [(WebAssemblybr_table I32:$index)], 0,
47                      "br_table \t$index", 0x0e> {
48  let TSFlags{0} = 1;
49  let TSFlags{1} = 1;
50}
51def BR_TABLE_I32_S : NI<(outs), (ins variable_ops),
52                        [], 1,
53                        "br_table", 0x0e> {
54  let TSFlags{0} = 1;
55  let TSFlags{1} = 1;
56}
57let isCodeGenOnly = 1 in
58def BR_TABLE_I64 : NI<(outs), (ins I64:$index, variable_ops),
59                      [(WebAssemblybr_table I64:$index)], 0,
60                      "br_table \t$index"> {
61  let TSFlags{0} = 1;
62  let TSFlags{1} = 1;
63}
64def BR_TABLE_I64_S : NI<(outs), (ins variable_ops),
65                        [], 1,
66                        "br_table"> {
67  let TSFlags{0} = 1;
68  let TSFlags{1} = 1;
69}
70} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
71
72// This is technically a control-flow instruction, since all it affects is the
73// IP.
74defm NOP : NRI<(outs), (ins), [], "nop", 0x01>;
75
76// Placemarkers to indicate the start or end of a block or loop scope.
77// These use/clobber VALUE_STACK to prevent them from being moved into the
78// middle of an expression tree.
79let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
80defm BLOCK     : NRI<(outs), (ins Signature:$sig), [], "block   \t$sig", 0x02>;
81defm LOOP      : NRI<(outs), (ins Signature:$sig), [], "loop    \t$sig", 0x03>;
82
83// END_BLOCK, END_LOOP, and END_FUNCTION are represented with the same opcode in
84// wasm.
85defm END_BLOCK : NRI<(outs), (ins), [], "end_block", 0x0b>;
86defm END_LOOP  : NRI<(outs), (ins), [], "end_loop", 0x0b>;
87let isTerminator = 1, isBarrier = 1 in
88defm END_FUNCTION : NRI<(outs), (ins), [], "end_function", 0x0b>;
89} // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
90
91multiclass RETURN<WebAssemblyRegClass vt> {
92  defm RETURN_#vt : I<(outs), (ins vt:$val), (outs), (ins),
93                      [(WebAssemblyreturn vt:$val)],
94                      "return  \t$val", "return", 0x0f>;
95  // Equivalent to RETURN_#vt, for use at the end of a function when wasm
96  // semantics return by falling off the end of the block.
97  let isCodeGenOnly = 1 in
98  defm FALLTHROUGH_RETURN_#vt : I<(outs), (ins vt:$val), (outs), (ins), []>;
99}
100
101multiclass SIMD_RETURN<ValueType vt> {
102  defm RETURN_#vt : I<(outs), (ins V128:$val), (outs), (ins),
103                      [(WebAssemblyreturn (vt V128:$val))],
104                      "return  \t$val", "return", 0x0f>,
105                    Requires<[HasSIMD128]>;
106  // Equivalent to RETURN_#vt, for use at the end of a function when wasm
107  // semantics return by falling off the end of the block.
108  let isCodeGenOnly = 1 in
109  defm FALLTHROUGH_RETURN_#vt : I<(outs), (ins V128:$val), (outs), (ins),
110                                  []>,
111                                Requires<[HasSIMD128]>;
112}
113
114let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
115
116let isReturn = 1 in {
117  defm "": RETURN<I32>;
118  defm "": RETURN<I64>;
119  defm "": RETURN<F32>;
120  defm "": RETURN<F64>;
121  defm "": RETURN<EXCEPT_REF>;
122  defm "": SIMD_RETURN<v16i8>;
123  defm "": SIMD_RETURN<v8i16>;
124  defm "": SIMD_RETURN<v4i32>;
125  defm "": SIMD_RETURN<v2i64>;
126  defm "": SIMD_RETURN<v4f32>;
127  defm "": SIMD_RETURN<v2f64>;
128
129  defm RETURN_VOID : NRI<(outs), (ins), [(WebAssemblyreturn)], "return", 0x0f>;
130
131  // This is to RETURN_VOID what FALLTHROUGH_RETURN_#vt is to RETURN_#vt.
132  let isCodeGenOnly = 1 in
133  defm FALLTHROUGH_RETURN_VOID : NRI<(outs), (ins), []>;
134} // isReturn = 1
135
136defm UNREACHABLE : NRI<(outs), (ins), [(trap)], "unreachable", 0x00>;
137} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
138
139//===----------------------------------------------------------------------===//
140// Exception handling instructions
141//===----------------------------------------------------------------------===//
142
143let Predicates = [HasExceptionHandling] in {
144
145// Throwing an exception: throw / rethrow
146let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
147defm THROW_I32 : I<(outs), (ins i32imm:$tag, I32:$val),
148                   (outs), (ins i32imm:$tag),
149                   [(int_wasm_throw imm:$tag, I32:$val)],
150                   "throw   \t$tag, $val", "throw   \t$tag",
151                   0x08>;
152defm THROW_I64 : I<(outs), (ins i32imm:$tag, I64:$val),
153                   (outs), (ins i32imm:$tag),
154                   [(int_wasm_throw imm:$tag, I64:$val)],
155                   "throw   \t$tag, $val", "throw   \t$tag",
156                   0x08>;
157defm RETHROW : NRI<(outs), (ins bb_op:$dst), [], "rethrow \t$dst", 0x09>;
158let isCodeGenOnly = 1 in
159// This is used when the destination for rethrow is the caller function. This
160// will be converted to a rethrow in CFGStackify.
161defm RETHROW_TO_CALLER : NRI<(outs), (ins), [], "rethrow">;
162} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
163
164// Region within which an exception is caught: try / end_try
165let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
166defm TRY     : NRI<(outs), (ins Signature:$sig), [], "try     \t$sig", 0x06>;
167defm END_TRY : NRI<(outs), (ins), [], "end_try", 0x0b>;
168} // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
169
170// Catching an exception: catch / catch_all
171let hasCtrlDep = 1, hasSideEffects = 1 in {
172defm CATCH_I32 : I<(outs I32:$dst), (ins i32imm:$tag),
173                   (outs), (ins i32imm:$tag),
174                   [(set I32:$dst, (int_wasm_catch imm:$tag))],
175                   "i32.catch   \t$dst, $tag", "i32.catch   \t$tag", 0x07>;
176defm CATCH_I64 : I<(outs I64:$dst), (ins i32imm:$tag),
177                   (outs), (ins i32imm:$tag),
178                   [(set I64:$dst, (int_wasm_catch imm:$tag))],
179                   "i64.catch   \t$dst, $tag", "i64.catch   \t$tag", 0x07>;
180defm CATCH_ALL : NRI<(outs), (ins), [], "catch_all", 0x05>;
181}
182
183// Pseudo instructions: cleanupret / catchret
184let isTerminator = 1, hasSideEffects = 1, isBarrier = 1, hasCtrlDep = 1,
185    isCodeGenOnly = 1, isEHScopeReturn = 1 in {
186  defm CLEANUPRET : NRI<(outs), (ins), [(cleanupret)], "", 0>;
187  defm CATCHRET : NRI<(outs), (ins bb_op:$dst, bb_op:$from),
188                   [(catchret bb:$dst, bb:$from)], "", 0>;
189}
190}
191