1//===-- SystemZOperators.td - SystemZ-specific operators ------*- tblgen-*-===//
2//
3//                     The LLVM Compiler Infrastructure
4//
5// This file is distributed under the University of Illinois Open Source
6// License. See LICENSE.TXT for details.
7//
8//===----------------------------------------------------------------------===//
9
10//===----------------------------------------------------------------------===//
11// Type profiles
12//===----------------------------------------------------------------------===//
13def SDT_CallSeqStart        : SDCallSeqStart<[SDTCisVT<0, i64>]>;
14def SDT_CallSeqEnd          : SDCallSeqEnd<[SDTCisVT<0, i64>,
15                                            SDTCisVT<1, i64>]>;
16def SDT_ZCall               : SDTypeProfile<0, -1, [SDTCisPtrTy<0>]>;
17def SDT_ZCmp                : SDTypeProfile<0, 2, [SDTCisSameAs<0, 1>]>;
18def SDT_ZICmp               : SDTypeProfile<0, 3,
19                                            [SDTCisSameAs<0, 1>,
20                                             SDTCisVT<2, i32>]>;
21def SDT_ZBRCCMask           : SDTypeProfile<0, 3,
22                                            [SDTCisVT<0, i32>,
23                                             SDTCisVT<1, i32>,
24                                             SDTCisVT<2, OtherVT>]>;
25def SDT_ZSelectCCMask       : SDTypeProfile<1, 4,
26                                            [SDTCisSameAs<0, 1>,
27                                             SDTCisSameAs<1, 2>,
28                                             SDTCisVT<3, i32>,
29                                             SDTCisVT<4, i32>]>;
30def SDT_ZWrapPtr            : SDTypeProfile<1, 1,
31                                            [SDTCisSameAs<0, 1>,
32                                             SDTCisPtrTy<0>]>;
33def SDT_ZWrapOffset         : SDTypeProfile<1, 2,
34                                            [SDTCisSameAs<0, 1>,
35                                             SDTCisSameAs<0, 2>,
36                                             SDTCisPtrTy<0>]>;
37def SDT_ZAdjDynAlloc        : SDTypeProfile<1, 0, [SDTCisVT<0, i64>]>;
38def SDT_ZExtractAccess      : SDTypeProfile<1, 1,
39                                            [SDTCisVT<0, i32>,
40                                             SDTCisVT<1, i32>]>;
41def SDT_ZGR128Binary32      : SDTypeProfile<1, 2,
42                                            [SDTCisVT<0, untyped>,
43                                             SDTCisVT<1, untyped>,
44                                             SDTCisVT<2, i32>]>;
45def SDT_ZGR128Binary64      : SDTypeProfile<1, 2,
46                                            [SDTCisVT<0, untyped>,
47                                             SDTCisVT<1, untyped>,
48                                             SDTCisVT<2, i64>]>;
49def SDT_ZAtomicLoadBinaryW  : SDTypeProfile<1, 5,
50                                            [SDTCisVT<0, i32>,
51                                             SDTCisPtrTy<1>,
52                                             SDTCisVT<2, i32>,
53                                             SDTCisVT<3, i32>,
54                                             SDTCisVT<4, i32>,
55                                             SDTCisVT<5, i32>]>;
56def SDT_ZAtomicCmpSwapW     : SDTypeProfile<1, 6,
57                                            [SDTCisVT<0, i32>,
58                                             SDTCisPtrTy<1>,
59                                             SDTCisVT<2, i32>,
60                                             SDTCisVT<3, i32>,
61                                             SDTCisVT<4, i32>,
62                                             SDTCisVT<5, i32>,
63                                             SDTCisVT<6, i32>]>;
64def SDT_ZMemMemLength       : SDTypeProfile<0, 3,
65                                            [SDTCisPtrTy<0>,
66                                             SDTCisPtrTy<1>,
67                                             SDTCisVT<2, i64>]>;
68def SDT_ZMemMemLoop         : SDTypeProfile<0, 4,
69                                            [SDTCisPtrTy<0>,
70                                             SDTCisPtrTy<1>,
71                                             SDTCisVT<2, i64>,
72                                             SDTCisVT<3, i64>]>;
73def SDT_ZString             : SDTypeProfile<1, 3,
74                                            [SDTCisPtrTy<0>,
75                                             SDTCisPtrTy<1>,
76                                             SDTCisPtrTy<2>,
77                                             SDTCisVT<3, i32>]>;
78def SDT_ZI32Intrinsic       : SDTypeProfile<1, 0, [SDTCisVT<0, i32>]>;
79def SDT_ZPrefetch           : SDTypeProfile<0, 2,
80                                            [SDTCisVT<0, i32>,
81                                             SDTCisPtrTy<1>]>;
82def SDT_ZLoadBSwap          : SDTypeProfile<1, 2,
83                                            [SDTCisInt<0>,
84                                             SDTCisPtrTy<1>,
85                                             SDTCisVT<2, OtherVT>]>;
86def SDT_ZStoreBSwap         : SDTypeProfile<0, 3,
87                                            [SDTCisInt<0>,
88                                             SDTCisPtrTy<1>,
89                                             SDTCisVT<2, OtherVT>]>;
90def SDT_ZTBegin             : SDTypeProfile<0, 2,
91                                            [SDTCisPtrTy<0>,
92                                             SDTCisVT<1, i32>]>;
93def SDT_ZInsertVectorElt    : SDTypeProfile<1, 3,
94                                            [SDTCisVec<0>,
95                                             SDTCisSameAs<0, 1>,
96                                             SDTCisVT<3, i32>]>;
97def SDT_ZExtractVectorElt   : SDTypeProfile<1, 2,
98                                            [SDTCisVec<1>,
99                                             SDTCisVT<2, i32>]>;
100def SDT_ZReplicate          : SDTypeProfile<1, 1,
101                                            [SDTCisVec<0>]>;
102def SDT_ZVecUnaryConv       : SDTypeProfile<1, 1,
103                                            [SDTCisVec<0>,
104                                             SDTCisVec<1>]>;
105def SDT_ZVecUnary           : SDTypeProfile<1, 1,
106                                            [SDTCisVec<0>,
107                                             SDTCisSameAs<0, 1>]>;
108def SDT_ZVecBinary          : SDTypeProfile<1, 2,
109                                            [SDTCisVec<0>,
110                                             SDTCisSameAs<0, 1>,
111                                             SDTCisSameAs<0, 2>]>;
112def SDT_ZVecBinaryInt       : SDTypeProfile<1, 2,
113                                            [SDTCisVec<0>,
114                                             SDTCisSameAs<0, 1>,
115                                             SDTCisVT<2, i32>]>;
116def SDT_ZVecBinaryConv      : SDTypeProfile<1, 2,
117                                            [SDTCisVec<0>,
118                                             SDTCisVec<1>,
119                                             SDTCisSameAs<1, 2>]>;
120def SDT_ZVecBinaryConvInt   : SDTypeProfile<1, 2,
121                                            [SDTCisVec<0>,
122                                             SDTCisVec<1>,
123                                             SDTCisVT<2, i32>]>;
124def SDT_ZRotateMask         : SDTypeProfile<1, 2,
125                                            [SDTCisVec<0>,
126                                             SDTCisVT<1, i32>,
127                                             SDTCisVT<2, i32>]>;
128def SDT_ZJoinDwords         : SDTypeProfile<1, 2,
129                                            [SDTCisVT<0, v2i64>,
130                                             SDTCisVT<1, i64>,
131                                             SDTCisVT<2, i64>]>;
132def SDT_ZVecTernary         : SDTypeProfile<1, 3,
133                                            [SDTCisVec<0>,
134                                             SDTCisSameAs<0, 1>,
135                                             SDTCisSameAs<0, 2>,
136                                             SDTCisSameAs<0, 3>]>;
137def SDT_ZVecTernaryInt      : SDTypeProfile<1, 3,
138                                            [SDTCisVec<0>,
139                                             SDTCisSameAs<0, 1>,
140                                             SDTCisSameAs<0, 2>,
141                                             SDTCisVT<3, i32>]>;
142def SDT_ZVecQuaternaryInt   : SDTypeProfile<1, 4,
143                                            [SDTCisVec<0>,
144                                             SDTCisSameAs<0, 1>,
145                                             SDTCisSameAs<0, 2>,
146                                             SDTCisSameAs<0, 3>,
147                                             SDTCisVT<4, i32>]>;
148def SDT_ZTest               : SDTypeProfile<0, 2, [SDTCisVT<1, i64>]>;
149
150//===----------------------------------------------------------------------===//
151// Node definitions
152//===----------------------------------------------------------------------===//
153
154// These are target-independent nodes, but have target-specific formats.
155def callseq_start       : SDNode<"ISD::CALLSEQ_START", SDT_CallSeqStart,
156                                 [SDNPHasChain, SDNPSideEffect, SDNPOutGlue]>;
157def callseq_end         : SDNode<"ISD::CALLSEQ_END",   SDT_CallSeqEnd,
158                                 [SDNPHasChain, SDNPSideEffect, SDNPOptInGlue,
159                                  SDNPOutGlue]>;
160def global_offset_table : SDNode<"ISD::GLOBAL_OFFSET_TABLE", SDTPtrLeaf>;
161
162// Nodes for SystemZISD::*.  See SystemZISelLowering.h for more details.
163def z_retflag           : SDNode<"SystemZISD::RET_FLAG", SDTNone,
164                                 [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
165def z_call              : SDNode<"SystemZISD::CALL", SDT_ZCall,
166                                 [SDNPHasChain, SDNPOutGlue, SDNPOptInGlue,
167                                  SDNPVariadic]>;
168def z_sibcall           : SDNode<"SystemZISD::SIBCALL", SDT_ZCall,
169                                 [SDNPHasChain, SDNPOutGlue, SDNPOptInGlue,
170                                  SDNPVariadic]>;
171def z_tls_gdcall        : SDNode<"SystemZISD::TLS_GDCALL", SDT_ZCall,
172                                 [SDNPHasChain, SDNPInGlue, SDNPOutGlue,
173                                  SDNPVariadic]>;
174def z_tls_ldcall        : SDNode<"SystemZISD::TLS_LDCALL", SDT_ZCall,
175                                 [SDNPHasChain, SDNPInGlue, SDNPOutGlue,
176                                  SDNPVariadic]>;
177def z_pcrel_wrapper     : SDNode<"SystemZISD::PCREL_WRAPPER", SDT_ZWrapPtr, []>;
178def z_pcrel_offset      : SDNode<"SystemZISD::PCREL_OFFSET",
179                                 SDT_ZWrapOffset, []>;
180def z_iabs              : SDNode<"SystemZISD::IABS", SDTIntUnaryOp, []>;
181def z_icmp              : SDNode<"SystemZISD::ICMP", SDT_ZICmp, [SDNPOutGlue]>;
182def z_fcmp              : SDNode<"SystemZISD::FCMP", SDT_ZCmp, [SDNPOutGlue]>;
183def z_tm                : SDNode<"SystemZISD::TM", SDT_ZICmp, [SDNPOutGlue]>;
184def z_br_ccmask         : SDNode<"SystemZISD::BR_CCMASK", SDT_ZBRCCMask,
185                                 [SDNPHasChain, SDNPInGlue]>;
186def z_select_ccmask     : SDNode<"SystemZISD::SELECT_CCMASK", SDT_ZSelectCCMask,
187    		                 [SDNPInGlue]>;
188def z_adjdynalloc       : SDNode<"SystemZISD::ADJDYNALLOC", SDT_ZAdjDynAlloc>;
189def z_extract_access    : SDNode<"SystemZISD::EXTRACT_ACCESS",
190                                 SDT_ZExtractAccess>;
191def z_popcnt            : SDNode<"SystemZISD::POPCNT", SDTIntUnaryOp>;
192def z_umul_lohi64       : SDNode<"SystemZISD::UMUL_LOHI64", SDT_ZGR128Binary64>;
193def z_sdivrem32         : SDNode<"SystemZISD::SDIVREM32", SDT_ZGR128Binary32>;
194def z_sdivrem64         : SDNode<"SystemZISD::SDIVREM64", SDT_ZGR128Binary64>;
195def z_udivrem32         : SDNode<"SystemZISD::UDIVREM32", SDT_ZGR128Binary32>;
196def z_udivrem64         : SDNode<"SystemZISD::UDIVREM64", SDT_ZGR128Binary64>;
197
198def z_serialize         : SDNode<"SystemZISD::SERIALIZE", SDTNone,
199                                 [SDNPHasChain, SDNPMayStore]>;
200def z_membarrier        : SDNode<"SystemZISD::MEMBARRIER", SDTNone,
201                                 [SDNPHasChain, SDNPSideEffect]>;
202
203def z_loadbswap        : SDNode<"SystemZISD::LRV", SDT_ZLoadBSwap,
204                                 [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
205def z_storebswap       : SDNode<"SystemZISD::STRV", SDT_ZStoreBSwap,
206                                 [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
207
208def z_tdc               : SDNode<"SystemZISD::TDC", SDT_ZTest, [SDNPOutGlue]>;
209
210// Defined because the index is an i32 rather than a pointer.
211def z_vector_insert     : SDNode<"ISD::INSERT_VECTOR_ELT",
212                                 SDT_ZInsertVectorElt>;
213def z_vector_extract    : SDNode<"ISD::EXTRACT_VECTOR_ELT",
214                                 SDT_ZExtractVectorElt>;
215def z_byte_mask         : SDNode<"SystemZISD::BYTE_MASK", SDT_ZReplicate>;
216def z_rotate_mask       : SDNode<"SystemZISD::ROTATE_MASK", SDT_ZRotateMask>;
217def z_replicate         : SDNode<"SystemZISD::REPLICATE", SDT_ZReplicate>;
218def z_join_dwords       : SDNode<"SystemZISD::JOIN_DWORDS", SDT_ZJoinDwords>;
219def z_splat             : SDNode<"SystemZISD::SPLAT", SDT_ZVecBinaryInt>;
220def z_merge_high        : SDNode<"SystemZISD::MERGE_HIGH", SDT_ZVecBinary>;
221def z_merge_low         : SDNode<"SystemZISD::MERGE_LOW", SDT_ZVecBinary>;
222def z_shl_double        : SDNode<"SystemZISD::SHL_DOUBLE", SDT_ZVecTernaryInt>;
223def z_permute_dwords    : SDNode<"SystemZISD::PERMUTE_DWORDS",
224                                 SDT_ZVecTernaryInt>;
225def z_permute           : SDNode<"SystemZISD::PERMUTE", SDT_ZVecTernary>;
226def z_pack              : SDNode<"SystemZISD::PACK", SDT_ZVecBinaryConv>;
227def z_packs_cc          : SDNode<"SystemZISD::PACKS_CC", SDT_ZVecBinaryConv,
228                                 [SDNPOutGlue]>;
229def z_packls_cc         : SDNode<"SystemZISD::PACKLS_CC", SDT_ZVecBinaryConv,
230                                 [SDNPOutGlue]>;
231def z_unpack_high       : SDNode<"SystemZISD::UNPACK_HIGH", SDT_ZVecUnaryConv>;
232def z_unpackl_high      : SDNode<"SystemZISD::UNPACKL_HIGH", SDT_ZVecUnaryConv>;
233def z_unpack_low        : SDNode<"SystemZISD::UNPACK_LOW", SDT_ZVecUnaryConv>;
234def z_unpackl_low       : SDNode<"SystemZISD::UNPACKL_LOW", SDT_ZVecUnaryConv>;
235def z_vshl_by_scalar    : SDNode<"SystemZISD::VSHL_BY_SCALAR",
236                                 SDT_ZVecBinaryInt>;
237def z_vsrl_by_scalar    : SDNode<"SystemZISD::VSRL_BY_SCALAR",
238                                 SDT_ZVecBinaryInt>;
239def z_vsra_by_scalar    : SDNode<"SystemZISD::VSRA_BY_SCALAR",
240                                 SDT_ZVecBinaryInt>;
241def z_vsum              : SDNode<"SystemZISD::VSUM", SDT_ZVecBinaryConv>;
242def z_vicmpe            : SDNode<"SystemZISD::VICMPE", SDT_ZVecBinary>;
243def z_vicmph            : SDNode<"SystemZISD::VICMPH", SDT_ZVecBinary>;
244def z_vicmphl           : SDNode<"SystemZISD::VICMPHL", SDT_ZVecBinary>;
245def z_vicmpes           : SDNode<"SystemZISD::VICMPES", SDT_ZVecBinary,
246                                 [SDNPOutGlue]>;
247def z_vicmphs           : SDNode<"SystemZISD::VICMPHS", SDT_ZVecBinary,
248                                 [SDNPOutGlue]>;
249def z_vicmphls          : SDNode<"SystemZISD::VICMPHLS", SDT_ZVecBinary,
250                                 [SDNPOutGlue]>;
251def z_vfcmpe            : SDNode<"SystemZISD::VFCMPE", SDT_ZVecBinaryConv>;
252def z_vfcmph            : SDNode<"SystemZISD::VFCMPH", SDT_ZVecBinaryConv>;
253def z_vfcmphe           : SDNode<"SystemZISD::VFCMPHE", SDT_ZVecBinaryConv>;
254def z_vfcmpes           : SDNode<"SystemZISD::VFCMPES", SDT_ZVecBinaryConv,
255                                 [SDNPOutGlue]>;
256def z_vfcmphs           : SDNode<"SystemZISD::VFCMPHS", SDT_ZVecBinaryConv,
257                                 [SDNPOutGlue]>;
258def z_vfcmphes          : SDNode<"SystemZISD::VFCMPHES", SDT_ZVecBinaryConv,
259                                 [SDNPOutGlue]>;
260def z_vextend           : SDNode<"SystemZISD::VEXTEND", SDT_ZVecUnaryConv>;
261def z_vround            : SDNode<"SystemZISD::VROUND", SDT_ZVecUnaryConv>;
262def z_vtm               : SDNode<"SystemZISD::VTM", SDT_ZCmp, [SDNPOutGlue]>;
263def z_vfae_cc           : SDNode<"SystemZISD::VFAE_CC", SDT_ZVecTernaryInt,
264                                 [SDNPOutGlue]>;
265def z_vfaez_cc          : SDNode<"SystemZISD::VFAEZ_CC", SDT_ZVecTernaryInt,
266                                 [SDNPOutGlue]>;
267def z_vfee_cc           : SDNode<"SystemZISD::VFEE_CC", SDT_ZVecBinary,
268                                 [SDNPOutGlue]>;
269def z_vfeez_cc          : SDNode<"SystemZISD::VFEEZ_CC", SDT_ZVecBinary,
270                                 [SDNPOutGlue]>;
271def z_vfene_cc          : SDNode<"SystemZISD::VFENE_CC", SDT_ZVecBinary,
272                                 [SDNPOutGlue]>;
273def z_vfenez_cc         : SDNode<"SystemZISD::VFENEZ_CC", SDT_ZVecBinary,
274                                 [SDNPOutGlue]>;
275def z_vistr_cc          : SDNode<"SystemZISD::VISTR_CC", SDT_ZVecUnary,
276                                 [SDNPOutGlue]>;
277def z_vstrc_cc          : SDNode<"SystemZISD::VSTRC_CC", SDT_ZVecQuaternaryInt,
278                                 [SDNPOutGlue]>;
279def z_vstrcz_cc         : SDNode<"SystemZISD::VSTRCZ_CC",
280                                 SDT_ZVecQuaternaryInt, [SDNPOutGlue]>;
281def z_vftci             : SDNode<"SystemZISD::VFTCI", SDT_ZVecBinaryConvInt,
282                                 [SDNPOutGlue]>;
283
284class AtomicWOp<string name, SDTypeProfile profile = SDT_ZAtomicLoadBinaryW>
285  : SDNode<"SystemZISD::"##name, profile,
286           [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
287
288def z_atomic_swapw      : AtomicWOp<"ATOMIC_SWAPW">;
289def z_atomic_loadw_add  : AtomicWOp<"ATOMIC_LOADW_ADD">;
290def z_atomic_loadw_sub  : AtomicWOp<"ATOMIC_LOADW_SUB">;
291def z_atomic_loadw_and  : AtomicWOp<"ATOMIC_LOADW_AND">;
292def z_atomic_loadw_or   : AtomicWOp<"ATOMIC_LOADW_OR">;
293def z_atomic_loadw_xor  : AtomicWOp<"ATOMIC_LOADW_XOR">;
294def z_atomic_loadw_nand : AtomicWOp<"ATOMIC_LOADW_NAND">;
295def z_atomic_loadw_min  : AtomicWOp<"ATOMIC_LOADW_MIN">;
296def z_atomic_loadw_max  : AtomicWOp<"ATOMIC_LOADW_MAX">;
297def z_atomic_loadw_umin : AtomicWOp<"ATOMIC_LOADW_UMIN">;
298def z_atomic_loadw_umax : AtomicWOp<"ATOMIC_LOADW_UMAX">;
299def z_atomic_cmp_swapw  : AtomicWOp<"ATOMIC_CMP_SWAPW", SDT_ZAtomicCmpSwapW>;
300
301def z_mvc               : SDNode<"SystemZISD::MVC", SDT_ZMemMemLength,
302                                 [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
303def z_mvc_loop          : SDNode<"SystemZISD::MVC_LOOP", SDT_ZMemMemLoop,
304                                 [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
305def z_nc                : SDNode<"SystemZISD::NC", SDT_ZMemMemLength,
306                                  [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
307def z_nc_loop           : SDNode<"SystemZISD::NC_LOOP", SDT_ZMemMemLoop,
308                                  [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
309def z_oc                : SDNode<"SystemZISD::OC", SDT_ZMemMemLength,
310                                  [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
311def z_oc_loop           : SDNode<"SystemZISD::OC_LOOP", SDT_ZMemMemLoop,
312                                  [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
313def z_xc                : SDNode<"SystemZISD::XC", SDT_ZMemMemLength,
314                                  [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
315def z_xc_loop           : SDNode<"SystemZISD::XC_LOOP", SDT_ZMemMemLoop,
316                                  [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
317def z_clc               : SDNode<"SystemZISD::CLC", SDT_ZMemMemLength,
318                                 [SDNPHasChain, SDNPOutGlue, SDNPMayLoad]>;
319def z_clc_loop          : SDNode<"SystemZISD::CLC_LOOP", SDT_ZMemMemLoop,
320                                 [SDNPHasChain, SDNPOutGlue, SDNPMayLoad]>;
321def z_strcmp            : SDNode<"SystemZISD::STRCMP", SDT_ZString,
322                                 [SDNPHasChain, SDNPOutGlue, SDNPMayLoad]>;
323def z_stpcpy            : SDNode<"SystemZISD::STPCPY", SDT_ZString,
324                                 [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
325def z_search_string     : SDNode<"SystemZISD::SEARCH_STRING", SDT_ZString,
326                                 [SDNPHasChain, SDNPOutGlue, SDNPMayLoad]>;
327def z_ipm               : SDNode<"SystemZISD::IPM", SDT_ZI32Intrinsic,
328                                 [SDNPInGlue]>;
329def z_prefetch          : SDNode<"SystemZISD::PREFETCH", SDT_ZPrefetch,
330                                 [SDNPHasChain, SDNPMayLoad, SDNPMayStore,
331                                  SDNPMemOperand]>;
332
333def z_tbegin            : SDNode<"SystemZISD::TBEGIN", SDT_ZTBegin,
334                                 [SDNPHasChain, SDNPOutGlue, SDNPMayStore,
335                                  SDNPSideEffect]>;
336def z_tbegin_nofloat    : SDNode<"SystemZISD::TBEGIN_NOFLOAT", SDT_ZTBegin,
337                                 [SDNPHasChain, SDNPOutGlue, SDNPMayStore,
338                                  SDNPSideEffect]>;
339def z_tend              : SDNode<"SystemZISD::TEND", SDTNone,
340                                 [SDNPHasChain, SDNPOutGlue, SDNPSideEffect]>;
341
342def z_vshl              : SDNode<"ISD::SHL", SDT_ZVecBinary>;
343def z_vsra              : SDNode<"ISD::SRA", SDT_ZVecBinary>;
344def z_vsrl              : SDNode<"ISD::SRL", SDT_ZVecBinary>;
345
346//===----------------------------------------------------------------------===//
347// Pattern fragments
348//===----------------------------------------------------------------------===//
349
350def z_lrvh  : PatFrag<(ops node:$addr), (z_loadbswap node:$addr, i16)>;
351def z_lrv   : PatFrag<(ops node:$addr), (z_loadbswap node:$addr, i32)>;
352def z_lrvg  : PatFrag<(ops node:$addr), (z_loadbswap node:$addr, i64)>;
353
354def z_strvh : PatFrag<(ops node:$src, node:$addr),
355                      (z_storebswap node:$src, node:$addr, i16)>;
356def z_strv  : PatFrag<(ops node:$src, node:$addr),
357                      (z_storebswap node:$src, node:$addr, i32)>;
358def z_strvg : PatFrag<(ops node:$src, node:$addr),
359                      (z_storebswap node:$src, node:$addr, i64)>;
360
361// Signed and unsigned comparisons.
362def z_scmp : PatFrag<(ops node:$a, node:$b), (z_icmp node:$a, node:$b, imm), [{
363  unsigned Type = cast<ConstantSDNode>(N->getOperand(2))->getZExtValue();
364  return Type != SystemZICMP::UnsignedOnly;
365}]>;
366def z_ucmp : PatFrag<(ops node:$a, node:$b), (z_icmp node:$a, node:$b, imm), [{
367  unsigned Type = cast<ConstantSDNode>(N->getOperand(2))->getZExtValue();
368  return Type != SystemZICMP::SignedOnly;
369}]>;
370
371// Register- and memory-based TEST UNDER MASK.
372def z_tm_reg : PatFrag<(ops node:$a, node:$b), (z_tm node:$a, node:$b, imm)>;
373def z_tm_mem : PatFrag<(ops node:$a, node:$b), (z_tm node:$a, node:$b, 0)>;
374
375// Register sign-extend operations.  Sub-32-bit values are represented as i32s.
376def sext8  : PatFrag<(ops node:$src), (sext_inreg node:$src, i8)>;
377def sext16 : PatFrag<(ops node:$src), (sext_inreg node:$src, i16)>;
378def sext32 : PatFrag<(ops node:$src), (sext (i32 node:$src))>;
379
380// Match extensions of an i32 to an i64, followed by an in-register sign
381// extension from a sub-i32 value.
382def sext8dbl : PatFrag<(ops node:$src), (sext8 (anyext node:$src))>;
383def sext16dbl : PatFrag<(ops node:$src), (sext16 (anyext node:$src))>;
384
385// Register zero-extend operations.  Sub-32-bit values are represented as i32s.
386def zext8  : PatFrag<(ops node:$src), (and node:$src, 0xff)>;
387def zext16 : PatFrag<(ops node:$src), (and node:$src, 0xffff)>;
388def zext32 : PatFrag<(ops node:$src), (zext (i32 node:$src))>;
389
390// Extending loads in which the extension type can be signed.
391def asextload : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
392  unsigned Type = cast<LoadSDNode>(N)->getExtensionType();
393  return Type == ISD::EXTLOAD || Type == ISD::SEXTLOAD;
394}]>;
395def asextloadi8 : PatFrag<(ops node:$ptr), (asextload node:$ptr), [{
396  return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
397}]>;
398def asextloadi16 : PatFrag<(ops node:$ptr), (asextload node:$ptr), [{
399  return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
400}]>;
401def asextloadi32 : PatFrag<(ops node:$ptr), (asextload node:$ptr), [{
402  return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
403}]>;
404
405// Extending loads in which the extension type can be unsigned.
406def azextload : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
407  unsigned Type = cast<LoadSDNode>(N)->getExtensionType();
408  return Type == ISD::EXTLOAD || Type == ISD::ZEXTLOAD;
409}]>;
410def azextloadi8 : PatFrag<(ops node:$ptr), (azextload node:$ptr), [{
411  return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
412}]>;
413def azextloadi16 : PatFrag<(ops node:$ptr), (azextload node:$ptr), [{
414  return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
415}]>;
416def azextloadi32 : PatFrag<(ops node:$ptr), (azextload node:$ptr), [{
417  return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
418}]>;
419
420// Extending loads in which the extension type doesn't matter.
421def anyextload : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
422  return cast<LoadSDNode>(N)->getExtensionType() != ISD::NON_EXTLOAD;
423}]>;
424def anyextloadi8 : PatFrag<(ops node:$ptr), (anyextload node:$ptr), [{
425  return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
426}]>;
427def anyextloadi16 : PatFrag<(ops node:$ptr), (anyextload node:$ptr), [{
428  return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
429}]>;
430def anyextloadi32 : PatFrag<(ops node:$ptr), (anyextload node:$ptr), [{
431  return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
432}]>;
433
434// Aligned loads.
435class AlignedLoad<SDPatternOperator load>
436  : PatFrag<(ops node:$addr), (load node:$addr), [{
437  auto *Load = cast<LoadSDNode>(N);
438  return Load->getAlignment() >= Load->getMemoryVT().getStoreSize();
439}]>;
440def aligned_load         : AlignedLoad<load>;
441def aligned_asextloadi16 : AlignedLoad<asextloadi16>;
442def aligned_asextloadi32 : AlignedLoad<asextloadi32>;
443def aligned_azextloadi16 : AlignedLoad<azextloadi16>;
444def aligned_azextloadi32 : AlignedLoad<azextloadi32>;
445
446// Aligned stores.
447class AlignedStore<SDPatternOperator store>
448  : PatFrag<(ops node:$src, node:$addr), (store node:$src, node:$addr), [{
449  auto *Store = cast<StoreSDNode>(N);
450  return Store->getAlignment() >= Store->getMemoryVT().getStoreSize();
451}]>;
452def aligned_store         : AlignedStore<store>;
453def aligned_truncstorei16 : AlignedStore<truncstorei16>;
454def aligned_truncstorei32 : AlignedStore<truncstorei32>;
455
456// Non-volatile loads.  Used for instructions that might access the storage
457// location multiple times.
458class NonvolatileLoad<SDPatternOperator load>
459  : PatFrag<(ops node:$addr), (load node:$addr), [{
460  auto *Load = cast<LoadSDNode>(N);
461  return !Load->isVolatile();
462}]>;
463def nonvolatile_load          : NonvolatileLoad<load>;
464def nonvolatile_anyextloadi8  : NonvolatileLoad<anyextloadi8>;
465def nonvolatile_anyextloadi16 : NonvolatileLoad<anyextloadi16>;
466def nonvolatile_anyextloadi32 : NonvolatileLoad<anyextloadi32>;
467
468// Non-volatile stores.
469class NonvolatileStore<SDPatternOperator store>
470  : PatFrag<(ops node:$src, node:$addr), (store node:$src, node:$addr), [{
471  auto *Store = cast<StoreSDNode>(N);
472  return !Store->isVolatile();
473}]>;
474def nonvolatile_store         : NonvolatileStore<store>;
475def nonvolatile_truncstorei8  : NonvolatileStore<truncstorei8>;
476def nonvolatile_truncstorei16 : NonvolatileStore<truncstorei16>;
477def nonvolatile_truncstorei32 : NonvolatileStore<truncstorei32>;
478
479// A store of a load that can be implemented using MVC.
480def mvc_store : PatFrag<(ops node:$value, node:$addr),
481                        (unindexedstore node:$value, node:$addr),
482                        [{ return storeLoadCanUseMVC(N); }]>;
483
484// Binary read-modify-write operations on memory in which the other
485// operand is also memory and for which block operations like NC can
486// be used.  There are two patterns for each operator, depending on
487// which operand contains the "other" load.
488multiclass block_op<SDPatternOperator operator> {
489  def "1" : PatFrag<(ops node:$value, node:$addr),
490                    (unindexedstore (operator node:$value,
491                                              (unindexedload node:$addr)),
492                                    node:$addr),
493                    [{ return storeLoadCanUseBlockBinary(N, 0); }]>;
494  def "2" : PatFrag<(ops node:$value, node:$addr),
495                    (unindexedstore (operator (unindexedload node:$addr),
496                                              node:$value),
497                                    node:$addr),
498                    [{ return storeLoadCanUseBlockBinary(N, 1); }]>;
499}
500defm block_and : block_op<and>;
501defm block_or  : block_op<or>;
502defm block_xor : block_op<xor>;
503
504// Insertions.
505def inserti8 : PatFrag<(ops node:$src1, node:$src2),
506                       (or (and node:$src1, -256), node:$src2)>;
507def insertll : PatFrag<(ops node:$src1, node:$src2),
508                       (or (and node:$src1, 0xffffffffffff0000), node:$src2)>;
509def insertlh : PatFrag<(ops node:$src1, node:$src2),
510                       (or (and node:$src1, 0xffffffff0000ffff), node:$src2)>;
511def inserthl : PatFrag<(ops node:$src1, node:$src2),
512                       (or (and node:$src1, 0xffff0000ffffffff), node:$src2)>;
513def inserthh : PatFrag<(ops node:$src1, node:$src2),
514                       (or (and node:$src1, 0x0000ffffffffffff), node:$src2)>;
515def insertlf : PatFrag<(ops node:$src1, node:$src2),
516                       (or (and node:$src1, 0xffffffff00000000), node:$src2)>;
517def inserthf : PatFrag<(ops node:$src1, node:$src2),
518                       (or (and node:$src1, 0x00000000ffffffff), node:$src2)>;
519
520// ORs that can be treated as insertions.
521def or_as_inserti8 : PatFrag<(ops node:$src1, node:$src2),
522                             (or node:$src1, node:$src2), [{
523  unsigned BitWidth = N->getValueType(0).getScalarSizeInBits();
524  return CurDAG->MaskedValueIsZero(N->getOperand(0),
525                                   APInt::getLowBitsSet(BitWidth, 8));
526}]>;
527
528// ORs that can be treated as reversed insertions.
529def or_as_revinserti8 : PatFrag<(ops node:$src1, node:$src2),
530                                (or node:$src1, node:$src2), [{
531  unsigned BitWidth = N->getValueType(0).getScalarSizeInBits();
532  return CurDAG->MaskedValueIsZero(N->getOperand(1),
533                                   APInt::getLowBitsSet(BitWidth, 8));
534}]>;
535
536// Negative integer absolute.
537def z_inegabs : PatFrag<(ops node:$src), (ineg (z_iabs node:$src))>;
538
539// Integer absolute, matching the canonical form generated by DAGCombiner.
540def z_iabs32 : PatFrag<(ops node:$src),
541                       (xor (add node:$src, (sra node:$src, (i32 31))),
542                            (sra node:$src, (i32 31)))>;
543def z_iabs64 : PatFrag<(ops node:$src),
544                       (xor (add node:$src, (sra node:$src, (i32 63))),
545                            (sra node:$src, (i32 63)))>;
546def z_inegabs32 : PatFrag<(ops node:$src), (ineg (z_iabs32 node:$src))>;
547def z_inegabs64 : PatFrag<(ops node:$src), (ineg (z_iabs64 node:$src))>;
548
549// Integer multiply-and-add
550def z_muladd : PatFrag<(ops node:$src1, node:$src2, node:$src3),
551                       (add (mul node:$src1, node:$src2), node:$src3)>;
552
553// Fused multiply-subtract, using the natural operand order.
554def fms : PatFrag<(ops node:$src1, node:$src2, node:$src3),
555                  (fma node:$src1, node:$src2, (fneg node:$src3))>;
556
557// Fused multiply-add and multiply-subtract, but with the order of the
558// operands matching SystemZ's MA and MS instructions.
559def z_fma : PatFrag<(ops node:$src1, node:$src2, node:$src3),
560                    (fma node:$src2, node:$src3, node:$src1)>;
561def z_fms : PatFrag<(ops node:$src1, node:$src2, node:$src3),
562                    (fma node:$src2, node:$src3, (fneg node:$src1))>;
563
564// Floating-point negative absolute.
565def fnabs : PatFrag<(ops node:$ptr), (fneg (fabs node:$ptr))>;
566
567// Create a unary operator that loads from memory and then performs
568// the given operation on it.
569class loadu<SDPatternOperator operator, SDPatternOperator load = load>
570  : PatFrag<(ops node:$addr), (operator (load node:$addr))>;
571
572// Create a store operator that performs the given unary operation
573// on the value before storing it.
574class storeu<SDPatternOperator operator, SDPatternOperator store = store>
575  : PatFrag<(ops node:$value, node:$addr),
576            (store (operator node:$value), node:$addr)>;
577
578// Vector representation of all-zeros and all-ones.
579def z_vzero : PatFrag<(ops), (bitconvert (v16i8 (z_byte_mask (i32 0))))>;
580def z_vones : PatFrag<(ops), (bitconvert (v16i8 (z_byte_mask (i32 65535))))>;
581
582// Load a scalar and replicate it in all elements of a vector.
583class z_replicate_load<ValueType scalartype, SDPatternOperator load>
584  : PatFrag<(ops node:$addr),
585            (z_replicate (scalartype (load node:$addr)))>;
586def z_replicate_loadi8  : z_replicate_load<i32, anyextloadi8>;
587def z_replicate_loadi16 : z_replicate_load<i32, anyextloadi16>;
588def z_replicate_loadi32 : z_replicate_load<i32, load>;
589def z_replicate_loadi64 : z_replicate_load<i64, load>;
590def z_replicate_loadf32 : z_replicate_load<f32, load>;
591def z_replicate_loadf64 : z_replicate_load<f64, load>;
592
593// Load a scalar and insert it into a single element of a vector.
594class z_vle<ValueType scalartype, SDPatternOperator load>
595  : PatFrag<(ops node:$vec, node:$addr, node:$index),
596            (z_vector_insert node:$vec, (scalartype (load node:$addr)),
597                             node:$index)>;
598def z_vlei8  : z_vle<i32, anyextloadi8>;
599def z_vlei16 : z_vle<i32, anyextloadi16>;
600def z_vlei32 : z_vle<i32, load>;
601def z_vlei64 : z_vle<i64, load>;
602def z_vlef32 : z_vle<f32, load>;
603def z_vlef64 : z_vle<f64, load>;
604
605// Load a scalar and insert it into the low element of the high i64 of a
606// zeroed vector.
607class z_vllez<ValueType scalartype, SDPatternOperator load, int index>
608  : PatFrag<(ops node:$addr),
609            (z_vector_insert (z_vzero),
610                             (scalartype (load node:$addr)), (i32 index))>;
611def z_vllezi8  : z_vllez<i32, anyextloadi8, 7>;
612def z_vllezi16 : z_vllez<i32, anyextloadi16, 3>;
613def z_vllezi32 : z_vllez<i32, load, 1>;
614def z_vllezi64 : PatFrag<(ops node:$addr),
615                         (z_join_dwords (i64 (load node:$addr)), (i64 0))>;
616// We use high merges to form a v4f32 from four f32s.  Propagating zero
617// into all elements but index 1 gives this expression.
618def z_vllezf32 : PatFrag<(ops node:$addr),
619                         (bitconvert
620                          (z_merge_high
621                           (v2i64
622                            (z_unpackl_high
623                             (v4i32
624                              (bitconvert
625                               (v4f32 (scalar_to_vector
626                                       (f32 (load node:$addr)))))))),
627                           (v2i64 (z_vzero))))>;
628def z_vllezf64 : PatFrag<(ops node:$addr),
629                         (z_merge_high
630                          (scalar_to_vector (f64 (load node:$addr))),
631                          (z_vzero))>;
632
633// Store one element of a vector.
634class z_vste<ValueType scalartype, SDPatternOperator store>
635  : PatFrag<(ops node:$vec, node:$addr, node:$index),
636            (store (scalartype (z_vector_extract node:$vec, node:$index)),
637                   node:$addr)>;
638def z_vstei8  : z_vste<i32, truncstorei8>;
639def z_vstei16 : z_vste<i32, truncstorei16>;
640def z_vstei32 : z_vste<i32, store>;
641def z_vstei64 : z_vste<i64, store>;
642def z_vstef32 : z_vste<f32, store>;
643def z_vstef64 : z_vste<f64, store>;
644
645// Arithmetic negation on vectors.
646def z_vneg : PatFrag<(ops node:$x), (sub (z_vzero), node:$x)>;
647
648// Bitwise negation on vectors.
649def z_vnot : PatFrag<(ops node:$x), (xor node:$x, (z_vones))>;
650
651// Signed "integer greater than zero" on vectors.
652def z_vicmph_zero : PatFrag<(ops node:$x), (z_vicmph node:$x, (z_vzero))>;
653
654// Signed "integer less than zero" on vectors.
655def z_vicmpl_zero : PatFrag<(ops node:$x), (z_vicmph (z_vzero), node:$x)>;
656
657// Integer absolute on vectors.
658class z_viabs<int shift>
659  : PatFrag<(ops node:$src),
660            (xor (add node:$src, (z_vsra_by_scalar node:$src, (i32 shift))),
661                 (z_vsra_by_scalar node:$src, (i32 shift)))>;
662def z_viabs8  : z_viabs<7>;
663def z_viabs16 : z_viabs<15>;
664def z_viabs32 : z_viabs<31>;
665def z_viabs64 : z_viabs<63>;
666
667// Sign-extend the i64 elements of a vector.
668class z_vse<int shift>
669  : PatFrag<(ops node:$src),
670            (z_vsra_by_scalar (z_vshl_by_scalar node:$src, shift), shift)>;
671def z_vsei8  : z_vse<56>;
672def z_vsei16 : z_vse<48>;
673def z_vsei32 : z_vse<32>;
674
675// ...and again with the extensions being done on individual i64 scalars.
676class z_vse_by_parts<SDPatternOperator operator, int index1, int index2>
677  : PatFrag<(ops node:$src),
678            (z_join_dwords
679             (operator (z_vector_extract node:$src, index1)),
680             (operator (z_vector_extract node:$src, index2)))>;
681def z_vsei8_by_parts  : z_vse_by_parts<sext8dbl, 7, 15>;
682def z_vsei16_by_parts : z_vse_by_parts<sext16dbl, 3, 7>;
683def z_vsei32_by_parts : z_vse_by_parts<sext32, 1, 3>;
684