1//===- WebAssemblyInstrControl.td-WebAssembly control-flow ------*- tablegen -*-
2//
3// Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
4// See https://llvm.org/LICENSE.txt for license information.
5// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
6//
7//===----------------------------------------------------------------------===//
8///
9/// \file
10/// WebAssembly control-flow code-gen constructs.
11///
12//===----------------------------------------------------------------------===//
13
14let isBranch = 1, isTerminator = 1, hasCtrlDep = 1 in {
15// The condition operand is a boolean value which WebAssembly represents as i32.
16defm BR_IF : I<(outs), (ins bb_op:$dst, I32:$cond),
17               (outs), (ins bb_op:$dst),
18               [(brcond I32:$cond, bb:$dst)],
19                "br_if   \t$dst, $cond", "br_if   \t$dst", 0x0d>;
20let isCodeGenOnly = 1 in
21defm BR_UNLESS : I<(outs), (ins bb_op:$dst, I32:$cond),
22                   (outs), (ins bb_op:$dst), []>;
23let isBarrier = 1 in {
24defm BR   : NRI<(outs), (ins bb_op:$dst),
25                [(br bb:$dst)],
26                "br      \t$dst", 0x0c>;
27} // isBarrier = 1
28} // isBranch = 1, isTerminator = 1, hasCtrlDep = 1
29
30def : Pat<(brcond (i32 (setne I32:$cond, 0)), bb:$dst),
31          (BR_IF bb_op:$dst, I32:$cond)>;
32def : Pat<(brcond (i32 (seteq I32:$cond, 0)), bb:$dst),
33          (BR_UNLESS bb_op:$dst, I32:$cond)>;
34
35// A list of branch targets enclosed in {} and separated by comma.
36// Used by br_table only.
37def BrListAsmOperand : AsmOperandClass { let Name = "BrList"; }
38let OperandNamespace = "WebAssembly" in {
39let OperandType = "OPERAND_BRLIST" in {
40def brlist : Operand<i32> {
41  let ParserMatchClass = BrListAsmOperand;
42  let PrintMethod = "printBrList";
43}
44} // OPERAND_BRLIST
45} // OperandNamespace = "WebAssembly"
46
47// TODO: SelectionDAG's lowering insists on using a pointer as the index for
48// jump tables, so in practice we don't ever use BR_TABLE_I64 in wasm32 mode
49// currently.
50let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
51defm BR_TABLE_I32 : I<(outs), (ins I32:$index, variable_ops),
52                      (outs), (ins brlist:$brl),
53                      [(WebAssemblybr_table I32:$index)],
54                      "br_table \t$index", "br_table \t$brl",
55                      0x0e>;
56defm BR_TABLE_I64 : I<(outs), (ins I64:$index, variable_ops),
57                      (outs), (ins brlist:$brl),
58                      [(WebAssemblybr_table I64:$index)],
59                      "br_table \t$index", "br_table \t$brl",
60                      0x0e>;
61} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
62
63// This is technically a control-flow instruction, since all it affects is the
64// IP.
65defm NOP : NRI<(outs), (ins), [], "nop", 0x01>;
66
67// Placemarkers to indicate the start or end of a block or loop scope.
68// These use/clobber VALUE_STACK to prevent them from being moved into the
69// middle of an expression tree.
70let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
71defm BLOCK : NRI<(outs), (ins Signature:$sig), [], "block   \t$sig", 0x02>;
72defm LOOP  : NRI<(outs), (ins Signature:$sig), [], "loop    \t$sig", 0x03>;
73
74defm IF : I<(outs), (ins Signature:$sig, I32:$cond),
75            (outs), (ins Signature:$sig),
76            [], "if    \t$sig, $cond", "if    \t$sig", 0x04>;
77defm ELSE : NRI<(outs), (ins), [], "else", 0x05>;
78
79// END_BLOCK, END_LOOP, END_IF and END_FUNCTION are represented with the same
80// opcode in wasm.
81defm END_BLOCK : NRI<(outs), (ins), [], "end_block", 0x0b>;
82defm END_LOOP  : NRI<(outs), (ins), [], "end_loop", 0x0b>;
83defm END_IF    : NRI<(outs), (ins), [], "end_if", 0x0b>;
84let isTerminator = 1, isBarrier = 1 in
85defm END_FUNCTION : NRI<(outs), (ins), [], "end_function", 0x0b>;
86} // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
87
88multiclass RETURN<WebAssemblyRegClass vt> {
89  defm RETURN_#vt : I<(outs), (ins vt:$val), (outs), (ins),
90                      [(WebAssemblyreturn vt:$val)],
91                      "return  \t$val", "return", 0x0f>;
92  // Equivalent to RETURN_#vt, for use at the end of a function when wasm
93  // semantics return by falling off the end of the block.
94  let isCodeGenOnly = 1 in
95  defm FALLTHROUGH_RETURN_#vt : I<(outs), (ins vt:$val), (outs), (ins), []>;
96}
97
98multiclass SIMD_RETURN<ValueType vt> {
99  defm RETURN_#vt : I<(outs), (ins V128:$val), (outs), (ins),
100                      [(WebAssemblyreturn (vt V128:$val))],
101                      "return  \t$val", "return", 0x0f>,
102                    Requires<[HasSIMD128]>;
103  // Equivalent to RETURN_#vt, for use at the end of a function when wasm
104  // semantics return by falling off the end of the block.
105  let isCodeGenOnly = 1 in
106  defm FALLTHROUGH_RETURN_#vt : I<(outs), (ins V128:$val), (outs), (ins),
107                                  []>,
108                                Requires<[HasSIMD128]>;
109}
110
111let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
112
113let isReturn = 1 in {
114  defm "": RETURN<I32>;
115  defm "": RETURN<I64>;
116  defm "": RETURN<F32>;
117  defm "": RETURN<F64>;
118  defm "": RETURN<EXCEPT_REF>;
119  defm "": SIMD_RETURN<v16i8>;
120  defm "": SIMD_RETURN<v8i16>;
121  defm "": SIMD_RETURN<v4i32>;
122  defm "": SIMD_RETURN<v2i64>;
123  defm "": SIMD_RETURN<v4f32>;
124  defm "": SIMD_RETURN<v2f64>;
125
126  defm RETURN_VOID : NRI<(outs), (ins), [(WebAssemblyreturn)], "return", 0x0f>;
127
128  // This is to RETURN_VOID what FALLTHROUGH_RETURN_#vt is to RETURN_#vt.
129  let isCodeGenOnly = 1 in
130  defm FALLTHROUGH_RETURN_VOID : NRI<(outs), (ins), []>;
131} // isReturn = 1
132
133defm UNREACHABLE : NRI<(outs), (ins), [(trap)], "unreachable", 0x00>;
134} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
135
136//===----------------------------------------------------------------------===//
137// Exception handling instructions
138//===----------------------------------------------------------------------===//
139
140let Predicates = [HasExceptionHandling] in {
141
142// Throwing an exception: throw / rethrow
143let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
144defm THROW : I<(outs), (ins event_op:$tag, variable_ops),
145               (outs), (ins event_op:$tag),
146               [(WebAssemblythrow (WebAssemblywrapper texternalsym:$tag))],
147               "throw   \t$tag", "throw   \t$tag", 0x08>;
148defm RETHROW : NRI<(outs), (ins), [(int_wasm_rethrow)], "rethrow", 0x09>;
149} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
150
151// Region within which an exception is caught: try / end_try
152let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
153defm TRY     : NRI<(outs), (ins Signature:$sig), [], "try     \t$sig", 0x06>;
154defm END_TRY : NRI<(outs), (ins), [], "end_try", 0x0b>;
155} // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
156
157// Catching an exception: catch / extract_exception
158let hasCtrlDep = 1, hasSideEffects = 1 in
159defm CATCH : I<(outs EXCEPT_REF:$dst), (ins), (outs), (ins), [],
160               "catch   \t$dst", "catch", 0x07>;
161
162// Querying / extracing exception: br_on_exn
163// br_on_exn queries an except_ref to see if it matches the corresponding
164// exception tag index. If true it branches to the given label and pushes the
165// corresponding argument values of the exception onto the stack.
166let isBranch = 1, isTerminator = 1, hasCtrlDep = 1 in
167defm BR_ON_EXN : I<(outs), (ins bb_op:$dst, event_op:$tag, EXCEPT_REF:$exn),
168                   (outs), (ins bb_op:$dst, event_op:$tag), [],
169                   "br_on_exn \t$dst, $tag, $exn", "br_on_exn \t$dst, $tag",
170                   0x0a>;
171// This is a pseudo instruction that simulates popping a value from stack, which
172// has been pushed by br_on_exn
173let isCodeGenOnly = 1, hasSideEffects = 1 in
174defm EXTRACT_EXCEPTION_I32 : NRI<(outs I32:$dst), (ins),
175                                 [(set I32:$dst, (int_wasm_extract_exception))],
176                                 "extract_exception\t$dst">;
177
178// Pseudo instructions: cleanupret / catchret
179let isTerminator = 1, hasSideEffects = 1, isBarrier = 1, hasCtrlDep = 1,
180    isPseudo = 1, isEHScopeReturn = 1 in {
181  defm CLEANUPRET : NRI<(outs), (ins), [(cleanupret)], "cleanupret", 0>;
182  defm CATCHRET : NRI<(outs), (ins bb_op:$dst, bb_op:$from),
183                      [(catchret bb:$dst, bb:$from)], "catchret", 0>;
184} // isTerminator = 1, hasSideEffects = 1, isBarrier = 1, hasCtrlDep = 1,
185  // isPseudo = 1, isEHScopeReturn = 1
186}
187