1//===- WebAssemblyInstrControl.td-WebAssembly control-flow ------*- tablegen -*-
2//
3//                     The LLVM Compiler Infrastructure
4//
5// This file is distributed under the University of Illinois Open Source
6// License. See LICENSE.TXT for details.
7//
8//===----------------------------------------------------------------------===//
9///
10/// \file
11/// WebAssembly control-flow code-gen constructs.
12///
13//===----------------------------------------------------------------------===//
14
15let isBranch = 1, isTerminator = 1, hasCtrlDep = 1 in {
16// The condition operand is a boolean value which WebAssembly represents as i32.
17defm BR_IF : I<(outs), (ins bb_op:$dst, I32:$cond),
18               (outs), (ins bb_op:$dst),
19               [(brcond I32:$cond, bb:$dst)],
20                "br_if   \t$dst, $cond", "br_if   \t$dst", 0x0d>;
21let isCodeGenOnly = 1 in
22defm BR_UNLESS : I<(outs), (ins bb_op:$dst, I32:$cond),
23                   (outs), (ins bb_op:$dst), []>;
24let isBarrier = 1 in {
25defm BR   : NRI<(outs), (ins bb_op:$dst),
26                [(br bb:$dst)],
27                "br      \t$dst", 0x0c>;
28} // isBarrier = 1
29} // isBranch = 1, isTerminator = 1, hasCtrlDep = 1
30
31def : Pat<(brcond (i32 (setne I32:$cond, 0)), bb:$dst),
32          (BR_IF bb_op:$dst, I32:$cond)>;
33def : Pat<(brcond (i32 (seteq I32:$cond, 0)), bb:$dst),
34          (BR_UNLESS bb_op:$dst, I32:$cond)>;
35
36// A list of branch targets enclosed in {} and separated by comma.
37// Used by br_table only.
38def BrListAsmOperand : AsmOperandClass { let Name = "BrList"; }
39def brlist : Operand<i32> {
40  let ParserMatchClass = BrListAsmOperand;
41  let PrintMethod = "printBrList";
42}
43
44// TODO: SelectionDAG's lowering insists on using a pointer as the index for
45// jump tables, so in practice we don't ever use BR_TABLE_I64 in wasm32 mode
46// currently.
47// FIXME: this can't inherit from I<> since there is no way to inherit from a
48// multiclass and still have the let statements.
49let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
50let isCodeGenOnly = 1 in
51def BR_TABLE_I32 : NI<(outs), (ins I32:$index, variable_ops),
52                      [(WebAssemblybr_table I32:$index)], "false",
53                      "br_table \t$index", 0x0e> {
54}
55let BaseName = "BR_TABLE_I32" in
56def BR_TABLE_I32_S : NI<(outs), (ins brlist:$brl), [], "true",
57                        "br_table \t$brl", 0x0e> {
58}
59let isCodeGenOnly = 1 in
60def BR_TABLE_I64 : NI<(outs), (ins I64:$index, variable_ops),
61                      [(WebAssemblybr_table I64:$index)], "false",
62                      "br_table \t$index"> {
63}
64let BaseName = "BR_TABLE_I64" in
65def BR_TABLE_I64_S : NI<(outs), (ins brlist:$brl), [], "true",
66                        "br_table \t$brl"> {
67}
68} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
69
70// This is technically a control-flow instruction, since all it affects is the
71// IP.
72defm NOP : NRI<(outs), (ins), [], "nop", 0x01>;
73
74// Placemarkers to indicate the start or end of a block or loop scope.
75// These use/clobber VALUE_STACK to prevent them from being moved into the
76// middle of an expression tree.
77let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
78defm BLOCK : NRI<(outs), (ins Signature:$sig), [], "block   \t$sig", 0x02>;
79defm LOOP  : NRI<(outs), (ins Signature:$sig), [], "loop    \t$sig", 0x03>;
80
81defm IF : I<(outs), (ins Signature:$sig, I32:$cond),
82            (outs), (ins Signature:$sig),
83            [], "if    \t$sig, $cond", "if    \t$sig", 0x04>;
84defm ELSE : NRI<(outs), (ins), [], "else", 0x05>;
85
86// END_BLOCK, END_LOOP, END_IF and END_FUNCTION are represented with the same
87// opcode in wasm.
88defm END_BLOCK : NRI<(outs), (ins), [], "end_block", 0x0b>;
89defm END_LOOP  : NRI<(outs), (ins), [], "end_loop", 0x0b>;
90defm END_IF    : NRI<(outs), (ins), [], "end_if", 0x0b>;
91let isTerminator = 1, isBarrier = 1 in
92defm END_FUNCTION : NRI<(outs), (ins), [], "end_function", 0x0b>;
93} // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
94
95multiclass RETURN<WebAssemblyRegClass vt> {
96  defm RETURN_#vt : I<(outs), (ins vt:$val), (outs), (ins),
97                      [(WebAssemblyreturn vt:$val)],
98                      "return  \t$val", "return", 0x0f>;
99  // Equivalent to RETURN_#vt, for use at the end of a function when wasm
100  // semantics return by falling off the end of the block.
101  let isCodeGenOnly = 1 in
102  defm FALLTHROUGH_RETURN_#vt : I<(outs), (ins vt:$val), (outs), (ins), []>;
103}
104
105multiclass SIMD_RETURN<ValueType vt> {
106  defm RETURN_#vt : I<(outs), (ins V128:$val), (outs), (ins),
107                      [(WebAssemblyreturn (vt V128:$val))],
108                      "return  \t$val", "return", 0x0f>,
109                    Requires<[HasSIMD128]>;
110  // Equivalent to RETURN_#vt, for use at the end of a function when wasm
111  // semantics return by falling off the end of the block.
112  let isCodeGenOnly = 1 in
113  defm FALLTHROUGH_RETURN_#vt : I<(outs), (ins V128:$val), (outs), (ins),
114                                  []>,
115                                Requires<[HasSIMD128]>;
116}
117
118let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
119
120let isReturn = 1 in {
121  defm "": RETURN<I32>;
122  defm "": RETURN<I64>;
123  defm "": RETURN<F32>;
124  defm "": RETURN<F64>;
125  defm "": RETURN<EXCEPT_REF>;
126  defm "": SIMD_RETURN<v16i8>;
127  defm "": SIMD_RETURN<v8i16>;
128  defm "": SIMD_RETURN<v4i32>;
129  defm "": SIMD_RETURN<v2i64>;
130  defm "": SIMD_RETURN<v4f32>;
131  defm "": SIMD_RETURN<v2f64>;
132
133  defm RETURN_VOID : NRI<(outs), (ins), [(WebAssemblyreturn)], "return", 0x0f>;
134
135  // This is to RETURN_VOID what FALLTHROUGH_RETURN_#vt is to RETURN_#vt.
136  let isCodeGenOnly = 1 in
137  defm FALLTHROUGH_RETURN_VOID : NRI<(outs), (ins), []>;
138} // isReturn = 1
139
140defm UNREACHABLE : NRI<(outs), (ins), [(trap)], "unreachable", 0x00>;
141} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
142
143//===----------------------------------------------------------------------===//
144// Exception handling instructions
145//===----------------------------------------------------------------------===//
146
147let Predicates = [HasExceptionHandling] in {
148
149// Throwing an exception: throw / rethrow
150let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
151defm THROW_I32 : I<(outs), (ins event_op:$tag, I32:$val),
152                   (outs), (ins event_op:$tag),
153                   [(WebAssemblythrow (WebAssemblywrapper texternalsym:$tag),
154                                      I32:$val)],
155                   "throw   \t$tag, $val", "throw   \t$tag",
156                   0x08>;
157defm THROW_I64 : I<(outs), (ins event_op:$tag, I64:$val),
158                   (outs), (ins event_op:$tag),
159                   [(WebAssemblythrow (WebAssemblywrapper texternalsym:$tag),
160                                      I64:$val)],
161                   "throw   \t$tag, $val", "throw   \t$tag",
162                   0x08>;
163defm RETHROW : NRI<(outs), (ins bb_op:$dst), [], "rethrow \t$dst", 0x09>;
164let isCodeGenOnly = 1 in
165// This is used when the destination for rethrow is the caller function. This
166// will be converted to a rethrow in CFGStackify.
167defm RETHROW_TO_CALLER : NRI<(outs), (ins), [], "rethrow">;
168} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
169
170// Region within which an exception is caught: try / end_try
171let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
172defm TRY     : NRI<(outs), (ins Signature:$sig), [], "try     \t$sig", 0x06>;
173defm END_TRY : NRI<(outs), (ins), [], "end_try", 0x0b>;
174} // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
175
176// Catching an exception: catch / catch_all
177let hasCtrlDep = 1, hasSideEffects = 1 in {
178defm CATCH_I32 : I<(outs I32:$dst), (ins i32imm:$tag),
179                   (outs), (ins i32imm:$tag),
180                   [(set I32:$dst, (int_wasm_catch imm:$tag))],
181                   "i32.catch   \t$dst, $tag", "i32.catch   \t$tag", 0x07>;
182defm CATCH_I64 : I<(outs I64:$dst), (ins i32imm:$tag),
183                   (outs), (ins i32imm:$tag),
184                   [(set I64:$dst, (int_wasm_catch imm:$tag))],
185                   "i64.catch   \t$dst, $tag", "i64.catch   \t$tag", 0x07>;
186defm CATCH_ALL : NRI<(outs), (ins), [], "catch_all", 0x05>;
187}
188
189// Pseudo instructions: cleanupret / catchret
190let isTerminator = 1, hasSideEffects = 1, isBarrier = 1, hasCtrlDep = 1,
191    isCodeGenOnly = 1, isEHScopeReturn = 1 in {
192  defm CLEANUPRET : NRI<(outs), (ins), [(cleanupret)], "", 0>;
193  defm CATCHRET : NRI<(outs), (ins bb_op:$dst, bb_op:$from),
194                   [(catchret bb:$dst, bb:$from)], "", 0>;
195}
196}
197