1//===-- SIInstrInfo.td - SI Instruction Infos -------------*- tablegen -*--===//
2//
3// Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
4// See https://llvm.org/LICENSE.txt for license information.
5// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
6//
7//===----------------------------------------------------------------------===//
8
9def isWave32 : Predicate<"Subtarget->getWavefrontSize() == 32">,
10  AssemblerPredicate <(all_of FeatureWavefrontSize32)>;
11def isWave64 : Predicate<"Subtarget->getWavefrontSize() == 64">,
12  AssemblerPredicate <(all_of FeatureWavefrontSize64)>;
13
14class GCNPredicateControl : PredicateControl {
15  Predicate SIAssemblerPredicate = isGFX6GFX7;
16  Predicate VIAssemblerPredicate = isGFX8GFX9;
17}
18
19// Except for the NONE field, this must be kept in sync with the
20// SIEncodingFamily enum in AMDGPUInstrInfo.cpp
21def SIEncodingFamily {
22  int NONE = -1;
23  int SI = 0;
24  int VI = 1;
25  int SDWA = 2;
26  int SDWA9 = 3;
27  int GFX80 = 4;
28  int GFX9 = 5;
29  int GFX10 = 6;
30  int SDWA10 = 7;
31  int GFX90A = 8;
32  int GFX940 = 9;
33}
34
35//===----------------------------------------------------------------------===//
36// SI DAG Nodes
37//===----------------------------------------------------------------------===//
38
39def AMDGPUclamp : SDNode<"AMDGPUISD::CLAMP", SDTFPUnaryOp>;
40
41def SIsbuffer_load : SDNode<"AMDGPUISD::SBUFFER_LOAD",
42  SDTypeProfile<1, 3, [SDTCisVT<1, v4i32>, SDTCisVT<2, i32>, SDTCisVT<3, i32>]>,
43  [SDNPMayLoad, SDNPMemOperand]
44>;
45
46def SIds_ordered_count : SDNode<"AMDGPUISD::DS_ORDERED_COUNT",
47  SDTypeProfile<1, 2, [SDTCisVT<0, i32>, SDTCisVT<1, i32>, SDTCisVT<2, i16>]>,
48  [SDNPMayLoad, SDNPMayStore, SDNPMemOperand, SDNPHasChain, SDNPInGlue]
49>;
50
51def SIatomic_inc : SDNode<"AMDGPUISD::ATOMIC_INC", SDTAtomic2,
52  [SDNPMayLoad, SDNPMayStore, SDNPMemOperand, SDNPHasChain]
53>;
54
55def SIatomic_dec : SDNode<"AMDGPUISD::ATOMIC_DEC", SDTAtomic2,
56  [SDNPMayLoad, SDNPMayStore, SDNPMemOperand, SDNPHasChain]
57>;
58
59def SDTAtomic2_f32 : SDTypeProfile<1, 2, [
60  SDTCisSameAs<0,2>, SDTCisFP<0>, SDTCisPtrTy<1>
61]>;
62
63def SIatomic_fmin : SDNode<"AMDGPUISD::ATOMIC_LOAD_FMIN", SDTAtomic2_f32,
64  [SDNPMayLoad, SDNPMayStore, SDNPMemOperand, SDNPHasChain]
65>;
66
67def SIatomic_fmax : SDNode<"AMDGPUISD::ATOMIC_LOAD_FMAX", SDTAtomic2_f32,
68  [SDNPMayLoad, SDNPMayStore, SDNPMemOperand, SDNPHasChain]
69>;
70
71// load_d16_{lo|hi} ptr, tied_input
72def SIload_d16 : SDTypeProfile<1, 2, [
73  SDTCisPtrTy<1>,
74  SDTCisSameAs<0, 2>
75]>;
76
77
78def SDTtbuffer_load : SDTypeProfile<1, 8,
79  [                     // vdata
80   SDTCisVT<1, v4i32>,  // rsrc
81   SDTCisVT<2, i32>,    // vindex(VGPR)
82   SDTCisVT<3, i32>,    // voffset(VGPR)
83   SDTCisVT<4, i32>,    // soffset(SGPR)
84   SDTCisVT<5, i32>,    // offset(imm)
85   SDTCisVT<6, i32>,    // format(imm)
86   SDTCisVT<7, i32>,    // cachepolicy, swizzled buffer(imm)
87   SDTCisVT<8, i1>      // idxen(imm)
88  ]>;
89
90def SItbuffer_load :   SDNode<"AMDGPUISD::TBUFFER_LOAD_FORMAT", SDTtbuffer_load,
91                              [SDNPMayLoad, SDNPMemOperand, SDNPHasChain]>;
92def SItbuffer_load_d16 : SDNode<"AMDGPUISD::TBUFFER_LOAD_FORMAT_D16",
93                                SDTtbuffer_load,
94                                [SDNPMayLoad, SDNPMemOperand, SDNPHasChain]>;
95
96def SDTtbuffer_store : SDTypeProfile<0, 9,
97    [                     // vdata
98     SDTCisVT<1, v4i32>,  // rsrc
99     SDTCisVT<2, i32>,    // vindex(VGPR)
100     SDTCisVT<3, i32>,    // voffset(VGPR)
101     SDTCisVT<4, i32>,    // soffset(SGPR)
102     SDTCisVT<5, i32>,    // offset(imm)
103     SDTCisVT<6, i32>,    // format(imm)
104     SDTCisVT<7, i32>,    // cachepolicy, swizzled buffer(imm)
105     SDTCisVT<8, i1>      // idxen(imm)
106    ]>;
107
108def SItbuffer_store : SDNode<"AMDGPUISD::TBUFFER_STORE_FORMAT", SDTtbuffer_store,
109                             [SDNPMayStore, SDNPMemOperand, SDNPHasChain]>;
110def SItbuffer_store_d16 : SDNode<"AMDGPUISD::TBUFFER_STORE_FORMAT_D16",
111                                SDTtbuffer_store,
112                                [SDNPMayStore, SDNPMemOperand, SDNPHasChain]>;
113
114def SDTBufferLoad : SDTypeProfile<1, 7,
115    [                    // vdata
116     SDTCisVT<1, v4i32>, // rsrc
117     SDTCisVT<2, i32>,   // vindex(VGPR)
118     SDTCisVT<3, i32>,   // voffset(VGPR)
119     SDTCisVT<4, i32>,   // soffset(SGPR)
120     SDTCisVT<5, i32>,   // offset(imm)
121     SDTCisVT<6, i32>,   // cachepolicy, swizzled buffer(imm)
122     SDTCisVT<7, i1>]>;  // idxen(imm)
123
124def SIbuffer_load : SDNode <"AMDGPUISD::BUFFER_LOAD", SDTBufferLoad,
125                            [SDNPMemOperand, SDNPHasChain, SDNPMayLoad]>;
126def SIbuffer_load_ubyte : SDNode <"AMDGPUISD::BUFFER_LOAD_UBYTE", SDTBufferLoad,
127                            [SDNPMemOperand, SDNPHasChain, SDNPMayLoad]>;
128def SIbuffer_load_ushort : SDNode <"AMDGPUISD::BUFFER_LOAD_USHORT", SDTBufferLoad,
129                            [SDNPMemOperand, SDNPHasChain, SDNPMayLoad]>;
130def SIbuffer_load_byte : SDNode <"AMDGPUISD::BUFFER_LOAD_BYTE", SDTBufferLoad,
131                            [SDNPMemOperand, SDNPHasChain, SDNPMayLoad]>;
132def SIbuffer_load_short: SDNode <"AMDGPUISD::BUFFER_LOAD_SHORT", SDTBufferLoad,
133                            [SDNPMemOperand, SDNPHasChain, SDNPMayLoad]>;
134def SIbuffer_load_format : SDNode <"AMDGPUISD::BUFFER_LOAD_FORMAT", SDTBufferLoad,
135                            [SDNPMemOperand, SDNPHasChain, SDNPMayLoad]>;
136def SIbuffer_load_format_d16 : SDNode <"AMDGPUISD::BUFFER_LOAD_FORMAT_D16",
137                                SDTBufferLoad,
138                                [SDNPMemOperand, SDNPHasChain, SDNPMayLoad]>;
139
140def SDTBufferStore : SDTypeProfile<0, 8,
141    [                    // vdata
142     SDTCisVT<1, v4i32>, // rsrc
143     SDTCisVT<2, i32>,   // vindex(VGPR)
144     SDTCisVT<3, i32>,   // voffset(VGPR)
145     SDTCisVT<4, i32>,   // soffset(SGPR)
146     SDTCisVT<5, i32>,   // offset(imm)
147     SDTCisVT<6, i32>,   // cachepolicy, swizzled buffer(imm)
148     SDTCisVT<7, i1>]>;  // idxen(imm)
149
150def SIbuffer_store : SDNode <"AMDGPUISD::BUFFER_STORE", SDTBufferStore,
151                             [SDNPMayStore, SDNPMemOperand, SDNPHasChain]>;
152def SIbuffer_store_byte: SDNode <"AMDGPUISD::BUFFER_STORE_BYTE",
153                         SDTBufferStore,
154                         [SDNPMayStore, SDNPMemOperand, SDNPHasChain]>;
155def SIbuffer_store_short : SDNode <"AMDGPUISD::BUFFER_STORE_SHORT",
156                           SDTBufferStore,
157                           [SDNPMayStore, SDNPMemOperand, SDNPHasChain]>;
158def SIbuffer_store_format : SDNode <"AMDGPUISD::BUFFER_STORE_FORMAT",
159                            SDTBufferStore,
160                            [SDNPMayStore, SDNPMemOperand, SDNPHasChain]>;
161def SIbuffer_store_format_d16 : SDNode <"AMDGPUISD::BUFFER_STORE_FORMAT_D16",
162                            SDTBufferStore,
163                            [SDNPMayStore, SDNPMemOperand, SDNPHasChain]>;
164
165class SDBufferAtomic<string opcode> : SDNode <opcode,
166  SDTypeProfile<1, 8,
167       [SDTCisVT<2, v4i32>, // rsrc
168       SDTCisVT<3, i32>,   // vindex(VGPR)
169       SDTCisVT<4, i32>,   // voffset(VGPR)
170       SDTCisVT<5, i32>,   // soffset(SGPR)
171       SDTCisVT<6, i32>,   // offset(imm)
172       SDTCisVT<7, i32>,   // cachepolicy(imm)
173       SDTCisVT<8, i1>]>,  // idxen(imm)
174  [SDNPMemOperand, SDNPHasChain, SDNPMayLoad, SDNPMayStore]
175>;
176
177def SIbuffer_atomic_swap : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_SWAP">;
178def SIbuffer_atomic_add : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_ADD">;
179def SIbuffer_atomic_sub : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_SUB">;
180def SIbuffer_atomic_smin : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_SMIN">;
181def SIbuffer_atomic_umin : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_UMIN">;
182def SIbuffer_atomic_smax : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_SMAX">;
183def SIbuffer_atomic_umax : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_UMAX">;
184def SIbuffer_atomic_and : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_AND">;
185def SIbuffer_atomic_or : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_OR">;
186def SIbuffer_atomic_xor : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_XOR">;
187def SIbuffer_atomic_inc : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_INC">;
188def SIbuffer_atomic_dec : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_DEC">;
189def SIbuffer_atomic_csub : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_CSUB">;
190def SIbuffer_atomic_fadd : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_FADD">;
191def SIbuffer_atomic_fmin : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_FMIN">;
192def SIbuffer_atomic_fmax : SDBufferAtomic <"AMDGPUISD::BUFFER_ATOMIC_FMAX">;
193
194multiclass SDBufferAtomicRetNoRet {
195  def "_ret" : PatFrag<
196    (ops node:$vdata_in, node:$rsrc, node:$vindex, node:$voffset, node:$soffset,
197      node:$offset, node:$cachepolicy, node:$idxen),
198    (!cast<SDNode>(NAME) node:$vdata_in, node:$rsrc, node:$vindex,
199      node:$voffset, node:$soffset, node:$offset, node:$cachepolicy,
200      node:$idxen)> {
201    let PredicateCode = [{ return !(SDValue(N, 0).use_empty()); }];
202    let GISelPredicateCode = [{ return true; }];
203  }
204
205  def "_noret" : PatFrag<
206    (ops node:$vdata_in, node:$rsrc, node:$vindex, node:$voffset, node:$soffset,
207      node:$offset, node:$cachepolicy, node:$idxen),
208    (!cast<SDNode>(NAME) node:$vdata_in, node:$rsrc, node:$vindex,
209      node:$voffset, node:$soffset, node:$offset, node:$cachepolicy,
210      node:$idxen)> {
211    let PredicateCode = [{ return SDValue(N, 0).use_empty(); }];
212    let GISelPredicateCode = [{ return false; }];
213  }
214}
215
216defm SIbuffer_atomic_swap : SDBufferAtomicRetNoRet;
217defm SIbuffer_atomic_add : SDBufferAtomicRetNoRet;
218defm SIbuffer_atomic_sub : SDBufferAtomicRetNoRet;
219defm SIbuffer_atomic_smin : SDBufferAtomicRetNoRet;
220defm SIbuffer_atomic_umin : SDBufferAtomicRetNoRet;
221defm SIbuffer_atomic_smax : SDBufferAtomicRetNoRet;
222defm SIbuffer_atomic_umax : SDBufferAtomicRetNoRet;
223defm SIbuffer_atomic_and : SDBufferAtomicRetNoRet;
224defm SIbuffer_atomic_or : SDBufferAtomicRetNoRet;
225defm SIbuffer_atomic_xor : SDBufferAtomicRetNoRet;
226defm SIbuffer_atomic_inc : SDBufferAtomicRetNoRet;
227defm SIbuffer_atomic_dec : SDBufferAtomicRetNoRet;
228defm SIbuffer_atomic_fadd : SDBufferAtomicRetNoRet;
229defm SIbuffer_atomic_fmin : SDBufferAtomicRetNoRet;
230defm SIbuffer_atomic_fmax : SDBufferAtomicRetNoRet;
231
232def SIbuffer_atomic_cmpswap : SDNode <"AMDGPUISD::BUFFER_ATOMIC_CMPSWAP",
233  SDTypeProfile<1, 9,
234    [SDTCisVT<0, i32>,   // dst
235     SDTCisVT<1, i32>,   // src
236     SDTCisVT<2, i32>,   // cmp
237     SDTCisVT<3, v4i32>, // rsrc
238     SDTCisVT<4, i32>,   // vindex(VGPR)
239     SDTCisVT<5, i32>,   // voffset(VGPR)
240     SDTCisVT<6, i32>,   // soffset(SGPR)
241     SDTCisVT<7, i32>,   // offset(imm)
242     SDTCisVT<8, i32>,   // cachepolicy(imm)
243     SDTCisVT<9, i1>]>,  // idxen(imm)
244  [SDNPMemOperand, SDNPHasChain, SDNPMayLoad, SDNPMayStore]
245>;
246
247def SIbuffer_atomic_cmpswap_ret : PatFrag<
248  (ops node:$src, node:$cmp, node:$rsrc, node:$vindex, node:$voffset,
249    node:$soffset, node:$offset, node:$cachepolicy, node:$idxen),
250  (SIbuffer_atomic_cmpswap node:$src, node:$cmp, node:$rsrc, node:$vindex,
251    node:$voffset, node:$soffset, node:$offset, node:$cachepolicy,
252    node:$idxen)> {
253  let PredicateCode = [{ return !(SDValue(N, 0).use_empty()); }];
254  let GISelPredicateCode = [{ return true; }];
255}
256
257def SIbuffer_atomic_cmpswap_noret : PatFrag<
258  (ops node:$src, node:$cmp, node:$rsrc, node:$vindex, node:$voffset,
259    node:$soffset, node:$offset, node:$cachepolicy, node:$idxen),
260  (SIbuffer_atomic_cmpswap node:$src, node:$cmp, node:$rsrc, node:$vindex,
261    node:$voffset, node:$soffset, node:$offset, node:$cachepolicy,
262    node:$idxen)> {
263  let PredicateCode = [{ return SDValue(N, 0).use_empty(); }];
264  let GISelPredicateCode = [{ return false; }];
265}
266
267class SDGlobalAtomicNoRtn<string opcode, ValueType ty> : SDNode <opcode,
268  SDTypeProfile<0, 2,
269      [SDTCisPtrTy<0>,     // vaddr
270       SDTCisVT<1, ty>]>,  // vdata
271  [SDNPMemOperand, SDNPHasChain, SDNPMayLoad, SDNPMayStore]
272>;
273
274def SIpc_add_rel_offset : SDNode<"AMDGPUISD::PC_ADD_REL_OFFSET",
275  SDTypeProfile<1, 2, [SDTCisVT<0, iPTR>, SDTCisSameAs<0,1>, SDTCisSameAs<0,2>]>
276>;
277
278def SIlds : SDNode<"AMDGPUISD::LDS",
279  SDTypeProfile<1, 1, [SDTCisVT<0, iPTR>, SDTCisSameAs<0,1>]>
280>;
281
282def SIload_d16_lo : SDNode<"AMDGPUISD::LOAD_D16_LO",
283  SIload_d16,
284  [SDNPMayLoad, SDNPMemOperand, SDNPHasChain]
285>;
286
287def SIload_d16_lo_u8 : SDNode<"AMDGPUISD::LOAD_D16_LO_U8",
288  SIload_d16,
289  [SDNPMayLoad, SDNPMemOperand, SDNPHasChain]
290>;
291
292def SIload_d16_lo_i8 : SDNode<"AMDGPUISD::LOAD_D16_LO_I8",
293  SIload_d16,
294  [SDNPMayLoad, SDNPMemOperand, SDNPHasChain]
295>;
296
297def SIload_d16_hi : SDNode<"AMDGPUISD::LOAD_D16_HI",
298  SIload_d16,
299  [SDNPMayLoad, SDNPMemOperand, SDNPHasChain]
300>;
301
302def SIload_d16_hi_u8 : SDNode<"AMDGPUISD::LOAD_D16_HI_U8",
303  SIload_d16,
304  [SDNPMayLoad, SDNPMemOperand, SDNPHasChain]
305>;
306
307def SIload_d16_hi_i8 : SDNode<"AMDGPUISD::LOAD_D16_HI_I8",
308  SIload_d16,
309  [SDNPMayLoad, SDNPMemOperand, SDNPHasChain]
310>;
311
312def SIdenorm_mode : SDNode<"AMDGPUISD::DENORM_MODE",
313  SDTypeProfile<0 ,1, [SDTCisInt<0>]>,
314  [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]
315>;
316
317def SIfptrunc_round_upward : SDNode<"AMDGPUISD::FPTRUNC_ROUND_UPWARD",
318  SDTFPRoundOp
319>;
320
321def SIfptrunc_round_downward : SDNode<"AMDGPUISD::FPTRUNC_ROUND_DOWNWARD",
322  SDTFPRoundOp
323>;
324
325//===----------------------------------------------------------------------===//
326// ValueType helpers
327//===----------------------------------------------------------------------===//
328
329// Returns 1 if the source arguments have modifiers, 0 if they do not.
330// XXX - do f16 instructions?
331class isFloatType<ValueType SrcVT> {
332  bit ret = !or(!eq(SrcVT.Value, f16.Value),
333                !eq(SrcVT.Value, f32.Value),
334                !eq(SrcVT.Value, f64.Value),
335                !eq(SrcVT.Value, v2f16.Value),
336                !eq(SrcVT.Value, v4f16.Value),
337                !eq(SrcVT.Value, v2f32.Value),
338                !eq(SrcVT.Value, v2f64.Value),
339                !eq(SrcVT.Value, v4f64.Value));
340}
341
342class isIntType<ValueType SrcVT> {
343  bit ret = !or(!eq(SrcVT.Value, i16.Value),
344                !eq(SrcVT.Value, i32.Value),
345                !eq(SrcVT.Value, i64.Value),
346                !eq(SrcVT.Value, v2i32.Value));
347}
348
349class isPackedType<ValueType SrcVT> {
350  bit ret = !or(!eq(SrcVT.Value, v2i16.Value),
351                !eq(SrcVT.Value, v2f16.Value),
352                !eq(SrcVT.Value, v4f16.Value),
353                !eq(SrcVT.Value, v2f32.Value));
354}
355
356
357//===----------------------------------------------------------------------===//
358// PatFrags for global memory operations
359//===----------------------------------------------------------------------===//
360
361defm atomic_inc : binary_atomic_op_all_as<SIatomic_inc>;
362defm atomic_dec : binary_atomic_op_all_as<SIatomic_dec>;
363defm atomic_load_fmin : binary_atomic_op_all_as<SIatomic_fmin, 0>;
364defm atomic_load_fmax : binary_atomic_op_all_as<SIatomic_fmax, 0>;
365
366//===----------------------------------------------------------------------===//
367// SDNodes PatFrags for loads/stores with a glue input.
368// This is for SDNodes and PatFrag for local loads and stores to
369// enable s_mov_b32 m0, -1 to be glued to the memory instructions.
370//
371// These mirror the regular load/store PatFrags and rely on special
372// processing during Select() to add the glued copy.
373//
374//===----------------------------------------------------------------------===//
375
376def AMDGPUld_glue : SDNode <"ISD::LOAD", SDTLoad,
377  [SDNPHasChain, SDNPMayLoad, SDNPMemOperand, SDNPInGlue]
378>;
379
380def AMDGPUatomic_ld_glue : SDNode <"ISD::ATOMIC_LOAD", SDTAtomicLoad,
381  [SDNPHasChain, SDNPMayLoad, SDNPMemOperand, SDNPInGlue]
382>;
383
384def unindexedload_glue : PatFrag <(ops node:$ptr), (AMDGPUld_glue node:$ptr)> {
385  let IsLoad = 1;
386  let IsUnindexed = 1;
387}
388
389def load_glue : PatFrag <(ops node:$ptr), (unindexedload_glue node:$ptr)> {
390  let IsLoad = 1;
391  let IsNonExtLoad = 1;
392}
393
394def atomic_load_8_glue : PatFrag<(ops node:$ptr),
395  (AMDGPUatomic_ld_glue node:$ptr)> {
396  let IsAtomic = 1;
397  let MemoryVT = i8;
398}
399
400def atomic_load_16_glue : PatFrag<(ops node:$ptr),
401  (AMDGPUatomic_ld_glue node:$ptr)> {
402  let IsAtomic = 1;
403  let MemoryVT = i16;
404}
405
406def atomic_load_32_glue : PatFrag<(ops node:$ptr),
407  (AMDGPUatomic_ld_glue node:$ptr)> {
408  let IsAtomic = 1;
409  let MemoryVT = i32;
410}
411
412def atomic_load_64_glue : PatFrag<(ops node:$ptr),
413  (AMDGPUatomic_ld_glue node:$ptr)> {
414  let IsAtomic = 1;
415  let MemoryVT = i64;
416}
417
418def extload_glue : PatFrag<(ops node:$ptr), (unindexedload_glue node:$ptr)> {
419  let IsLoad = 1;
420  let IsAnyExtLoad = 1;
421}
422
423def sextload_glue : PatFrag<(ops node:$ptr), (unindexedload_glue node:$ptr)> {
424  let IsLoad = 1;
425  let IsSignExtLoad = 1;
426}
427
428def zextload_glue : PatFrag<(ops node:$ptr), (unindexedload_glue node:$ptr)> {
429  let IsLoad = 1;
430  let IsZeroExtLoad = 1;
431}
432
433def extloadi8_glue : PatFrag<(ops node:$ptr), (extload_glue node:$ptr)> {
434  let IsLoad = 1;
435  let MemoryVT = i8;
436}
437
438def zextloadi8_glue : PatFrag<(ops node:$ptr), (zextload_glue node:$ptr)> {
439  let IsLoad = 1;
440  let MemoryVT = i8;
441}
442
443def extloadi16_glue : PatFrag<(ops node:$ptr), (extload_glue node:$ptr)> {
444  let IsLoad = 1;
445  let MemoryVT = i16;
446}
447
448def zextloadi16_glue : PatFrag<(ops node:$ptr), (zextload_glue node:$ptr)> {
449  let IsLoad = 1;
450  let MemoryVT = i16;
451}
452
453def sextloadi8_glue : PatFrag<(ops node:$ptr), (sextload_glue node:$ptr)> {
454  let IsLoad = 1;
455  let MemoryVT = i8;
456}
457
458def sextloadi16_glue : PatFrag<(ops node:$ptr), (sextload_glue node:$ptr)> {
459  let IsLoad = 1;
460  let MemoryVT = i16;
461}
462
463
464let IsLoad = 1, AddressSpaces = LoadAddress_local.AddrSpaces in {
465def load_local_m0 : PatFrag<(ops node:$ptr), (load_glue node:$ptr)> {
466  let IsNonExtLoad = 1;
467}
468
469let MemoryVT = i8 in {
470def extloadi8_local_m0 : PatFrag<(ops node:$ptr), (extloadi8_glue node:$ptr)>;
471def sextloadi8_local_m0 : PatFrag<(ops node:$ptr), (sextloadi8_glue node:$ptr)>;
472def zextloadi8_local_m0 : PatFrag<(ops node:$ptr), (zextloadi8_glue node:$ptr)>;
473}
474
475let MemoryVT = i16 in {
476def extloadi16_local_m0 : PatFrag<(ops node:$ptr), (extloadi16_glue node:$ptr)>;
477def sextloadi16_local_m0 : PatFrag<(ops node:$ptr), (sextloadi16_glue node:$ptr)>;
478def zextloadi16_local_m0 : PatFrag<(ops node:$ptr), (zextloadi16_glue node:$ptr)>;
479}
480
481def load_align8_local_m0 : PatFrag<(ops node:$ptr),
482                                   (load_local_m0 node:$ptr)>, Aligned<8> {
483  let IsLoad = 1;
484  let IsNonExtLoad = 1;
485}
486
487def load_align16_local_m0 : PatFrag<(ops node:$ptr),
488                                   (load_local_m0 node:$ptr)>, Aligned<16> {
489  let IsLoad = 1;
490  let IsNonExtLoad = 1;
491}
492
493} // End IsLoad = 1
494
495let IsAtomic = 1, AddressSpaces = LoadAddress_local.AddrSpaces in {
496def atomic_load_8_local_m0 : PatFrag<(ops node:$ptr),
497                                      (atomic_load_8_glue node:$ptr)> {
498  let MemoryVT = i8;
499}
500def atomic_load_16_local_m0 : PatFrag<(ops node:$ptr),
501                                      (atomic_load_16_glue node:$ptr)> {
502  let MemoryVT = i16;
503}
504def atomic_load_32_local_m0 : PatFrag<(ops node:$ptr),
505                                      (atomic_load_32_glue node:$ptr)> {
506  let MemoryVT = i32;
507}
508def atomic_load_64_local_m0 : PatFrag<(ops node:$ptr),
509                                       (atomic_load_64_glue node:$ptr)> {
510  let MemoryVT = i64;
511}
512
513} // End let AddressSpaces = LoadAddress_local.AddrSpaces
514
515
516def AMDGPUst_glue : SDNode <"ISD::STORE", SDTStore,
517  [SDNPHasChain, SDNPMayStore, SDNPMemOperand, SDNPInGlue]
518>;
519
520def AMDGPUatomic_st_glue : SDNode <"ISD::ATOMIC_STORE", SDTAtomicStore,
521  [SDNPHasChain, SDNPMayStore, SDNPMemOperand, SDNPInGlue]
522>;
523
524def unindexedstore_glue : PatFrag<(ops node:$val, node:$ptr),
525                                   (AMDGPUst_glue node:$val, node:$ptr)> {
526  let IsStore = 1;
527  let IsUnindexed = 1;
528}
529
530def store_glue : PatFrag<(ops node:$val, node:$ptr),
531                         (unindexedstore_glue node:$val, node:$ptr)> {
532  let IsStore = 1;
533  let IsTruncStore = 0;
534}
535
536def truncstore_glue : PatFrag<(ops node:$val, node:$ptr),
537  (unindexedstore_glue node:$val, node:$ptr)> {
538  let IsStore = 1;
539  let IsTruncStore = 1;
540}
541
542def truncstorei8_glue : PatFrag<(ops node:$val, node:$ptr),
543                           (truncstore_glue node:$val, node:$ptr)> {
544  let IsStore = 1;
545  let MemoryVT = i8;
546}
547
548def truncstorei16_glue : PatFrag<(ops node:$val, node:$ptr),
549                           (truncstore_glue node:$val, node:$ptr)> {
550  let IsStore = 1;
551  let MemoryVT = i16;
552}
553
554let IsStore = 1, AddressSpaces = StoreAddress_local.AddrSpaces in {
555def store_local_m0 : PatFrag<(ops node:$val, node:$ptr),
556                             (store_glue node:$val, node:$ptr)> {
557  let IsStore = 1;
558  let IsTruncStore = 0;
559}
560
561def truncstorei8_local_m0 : PatFrag<(ops node:$val, node:$ptr),
562                                    (unindexedstore_glue node:$val, node:$ptr)> {
563  let IsStore = 1;
564  let MemoryVT = i8;
565}
566
567def truncstorei16_local_m0 : PatFrag<(ops node:$val, node:$ptr),
568                                    (unindexedstore_glue node:$val, node:$ptr)> {
569  let IsStore = 1;
570  let MemoryVT = i16;
571}
572}
573
574def store_align8_local_m0 : PatFrag <(ops node:$value, node:$ptr),
575                                     (store_local_m0 node:$value, node:$ptr)>,
576                            Aligned<8> {
577  let IsStore = 1;
578  let IsTruncStore = 0;
579}
580
581def store_align16_local_m0 : PatFrag <(ops node:$value, node:$ptr),
582                                     (store_local_m0 node:$value, node:$ptr)>,
583                            Aligned<16> {
584  let IsStore = 1;
585  let IsTruncStore = 0;
586}
587
588let AddressSpaces = StoreAddress_local.AddrSpaces in {
589
590def atomic_store_local_8_m0 : PatFrag <
591  (ops node:$value, node:$ptr),
592  (AMDGPUatomic_st_glue node:$value, node:$ptr)> {
593  let IsAtomic = 1;
594  let MemoryVT = i8;
595}
596def atomic_store_local_16_m0 : PatFrag <
597  (ops node:$value, node:$ptr),
598  (AMDGPUatomic_st_glue node:$value, node:$ptr)> {
599  let IsAtomic = 1;
600  let MemoryVT = i16;
601}
602def atomic_store_local_32_m0 : PatFrag <
603  (ops node:$value, node:$ptr),
604  (AMDGPUatomic_st_glue node:$value, node:$ptr)> {
605  let IsAtomic = 1;
606  let MemoryVT = i32;
607}
608def atomic_store_local_64_m0 : PatFrag <
609  (ops node:$value, node:$ptr),
610  (AMDGPUatomic_st_glue node:$value, node:$ptr)> {
611  let IsAtomic = 1;
612  let MemoryVT = i64;
613}
614} // End let AddressSpaces = StoreAddress_local.AddrSpaces
615
616
617def si_setcc_uniform : PatFrag <
618  (ops node:$lhs, node:$rhs, node:$cond),
619  (setcc node:$lhs, node:$rhs, node:$cond), [{
620  return !N->isDivergent();
621}]>;
622
623//===----------------------------------------------------------------------===//
624// SDNodes PatFrags for a16 loads and stores with 3 components.
625// v3f16/v3i16 is widened to v4f16/v4i16, so we need to match on the memory
626// load/store size.
627//===----------------------------------------------------------------------===//
628
629class mubuf_intrinsic_load<SDPatternOperator name, ValueType vt> : PatFrag <
630  (ops node:$rsrc, node:$vindex, node:$voffset, node:$soffset, node:$offset,
631            node:$auxiliary, node:$idxen),
632  (name node:$rsrc, node:$vindex, node:$voffset, node:$soffset, node:$offset,
633            node:$auxiliary, node:$idxen)> {
634  let IsLoad = 1;
635  let MemoryVT = vt;
636}
637
638class mubuf_intrinsic_store<SDPatternOperator name, ValueType vt> : PatFrag <
639  (ops node:$vdata, node:$rsrc, node:$vindex, node:$voffset, node:$soffset, node:$offset,
640            node:$auxiliary, node:$idxen),
641  (name node:$vdata, node:$rsrc, node:$vindex, node:$voffset, node:$soffset, node:$offset,
642            node:$auxiliary, node:$idxen)> {
643  let IsStore = 1;
644  let MemoryVT = vt;
645}
646
647class mtbuf_intrinsic_load<SDPatternOperator name, ValueType vt> : PatFrag <
648  (ops node:$rsrc, node:$vindex, node:$voffset, node:$soffset, node:$offset,
649            node:$format, node:$auxiliary, node:$idxen),
650  (name node:$rsrc, node:$vindex, node:$voffset, node:$soffset, node:$offset,
651            node:$format, node:$auxiliary, node:$idxen)> {
652  let IsLoad = 1;
653  let MemoryVT = vt;
654}
655
656class mtbuf_intrinsic_store<SDPatternOperator name, ValueType vt> : PatFrag <
657  (ops node:$vdata, node:$rsrc, node:$vindex, node:$voffset, node:$soffset, node:$offset,
658            node:$format, node:$auxiliary, node:$idxen),
659  (name node:$vdata, node:$rsrc, node:$vindex, node:$voffset, node:$soffset, node:$offset,
660            node:$format, node:$auxiliary, node:$idxen)> {
661  let IsStore = 1;
662  let MemoryVT = vt;
663}
664
665//===----------------------------------------------------------------------===//
666// SDNodes PatFrags for d16 loads
667//===----------------------------------------------------------------------===//
668
669class LoadD16Frag <SDPatternOperator op> : PatFrag<
670  (ops node:$ptr, node:$tied_in),
671  (op node:$ptr, node:$tied_in)> {
672  let IsLoad = 1;
673}
674
675foreach as = [ "global", "flat", "constant", "local", "private", "region" ] in {
676let AddressSpaces = !cast<AddressSpaceList>("LoadAddress_"#as).AddrSpaces in {
677
678def load_d16_hi_#as : LoadD16Frag <SIload_d16_hi>;
679
680def az_extloadi8_d16_hi_#as : LoadD16Frag <SIload_d16_hi_u8> {
681  let MemoryVT = i8;
682}
683
684def sextloadi8_d16_hi_#as : LoadD16Frag <SIload_d16_hi_i8> {
685  let MemoryVT = i8;
686}
687
688def load_d16_lo_#as : LoadD16Frag <SIload_d16_lo>;
689
690def az_extloadi8_d16_lo_#as : LoadD16Frag <SIload_d16_lo_u8> {
691  let MemoryVT = i8;
692}
693
694def sextloadi8_d16_lo_#as : LoadD16Frag <SIload_d16_lo_i8> {
695  let MemoryVT = i8;
696}
697
698} // End let AddressSpaces = ...
699} // End foreach AddrSpace
700
701def lshr_rev : PatFrag <
702  (ops node:$src1, node:$src0),
703  (srl $src0, $src1)
704>;
705
706def ashr_rev : PatFrag <
707  (ops node:$src1, node:$src0),
708  (sra $src0, $src1)
709>;
710
711def lshl_rev : PatFrag <
712  (ops node:$src1, node:$src0),
713  (shl $src0, $src1)
714>;
715
716def add_ctpop : PatFrag <
717  (ops node:$src0, node:$src1),
718  (add (ctpop $src0), $src1)
719>;
720
721def xnor : PatFrag <
722  (ops node:$src0, node:$src1),
723  (not (xor $src0, $src1))
724>;
725
726foreach I = 1-4 in {
727def shl#I#_add : PatFrag <
728  (ops node:$src0, node:$src1),
729  (add (shl_oneuse $src0, (i32 I)), $src1)> {
730  // FIXME: Poor substitute for disabling pattern in SelectionDAG
731  let PredicateCode = [{return false;}];
732  let GISelPredicateCode = [{return true;}];
733}
734}
735
736multiclass SIAtomicM0Glue2 <string op_name, bit is_amdgpu = 0,
737                            SDTypeProfile tc = SDTAtomic2,
738                            bit IsInt = 1> {
739
740  def _glue : SDNode <
741    !if(is_amdgpu, "AMDGPUISD", "ISD")#"::ATOMIC_"#op_name, tc,
742    [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand, SDNPInGlue]
743  >;
744
745  let AddressSpaces = StoreAddress_local.AddrSpaces in {
746    defm _local_m0 : binary_atomic_op <!cast<SDNode>(NAME#"_glue"), IsInt>;
747    defm _local_m0 : ret_noret_binary_atomic_op <!cast<SDNode>(NAME#"_glue"),
748                                                 IsInt>;
749  }
750
751  let AddressSpaces = StoreAddress_region.AddrSpaces in {
752    defm _region_m0 : binary_atomic_op <!cast<SDNode>(NAME#"_glue"), IsInt>;
753    defm _region_m0 : ret_noret_binary_atomic_op <!cast<SDNode>(NAME#"_glue"),
754                                                  IsInt>;
755  }
756}
757
758defm atomic_load_add : SIAtomicM0Glue2 <"LOAD_ADD">;
759defm atomic_load_sub : SIAtomicM0Glue2 <"LOAD_SUB">;
760defm atomic_inc : SIAtomicM0Glue2 <"INC", 1>;
761defm atomic_dec : SIAtomicM0Glue2 <"DEC", 1>;
762defm atomic_load_and : SIAtomicM0Glue2 <"LOAD_AND">;
763defm atomic_load_min : SIAtomicM0Glue2 <"LOAD_MIN">;
764defm atomic_load_max : SIAtomicM0Glue2 <"LOAD_MAX">;
765defm atomic_load_or : SIAtomicM0Glue2 <"LOAD_OR">;
766defm atomic_load_xor : SIAtomicM0Glue2 <"LOAD_XOR">;
767defm atomic_load_umin : SIAtomicM0Glue2 <"LOAD_UMIN">;
768defm atomic_load_umax : SIAtomicM0Glue2 <"LOAD_UMAX">;
769defm atomic_swap : SIAtomicM0Glue2 <"SWAP">;
770defm atomic_load_fadd : SIAtomicM0Glue2 <"LOAD_FADD", 0, SDTAtomic2_f32, 0>;
771defm atomic_load_fmin : SIAtomicM0Glue2 <"LOAD_FMIN", 1, SDTAtomic2_f32, 0>;
772defm atomic_load_fmax : SIAtomicM0Glue2 <"LOAD_FMAX", 1, SDTAtomic2_f32, 0>;
773
774def as_i1timm : SDNodeXForm<timm, [{
775  return CurDAG->getTargetConstant(N->getZExtValue(), SDLoc(N), MVT::i1);
776}]>;
777
778def as_i8imm : SDNodeXForm<imm, [{
779  return CurDAG->getTargetConstant(N->getZExtValue(), SDLoc(N), MVT::i8);
780}]>;
781
782def as_i8timm : SDNodeXForm<timm, [{
783  return CurDAG->getTargetConstant(N->getSExtValue(), SDLoc(N), MVT::i16);
784}]>;
785
786def as_i16imm : SDNodeXForm<imm, [{
787  return CurDAG->getTargetConstant(N->getSExtValue(), SDLoc(N), MVT::i16);
788}]>;
789
790def as_i16timm : SDNodeXForm<timm, [{
791  return CurDAG->getTargetConstant(N->getSExtValue(), SDLoc(N), MVT::i16);
792}]>;
793
794def as_i32imm: SDNodeXForm<imm, [{
795  return CurDAG->getTargetConstant(N->getSExtValue(), SDLoc(N), MVT::i32);
796}]>;
797
798def as_i32timm: SDNodeXForm<timm, [{
799  return CurDAG->getTargetConstant(N->getSExtValue(), SDLoc(N), MVT::i32);
800}]>;
801
802def as_i64imm: SDNodeXForm<imm, [{
803  return CurDAG->getTargetConstant(N->getSExtValue(), SDLoc(N), MVT::i64);
804}]>;
805
806def cond_as_i32imm: SDNodeXForm<cond, [{
807  return CurDAG->getTargetConstant(N->get(), SDLoc(N), MVT::i32);
808}]>;
809
810// Copied from the AArch64 backend:
811def bitcast_fpimm_to_i32 : SDNodeXForm<fpimm, [{
812return CurDAG->getTargetConstant(
813  N->getValueAPF().bitcastToAPInt().getZExtValue(), SDLoc(N), MVT::i32);
814}]>;
815
816def frameindex_to_targetframeindex : SDNodeXForm<frameindex, [{
817  auto FI = cast<FrameIndexSDNode>(N);
818  return CurDAG->getTargetFrameIndex(FI->getIndex(), MVT::i32);
819}]>;
820
821// Copied from the AArch64 backend:
822def bitcast_fpimm_to_i64 : SDNodeXForm<fpimm, [{
823return CurDAG->getTargetConstant(
824  N->getValueAPF().bitcastToAPInt().getZExtValue(), SDLoc(N), MVT::i64);
825}]>;
826
827class bitextract_imm<int bitnum> : SDNodeXForm<imm, [{
828  uint64_t Imm = N->getZExtValue();
829  unsigned Bit = (Imm >> }] # bitnum # [{ ) & 1;
830  return CurDAG->getTargetConstant(Bit, SDLoc(N), MVT::i1);
831}]>;
832
833def SIMM16bit : ImmLeaf <i32,
834  [{return isInt<16>(Imm);}]
835>;
836
837def UIMM16bit : ImmLeaf <i32,
838  [{return isUInt<16>(Imm);}]
839>;
840
841def i64imm_32bit : ImmLeaf<i64, [{
842  return (Imm & 0xffffffffULL) == static_cast<uint64_t>(Imm);
843}]>;
844
845def InlineImm16 : ImmLeaf<i16, [{
846  return isInlineImmediate16(Imm);
847}]>;
848
849def InlineImm32 : ImmLeaf<i32, [{
850  return isInlineImmediate32(Imm);
851}]>;
852
853def InlineImm64 : ImmLeaf<i64, [{
854  return isInlineImmediate64(Imm);
855}]>;
856
857def InlineImmFP32 : FPImmLeaf<f32, [{
858  return isInlineImmediate(Imm);
859}]>;
860
861def InlineImmFP64 : FPImmLeaf<f64, [{
862  return isInlineImmediate(Imm);
863}]>;
864
865
866class VGPRImm <dag frag> : PatLeaf<frag, [{
867  return isVGPRImm(N);
868}]>;
869
870def NegateImm : SDNodeXForm<imm, [{
871  return CurDAG->getConstant(-N->getSExtValue(), SDLoc(N), MVT::i32);
872}]>;
873
874// TODO: When FP inline imm values work?
875def NegSubInlineConst32 : ImmLeaf<i32, [{
876  return Imm < -16 && Imm >= -64;
877}], NegateImm>;
878
879def NegSubInlineIntConst16 : ImmLeaf<i16, [{
880  return Imm < -16 && Imm >= -64;
881}], NegateImm>;
882
883def ShiftAmt32Imm : ImmLeaf <i32, [{
884  return Imm < 32;
885}]>;
886
887def getNegV2I16Imm : SDNodeXForm<build_vector, [{
888  return SDValue(packNegConstantV2I16(N, *CurDAG), 0);
889}]>;
890
891def NegSubInlineConstV216 : PatLeaf<(build_vector), [{
892  assert(N->getNumOperands() == 2);
893  assert(N->getOperand(0).getValueType().getSizeInBits() == 16);
894  SDValue Src0 = N->getOperand(0);
895  SDValue Src1 = N->getOperand(1);
896  if (Src0 == Src1)
897    return isNegInlineImmediate(Src0.getNode());
898
899  return (isNullConstantOrUndef(Src0) && isNegInlineImmediate(Src1.getNode())) ||
900         (isNullConstantOrUndef(Src1) && isNegInlineImmediate(Src0.getNode()));
901}], getNegV2I16Imm>;
902
903
904def fp16_zeros_high_16bits : PatLeaf<(f16 VGPR_32:$src), [{
905  return fp16SrcZerosHighBits(N->getOpcode());
906}]>;
907
908
909//===----------------------------------------------------------------------===//
910// MUBUF/SMEM Patterns
911//===----------------------------------------------------------------------===//
912
913def extract_cpol : SDNodeXForm<timm, [{
914  return CurDAG->getTargetConstant(N->getZExtValue() & AMDGPU::CPol::ALL, SDLoc(N), MVT::i8);
915}]>;
916
917def extract_swz : SDNodeXForm<timm, [{
918  return CurDAG->getTargetConstant((N->getZExtValue() >> 3) & 1, SDLoc(N), MVT::i8);
919}]>;
920
921def set_glc : SDNodeXForm<timm, [{
922  return CurDAG->getTargetConstant(N->getZExtValue() | AMDGPU::CPol::GLC, SDLoc(N), MVT::i8);
923}]>;
924
925//===----------------------------------------------------------------------===//
926// Custom Operands
927//===----------------------------------------------------------------------===//
928
929def SoppBrTarget : AsmOperandClass {
930  let Name = "SoppBrTarget";
931  let ParserMethod = "parseSOppBrTarget";
932}
933
934def sopp_brtarget : Operand<OtherVT> {
935  let EncoderMethod = "getSOPPBrEncoding";
936  let DecoderMethod = "decodeSoppBrTarget";
937  let OperandType = "OPERAND_PCREL";
938  let ParserMatchClass = SoppBrTarget;
939}
940
941def si_ga : Operand<iPTR>;
942
943def InterpSlotMatchClass : AsmOperandClass {
944  let Name = "InterpSlot";
945  let PredicateMethod = "isInterpSlot";
946  let ParserMethod = "parseInterpSlot";
947  let RenderMethod = "addImmOperands";
948}
949
950def InterpSlot : Operand<i32> {
951  let PrintMethod = "printInterpSlot";
952  let ParserMatchClass = InterpSlotMatchClass;
953  let OperandType = "OPERAND_IMMEDIATE";
954}
955
956def AttrMatchClass : AsmOperandClass {
957  let Name = "Attr";
958  let PredicateMethod = "isInterpAttr";
959  let ParserMethod = "parseInterpAttr";
960  let RenderMethod = "addImmOperands";
961}
962
963// It appears to be necessary to create a separate operand for this to
964// be able to parse attr<num> with no space.
965def Attr : Operand<i32> {
966  let PrintMethod = "printInterpAttr";
967  let ParserMatchClass = AttrMatchClass;
968  let OperandType = "OPERAND_IMMEDIATE";
969}
970
971def AttrChanMatchClass : AsmOperandClass {
972  let Name = "AttrChan";
973  let PredicateMethod = "isAttrChan";
974  let RenderMethod = "addImmOperands";
975}
976
977def AttrChan : Operand<i32> {
978  let PrintMethod = "printInterpAttrChan";
979  let ParserMatchClass = AttrChanMatchClass;
980  let OperandType = "OPERAND_IMMEDIATE";
981}
982
983def SendMsgMatchClass : AsmOperandClass {
984  let Name = "SendMsg";
985  let PredicateMethod = "isSendMsg";
986  let ParserMethod = "parseSendMsgOp";
987  let RenderMethod = "addImmOperands";
988}
989
990def SwizzleMatchClass : AsmOperandClass {
991  let Name = "Swizzle";
992  let PredicateMethod = "isSwizzle";
993  let ParserMethod = "parseSwizzleOp";
994  let RenderMethod = "addImmOperands";
995  let IsOptional = 1;
996}
997
998def EndpgmMatchClass : AsmOperandClass {
999  let Name = "EndpgmImm";
1000  let PredicateMethod = "isEndpgm";
1001  let ParserMethod = "parseEndpgmOp";
1002  let RenderMethod = "addImmOperands";
1003  let IsOptional = 1;
1004}
1005
1006def ExpTgtMatchClass : AsmOperandClass {
1007  let Name = "ExpTgt";
1008  let PredicateMethod = "isExpTgt";
1009  let ParserMethod = "parseExpTgt";
1010  let RenderMethod = "printExpTgt";
1011}
1012
1013def SWaitMatchClass : AsmOperandClass {
1014  let Name = "SWaitCnt";
1015  let RenderMethod = "addImmOperands";
1016  let ParserMethod = "parseSWaitCntOps";
1017}
1018
1019def DepCtrMatchClass : AsmOperandClass {
1020  let Name = "DepCtr";
1021  let RenderMethod = "addImmOperands";
1022  let ParserMethod = "parseDepCtrOps";
1023}
1024
1025def VReg32OrOffClass : AsmOperandClass {
1026  let Name = "VReg32OrOff";
1027  let ParserMethod = "parseVReg32OrOff";
1028}
1029
1030let OperandType = "OPERAND_IMMEDIATE" in {
1031def SendMsgImm : Operand<i32> {
1032  let PrintMethod = "printSendMsg";
1033  let ParserMatchClass = SendMsgMatchClass;
1034}
1035
1036def SwizzleImm : Operand<i16> {
1037  let PrintMethod = "printSwizzle";
1038  let ParserMatchClass = SwizzleMatchClass;
1039}
1040
1041def EndpgmImm : Operand<i16> {
1042  let PrintMethod = "printEndpgm";
1043  let ParserMatchClass = EndpgmMatchClass;
1044}
1045
1046def WAIT_FLAG : Operand <i32> {
1047  let ParserMatchClass = SWaitMatchClass;
1048  let PrintMethod = "printWaitFlag";
1049}
1050
1051def DepCtrImm : Operand <i32> {
1052  let ParserMatchClass = DepCtrMatchClass;
1053  let PrintMethod = "printDepCtr";
1054}
1055} // End OperandType = "OPERAND_IMMEDIATE"
1056
1057include "SIInstrFormats.td"
1058include "VIInstrFormats.td"
1059
1060def BoolReg : AsmOperandClass {
1061  let Name = "BoolReg";
1062  let ParserMethod = "parseBoolReg";
1063  let RenderMethod = "addRegOperands";
1064}
1065
1066class BoolRC : RegisterOperand<SReg_1> {
1067  let ParserMatchClass = BoolReg;
1068  let DecoderMethod = "decodeBoolReg";
1069}
1070
1071def SSrc_i1 : RegisterOperand<SReg_1_XEXEC> {
1072  let ParserMatchClass = BoolReg;
1073  let DecoderMethod = "decodeBoolReg";
1074}
1075
1076def VOPDstS64orS32 : BoolRC {
1077  let PrintMethod = "printVOPDst";
1078}
1079
1080// SCSrc_i1 is the operand for pseudo instructions only.
1081// Boolean immediates shall not be exposed to codegen instructions.
1082def SCSrc_i1 : RegisterOperand<SReg_1_XEXEC> {
1083  let OperandNamespace = "AMDGPU";
1084  let OperandType = "OPERAND_REG_IMM_INT32";
1085  let ParserMatchClass = BoolReg;
1086  let DecoderMethod = "decodeBoolReg";
1087}
1088
1089// ===----------------------------------------------------------------------===//
1090// ExpSrc* Special cases for exp src operands which are printed as
1091// "off" depending on en operand.
1092// ===----------------------------------------------------------------------===//
1093
1094def ExpSrc0 : RegisterOperand<VGPR_32> {
1095  let PrintMethod = "printExpSrc0";
1096  let ParserMatchClass = VReg32OrOffClass;
1097}
1098
1099def ExpSrc1 : RegisterOperand<VGPR_32> {
1100  let PrintMethod = "printExpSrc1";
1101  let ParserMatchClass = VReg32OrOffClass;
1102}
1103
1104def ExpSrc2 : RegisterOperand<VGPR_32> {
1105  let PrintMethod = "printExpSrc2";
1106  let ParserMatchClass = VReg32OrOffClass;
1107}
1108
1109def ExpSrc3 : RegisterOperand<VGPR_32> {
1110  let PrintMethod = "printExpSrc3";
1111  let ParserMatchClass = VReg32OrOffClass;
1112}
1113
1114class SDWASrc<ValueType vt> : RegisterOperand<VS_32> {
1115  let OperandNamespace = "AMDGPU";
1116  string Type = !if(isFloatType<vt>.ret, "FP", "INT");
1117  let OperandType = "OPERAND_REG_INLINE_C_"#Type#vt.Size;
1118  let DecoderMethod = "decodeSDWASrc"#vt.Size;
1119  let EncoderMethod = "getSDWASrcEncoding";
1120}
1121
1122def SDWASrc_i32 : SDWASrc<i32>;
1123def SDWASrc_i16 : SDWASrc<i16>;
1124def SDWASrc_f32 : SDWASrc<f32>;
1125def SDWASrc_f16 : SDWASrc<f16>;
1126
1127def SDWAVopcDst : BoolRC {
1128  let OperandNamespace = "AMDGPU";
1129  let OperandType = "OPERAND_SDWA_VOPC_DST";
1130  let EncoderMethod = "getSDWAVopcDstEncoding";
1131  let DecoderMethod = "decodeSDWAVopcDst";
1132  let PrintMethod = "printVOPDst";
1133}
1134
1135class NamedMatchClass<string CName, bit Optional = 1> : AsmOperandClass {
1136  let Name = "Imm"#CName;
1137  let PredicateMethod = "is"#CName;
1138  let ParserMethod = !if(Optional, "parseOptionalOperand", "parse"#CName);
1139  let RenderMethod = "addImmOperands";
1140  let IsOptional = Optional;
1141  let DefaultMethod = !if(Optional, "default"#CName, ?);
1142}
1143
1144class NamedOperandBit<string Name, AsmOperandClass MatchClass> : Operand<i1> {
1145  let PrintMethod = "print"#Name;
1146  let ParserMatchClass = MatchClass;
1147}
1148
1149class NamedOperandBit_0<string Name, AsmOperandClass MatchClass> :
1150  OperandWithDefaultOps<i1, (ops (i1 0))> {
1151  let PrintMethod = "print"#Name;
1152  let ParserMatchClass = MatchClass;
1153}
1154
1155class NamedOperandBit_1<string Name, AsmOperandClass MatchClass> :
1156  OperandWithDefaultOps<i1, (ops (i1 1))> {
1157  let PrintMethod = "print"#Name;
1158  let ParserMatchClass = MatchClass;
1159}
1160
1161class NamedOperandU8<string Name, AsmOperandClass MatchClass> : Operand<i8> {
1162  let PrintMethod = "print"#Name;
1163  let ParserMatchClass = MatchClass;
1164}
1165
1166class NamedOperandU16<string Name, AsmOperandClass MatchClass> : Operand<i16> {
1167  let PrintMethod = "print"#Name;
1168  let ParserMatchClass = MatchClass;
1169}
1170
1171class NamedOperandU32<string Name, AsmOperandClass MatchClass> : Operand<i32> {
1172  let PrintMethod = "print"#Name;
1173  let ParserMatchClass = MatchClass;
1174}
1175
1176class NamedOperandU32_0<string Name, AsmOperandClass MatchClass> :
1177  OperandWithDefaultOps<i32, (ops (i32 0))> {
1178  let PrintMethod = "print"#Name;
1179  let ParserMatchClass = MatchClass;
1180}
1181
1182class NamedOperandU32Default0<string Name, AsmOperandClass MatchClass> :
1183  OperandWithDefaultOps<i32, (ops (i32 0))> {
1184  let PrintMethod = "print"#Name;
1185  let ParserMatchClass = MatchClass;
1186}
1187
1188class NamedOperandU32Default1<string Name, AsmOperandClass MatchClass> :
1189  OperandWithDefaultOps<i32, (ops (i32 1))> {
1190  let PrintMethod = "print"#Name;
1191  let ParserMatchClass = MatchClass;
1192}
1193
1194let OperandType = "OPERAND_IMMEDIATE" in {
1195
1196def offen : NamedOperandBit<"Offen", NamedMatchClass<"Offen">>;
1197def idxen : NamedOperandBit<"Idxen", NamedMatchClass<"Idxen">>;
1198def addr64 : NamedOperandBit<"Addr64", NamedMatchClass<"Addr64">>;
1199
1200def flat_offset : NamedOperandU16<"FlatOffset", NamedMatchClass<"FlatOffset">>;
1201def offset : NamedOperandU16<"Offset", NamedMatchClass<"Offset">>;
1202def offset0 : NamedOperandU8<"Offset0", NamedMatchClass<"Offset0">>;
1203def offset1 : NamedOperandU8<"Offset1", NamedMatchClass<"Offset1">>;
1204
1205def gds : NamedOperandBit<"GDS", NamedMatchClass<"GDS">>;
1206
1207def omod : NamedOperandU32<"OModSI", NamedMatchClass<"OModSI">>;
1208def omod0 : NamedOperandU32_0<"OModSI", NamedMatchClass<"OModSI">>;
1209
1210// We need to make the cases with a default of 0 distinct from no
1211// default to help deal with some cases where the operand appears
1212// before a mandatory operand.
1213def clampmod : NamedOperandBit<"ClampSI", NamedMatchClass<"ClampSI">>;
1214def clampmod0 : NamedOperandBit_0<"ClampSI", NamedMatchClass<"ClampSI">>;
1215def highmod : NamedOperandBit<"High", NamedMatchClass<"High">>;
1216
1217def CPol : NamedOperandU32<"CPol", NamedMatchClass<"CPol">>;
1218def CPol_0 : NamedOperandU32Default0<"CPol", NamedMatchClass<"CPol">>;
1219def CPol_GLC1 : NamedOperandU32Default1<"CPol", NamedMatchClass<"CPol">>;
1220
1221def TFE : NamedOperandBit<"TFE", NamedMatchClass<"TFE">>;
1222def TFE_0 : NamedOperandBit_0<"TFE", NamedMatchClass<"TFE">>;
1223def SWZ : NamedOperandBit<"SWZ", NamedMatchClass<"SWZ">>;
1224def SWZ_0 : NamedOperandBit_0<"SWZ", NamedMatchClass<"SWZ">>;
1225def UNorm : NamedOperandBit<"UNorm", NamedMatchClass<"UNorm">>;
1226def DA : NamedOperandBit<"DA", NamedMatchClass<"DA">>;
1227def R128A16 : NamedOperandBit<"R128A16", NamedMatchClass<"R128A16">>;
1228def GFX10A16 : NamedOperandBit<"GFX10A16", NamedMatchClass<"GFX10A16">>;
1229def D16 : NamedOperandBit<"D16", NamedMatchClass<"D16">>;
1230def LWE : NamedOperandBit<"LWE", NamedMatchClass<"LWE">>;
1231def exp_compr : NamedOperandBit<"ExpCompr", NamedMatchClass<"ExpCompr">>;
1232def exp_vm : NamedOperandBit<"ExpVM", NamedMatchClass<"ExpVM">>;
1233
1234def FORMAT : NamedOperandU8<"FORMAT", NamedMatchClass<"FORMAT", 0>>;
1235
1236def DMask : NamedOperandU16<"DMask", NamedMatchClass<"DMask">>;
1237def Dim : NamedOperandU8<"Dim", NamedMatchClass<"Dim", 0>>;
1238
1239def dpp8 : NamedOperandU32<"DPP8", NamedMatchClass<"DPP8", 0>>;
1240
1241def dpp_ctrl : NamedOperandU32<"DPPCtrl", NamedMatchClass<"DPPCtrl", 0>>;
1242def row_mask : NamedOperandU32<"RowMask", NamedMatchClass<"RowMask">>;
1243def bank_mask : NamedOperandU32<"BankMask", NamedMatchClass<"BankMask">>;
1244def bound_ctrl : NamedOperandBit<"BoundCtrl", NamedMatchClass<"BoundCtrl">>;
1245def FI : NamedOperandU32<"FI", NamedMatchClass<"FI">>;
1246
1247def dst_sel : NamedOperandU32<"SDWADstSel", NamedMatchClass<"SDWADstSel">>;
1248def src0_sel : NamedOperandU32<"SDWASrc0Sel", NamedMatchClass<"SDWASrc0Sel">>;
1249def src1_sel : NamedOperandU32<"SDWASrc1Sel", NamedMatchClass<"SDWASrc1Sel">>;
1250def dst_unused : NamedOperandU32<"SDWADstUnused", NamedMatchClass<"SDWADstUnused">>;
1251
1252def op_sel0 : NamedOperandU32Default0<"OpSel", NamedMatchClass<"OpSel">>;
1253def op_sel_hi0 : NamedOperandU32Default0<"OpSelHi", NamedMatchClass<"OpSelHi">>;
1254def neg_lo0 : NamedOperandU32Default0<"NegLo", NamedMatchClass<"NegLo">>;
1255def neg_hi0 : NamedOperandU32Default0<"NegHi", NamedMatchClass<"NegHi">>;
1256
1257def blgp : NamedOperandU32<"BLGP", NamedMatchClass<"BLGP">>;
1258def cbsz : NamedOperandU32<"CBSZ", NamedMatchClass<"CBSZ">>;
1259def abid : NamedOperandU32<"ABID", NamedMatchClass<"ABID">>;
1260
1261def hwreg : NamedOperandU32<"Hwreg", NamedMatchClass<"Hwreg", 0>>;
1262
1263def exp_tgt : NamedOperandU32<"ExpTgt", NamedMatchClass<"ExpTgt", 0>> {
1264
1265}
1266
1267} // End OperandType = "OPERAND_IMMEDIATE"
1268
1269class KImmMatchClass<int size> : AsmOperandClass {
1270  let Name = "KImmFP"#size;
1271  let PredicateMethod = "isKImmFP"#size;
1272  let ParserMethod = "parseImm";
1273  let RenderMethod = "addKImmFP"#size#"Operands";
1274}
1275
1276class kimmOperand<ValueType vt> : Operand<vt> {
1277  let OperandNamespace = "AMDGPU";
1278  let OperandType = "OPERAND_KIMM"#vt.Size;
1279  let PrintMethod = "printU"#vt.Size#"ImmOperand";
1280  let ParserMatchClass = !cast<AsmOperandClass>("KImmFP"#vt.Size#"MatchClass");
1281  let DecoderMethod = "decodeOperand_f"#vt.Size#"kimm";
1282}
1283
1284// 32-bit VALU immediate operand that uses the constant bus.
1285def KImmFP32MatchClass : KImmMatchClass<32>;
1286def f32kimm : kimmOperand<i32>;
1287
1288// 32-bit VALU immediate operand with a 16-bit value that uses the
1289// constant bus.
1290def KImmFP16MatchClass : KImmMatchClass<16>;
1291def f16kimm : kimmOperand<i16>;
1292
1293class FPInputModsMatchClass <int opSize> : AsmOperandClass {
1294  let Name = "RegOrImmWithFP"#opSize#"InputMods";
1295  let ParserMethod = "parseRegOrImmWithFPInputMods";
1296  let PredicateMethod = "isRegOrImmWithFP"#opSize#"InputMods";
1297}
1298
1299def FP16InputModsMatchClass : FPInputModsMatchClass<16>;
1300def FP32InputModsMatchClass : FPInputModsMatchClass<32>;
1301def FP64InputModsMatchClass : FPInputModsMatchClass<64>;
1302
1303class InputMods <AsmOperandClass matchClass> : Operand <i32> {
1304  let OperandNamespace = "AMDGPU";
1305  let OperandType = "OPERAND_INPUT_MODS";
1306  let ParserMatchClass = matchClass;
1307}
1308
1309class FPInputMods <FPInputModsMatchClass matchClass> : InputMods <matchClass> {
1310  let PrintMethod = "printOperandAndFPInputMods";
1311}
1312
1313def FP16InputMods : FPInputMods<FP16InputModsMatchClass>;
1314def FP32InputMods : FPInputMods<FP32InputModsMatchClass>;
1315def FP64InputMods : FPInputMods<FP64InputModsMatchClass>;
1316
1317class IntInputModsMatchClass <int opSize> : AsmOperandClass {
1318  let Name = "RegOrImmWithInt"#opSize#"InputMods";
1319  let ParserMethod = "parseRegOrImmWithIntInputMods";
1320  let PredicateMethod = "isRegOrImmWithInt"#opSize#"InputMods";
1321}
1322def Int32InputModsMatchClass : IntInputModsMatchClass<32>;
1323def Int64InputModsMatchClass : IntInputModsMatchClass<64>;
1324
1325class IntInputMods <IntInputModsMatchClass matchClass> : InputMods <matchClass> {
1326  let PrintMethod = "printOperandAndIntInputMods";
1327}
1328def Int32InputMods : IntInputMods<Int32InputModsMatchClass>;
1329def Int64InputMods : IntInputMods<Int64InputModsMatchClass>;
1330
1331class OpSelModsMatchClass : AsmOperandClass {
1332  let Name = "OpSelMods";
1333  let ParserMethod = "parseRegOrImm";
1334  let PredicateMethod = "isRegOrImm";
1335}
1336
1337def IntOpSelModsMatchClass : OpSelModsMatchClass;
1338def IntOpSelMods : InputMods<IntOpSelModsMatchClass>;
1339
1340class FPSDWAInputModsMatchClass <int opSize> : AsmOperandClass {
1341  let Name = "SDWAWithFP"#opSize#"InputMods";
1342  let ParserMethod = "parseRegOrImmWithFPInputMods";
1343  let PredicateMethod = "isSDWAFP"#opSize#"Operand";
1344}
1345
1346def FP16SDWAInputModsMatchClass : FPSDWAInputModsMatchClass<16>;
1347def FP32SDWAInputModsMatchClass : FPSDWAInputModsMatchClass<32>;
1348
1349class FPSDWAInputMods <FPSDWAInputModsMatchClass matchClass> :
1350  InputMods <matchClass> {
1351  let PrintMethod = "printOperandAndFPInputMods";
1352}
1353
1354def FP16SDWAInputMods : FPSDWAInputMods<FP16SDWAInputModsMatchClass>;
1355def FP32SDWAInputMods : FPSDWAInputMods<FP32SDWAInputModsMatchClass>;
1356
1357def FPVRegInputModsMatchClass : AsmOperandClass {
1358  let Name = "VRegWithFPInputMods";
1359  let ParserMethod = "parseRegWithFPInputMods";
1360  let PredicateMethod = "isVRegWithInputMods";
1361}
1362
1363def FPVRegInputMods : InputMods <FPVRegInputModsMatchClass> {
1364  let PrintMethod = "printOperandAndFPInputMods";
1365}
1366
1367class IntSDWAInputModsMatchClass <int opSize> : AsmOperandClass {
1368  let Name = "SDWAWithInt"#opSize#"InputMods";
1369  let ParserMethod = "parseRegOrImmWithIntInputMods";
1370  let PredicateMethod = "isSDWAInt"#opSize#"Operand";
1371}
1372
1373def Int16SDWAInputModsMatchClass : IntSDWAInputModsMatchClass<16>;
1374def Int32SDWAInputModsMatchClass : IntSDWAInputModsMatchClass<32>;
1375
1376class IntSDWAInputMods <IntSDWAInputModsMatchClass matchClass> :
1377  InputMods <matchClass> {
1378  let PrintMethod = "printOperandAndIntInputMods";
1379}
1380
1381def Int16SDWAInputMods : IntSDWAInputMods<Int16SDWAInputModsMatchClass>;
1382def Int32SDWAInputMods : IntSDWAInputMods<Int32SDWAInputModsMatchClass>;
1383
1384def IntVRegInputModsMatchClass : AsmOperandClass {
1385  let Name = "VRegWithIntInputMods";
1386  let ParserMethod = "parseRegWithIntInputMods";
1387  let PredicateMethod = "isVRegWithInputMods";
1388}
1389
1390def IntVRegInputMods : InputMods <IntVRegInputModsMatchClass> {
1391  let PrintMethod = "printOperandAndIntInputMods";
1392}
1393
1394class PackedFPInputModsMatchClass <int opSize> : AsmOperandClass {
1395  let Name = "PackedFP"#opSize#"InputMods";
1396  let ParserMethod = "parseRegOrImm";
1397  let PredicateMethod = "isRegOrImm";
1398//  let PredicateMethod = "isPackedFP"#opSize#"InputMods";
1399}
1400
1401class PackedIntInputModsMatchClass <int opSize> : AsmOperandClass {
1402  let Name = "PackedInt"#opSize#"InputMods";
1403  let ParserMethod = "parseRegOrImm";
1404  let PredicateMethod = "isRegOrImm";
1405//  let PredicateMethod = "isPackedInt"#opSize#"InputMods";
1406}
1407
1408def PackedF16InputModsMatchClass : PackedFPInputModsMatchClass<16>;
1409def PackedI16InputModsMatchClass : PackedIntInputModsMatchClass<16>;
1410
1411class PackedFPInputMods <PackedFPInputModsMatchClass matchClass> : InputMods <matchClass> {
1412//  let PrintMethod = "printPackedFPInputMods";
1413}
1414
1415class PackedIntInputMods <PackedIntInputModsMatchClass matchClass> : InputMods <matchClass> {
1416  //let PrintMethod = "printPackedIntInputMods";
1417}
1418
1419def PackedF16InputMods : PackedFPInputMods<PackedF16InputModsMatchClass>;
1420def PackedI16InputMods : PackedIntInputMods<PackedI16InputModsMatchClass>;
1421
1422//===----------------------------------------------------------------------===//
1423// Complex patterns
1424//===----------------------------------------------------------------------===//
1425
1426def DS1Addr1Offset : ComplexPattern<iPTR, 2, "SelectDS1Addr1Offset">;
1427def DS64Bit4ByteAligned : ComplexPattern<iPTR, 3, "SelectDS64Bit4ByteAligned">;
1428def DS128Bit8ByteAligned : ComplexPattern<iPTR, 3, "SelectDS128Bit8ByteAligned">;
1429
1430def MOVRELOffset : ComplexPattern<iPTR, 2, "SelectMOVRELOffset">;
1431
1432def VOP3Mods0 : ComplexPattern<untyped, 4, "SelectVOP3Mods0">;
1433def VOP3Mods  : ComplexPattern<untyped, 2, "SelectVOP3Mods">;
1434def VOP3NoMods : ComplexPattern<untyped, 1, "SelectVOP3NoMods">;
1435// VOP3Mods, but the input source is known to never be NaN.
1436def VOP3Mods_nnan : ComplexPattern<fAny, 2, "SelectVOP3Mods_NNaN">;
1437
1438def VOP3OMods : ComplexPattern<untyped, 3, "SelectVOP3OMods">;
1439
1440def VOP3PMods  : ComplexPattern<untyped, 2, "SelectVOP3PMods">;
1441
1442def VOP3PModsDOT  : ComplexPattern<untyped, 2, "SelectVOP3PModsDOT">;
1443
1444def VOP3OpSel  : ComplexPattern<untyped, 2, "SelectVOP3OpSel">;
1445
1446def VOP3OpSelMods  : ComplexPattern<untyped, 2, "SelectVOP3OpSelMods">;
1447
1448def VOP3PMadMixMods  : ComplexPattern<untyped, 2, "SelectVOP3PMadMixMods">;
1449
1450//===----------------------------------------------------------------------===//
1451// SI assembler operands
1452//===----------------------------------------------------------------------===//
1453
1454def SIOperand {
1455  int ZERO = 0x80;
1456  int VCC = 0x6A;
1457  int FLAT_SCR = 0x68;
1458}
1459
1460// This should be kept in sync with SISrcMods enum
1461def SRCMODS {
1462  int NONE = 0;
1463  int NEG = 1;
1464  int ABS = 2;
1465  int NEG_ABS = 3;
1466
1467  int NEG_HI = ABS;
1468  int OP_SEL_0 = 4;
1469  int OP_SEL_1 = 8;
1470  int DST_OP_SEL = 8;
1471}
1472
1473def DSTCLAMP {
1474  int NONE = 0;
1475  int ENABLE = 1;
1476}
1477
1478def DSTOMOD {
1479  int NONE = 0;
1480}
1481
1482def HWREG {
1483  int MODE = 1;
1484  int STATUS = 2;
1485  int TRAPSTS = 3;
1486  int HW_ID = 4;
1487  int GPR_ALLOC = 5;
1488  int LDS_ALLOC = 6;
1489  int IB_STS = 7;
1490  int MEM_BASES = 15;
1491  int TBA_LO = 16;
1492  int TBA_HI = 17;
1493  int TMA_LO = 18;
1494  int TMA_HI = 19;
1495  int FLAT_SCR_LO = 20;
1496  int FLAT_SCR_HI = 21;
1497  int XNACK_MASK = 22;
1498  int POPS_PACKER = 25;
1499  int SHADER_CYCLES = 29;
1500}
1501
1502class getHwRegImm<int Reg, int Offset = 0, int Size = 32> {
1503  int ret = !and(!or(Reg,
1504                     !shl(Offset, 6),
1505                     !shl(!add(Size, -1), 11)), 65535);
1506}
1507
1508//===----------------------------------------------------------------------===//
1509//
1510// SI Instruction multiclass helpers.
1511//
1512// Instructions with _32 take 32-bit operands.
1513// Instructions with _64 take 64-bit operands.
1514//
1515// VOP_* instructions can use either a 32-bit or 64-bit encoding.  The 32-bit
1516// encoding is the standard encoding, but instruction that make use of
1517// any of the instruction modifiers must use the 64-bit encoding.
1518//
1519// Instructions with _e32 use the 32-bit encoding.
1520// Instructions with _e64 use the 64-bit encoding.
1521//
1522//===----------------------------------------------------------------------===//
1523
1524class SIMCInstr <string pseudo, int subtarget> {
1525  string PseudoInstr = pseudo;
1526  int Subtarget = subtarget;
1527}
1528
1529//===----------------------------------------------------------------------===//
1530// Vector ALU classes
1531//===----------------------------------------------------------------------===//
1532
1533class getNumSrcArgs<ValueType Src0, ValueType Src1, ValueType Src2> {
1534  int ret =
1535    !if (!eq(Src0.Value, untyped.Value),      0,
1536      !if (!eq(Src1.Value, untyped.Value),    1,   // VOP1
1537         !if (!eq(Src2.Value, untyped.Value), 2,   // VOP2
1538                                              3))); // VOP3
1539}
1540
1541// Returns the register class to use for the destination of VOP[123C]
1542// instructions for the given VT.
1543class getVALUDstForVT<ValueType VT> {
1544  RegisterOperand ret = !if(!eq(VT.Size, 32), VOPDstOperand<VGPR_32>,
1545                          !if(!eq(VT.Size, 128), VOPDstOperand<VReg_128>,
1546                            !if(!eq(VT.Size, 64), VOPDstOperand<VReg_64>,
1547                              !if(!eq(VT.Size, 16), VOPDstOperand<VGPR_32>,
1548                              VOPDstS64orS32)))); // else VT == i1
1549}
1550
1551// Returns the register class to use for the destination of VOP[12C]
1552// instructions with SDWA extension
1553class getSDWADstForVT<ValueType VT> {
1554  RegisterOperand ret = !if(!eq(VT.Size, 1),
1555                            SDWAVopcDst, // VOPC
1556                            VOPDstOperand<VGPR_32>); // VOP1/2 32-bit dst
1557}
1558
1559// Returns the register class to use for source 0 of VOP[12C]
1560// instructions for the given VT.
1561class getVOPSrc0ForVT<ValueType VT> {
1562  bit isFP = isFloatType<VT>.ret;
1563
1564  RegisterOperand ret =
1565    !if(isFP,
1566      !if(!eq(VT.Size, 64),
1567         VSrc_f64,
1568         !if(!eq(VT.Value, f16.Value),
1569            VSrc_f16,
1570            !if(!eq(VT.Value, v2f16.Value),
1571               VSrc_v2f16,
1572               !if(!eq(VT.Value, v4f16.Value),
1573                 AVSrc_64,
1574                 VSrc_f32
1575               )
1576            )
1577         )
1578       ),
1579       !if(!eq(VT.Size, 64),
1580          VSrc_b64,
1581          !if(!eq(VT.Value, i16.Value),
1582             VSrc_b16,
1583             !if(!eq(VT.Value, v2i16.Value),
1584                VSrc_v2b16,
1585                VSrc_b32
1586             )
1587          )
1588       )
1589    );
1590}
1591
1592class getSOPSrcForVT<ValueType VT> {
1593  RegisterOperand ret = !if(!eq(VT.Size, 64), SSrc_b64, SSrc_b32);
1594}
1595
1596// Returns the vreg register class to use for source operand given VT
1597class getVregSrcForVT<ValueType VT> {
1598  RegisterClass ret = !if(!eq(VT.Size, 128), VReg_128,
1599                        !if(!eq(VT.Size, 96), VReg_96,
1600                          !if(!eq(VT.Size, 64), VReg_64,
1601                            !if(!eq(VT.Size, 48), VReg_64,
1602                              VGPR_32))));
1603}
1604
1605class getSDWASrcForVT <ValueType VT> {
1606  bit isFP = isFloatType<VT>.ret;
1607  RegisterOperand retFlt = !if(!eq(VT.Size, 16), SDWASrc_f16, SDWASrc_f32);
1608  RegisterOperand retInt = !if(!eq(VT.Size, 16), SDWASrc_i16, SDWASrc_i32);
1609  RegisterOperand ret = !if(isFP, retFlt, retInt);
1610}
1611
1612// Returns the register class to use for sources of VOP3 instructions for the
1613// given VT.
1614class getVOP3SrcForVT<ValueType VT> {
1615  bit isFP = isFloatType<VT>.ret;
1616  RegisterOperand ret =
1617  !if(!eq(VT.Size, 128),
1618     VSrc_128,
1619     !if(!eq(VT.Size, 64),
1620        !if(isFP,
1621           !if(!eq(VT.Value, v2f32.Value),
1622               VSrc_v2f32,
1623               VSrc_f64),
1624           !if(!eq(VT.Value, v2i32.Value),
1625               VSrc_v2b32,
1626           VSrc_b64)),
1627        !if(!eq(VT.Value, i1.Value),
1628           SSrc_i1,
1629           !if(isFP,
1630              !if(!eq(VT.Value, f16.Value),
1631                 VSrc_f16,
1632                 !if(!eq(VT.Value, v2f16.Value),
1633                    VSrc_v2f16,
1634                    !if(!eq(VT.Value, v4f16.Value),
1635                      AVSrc_64,
1636                      VSrc_f32
1637                    )
1638                 )
1639              ),
1640              !if(!eq(VT.Value, i16.Value),
1641                 VSrc_b16,
1642                 !if(!eq(VT.Value, v2i16.Value),
1643                    VSrc_v2b16,
1644                    VSrc_b32
1645                 )
1646              )
1647           )
1648        )
1649     )
1650  );
1651}
1652
1653// Float or packed int
1654class isModifierType<ValueType SrcVT> {
1655  bit ret = !or(!eq(SrcVT.Value, f16.Value),
1656                !eq(SrcVT.Value, f32.Value),
1657                !eq(SrcVT.Value, f64.Value),
1658                !eq(SrcVT.Value, v2f16.Value),
1659                !eq(SrcVT.Value, v2i16.Value),
1660                !eq(SrcVT.Value, v2f32.Value),
1661                !eq(SrcVT.Value, v2i32.Value));
1662}
1663
1664// Return type of input modifiers operand for specified input operand
1665class getSrcMod <ValueType VT, bit EnableF32SrcMods> {
1666  bit isFP = isFloatType<VT>.ret;
1667  bit isPacked = isPackedType<VT>.ret;
1668  Operand ret =  !if(!eq(VT.Size, 64),
1669                     !if(isFP, FP64InputMods, Int64InputMods),
1670                       !if(isFP,
1671                         !if(!eq(VT.Value, f16.Value),
1672                            FP16InputMods,
1673                            FP32InputMods
1674                          ),
1675                         !if(EnableF32SrcMods, FP32InputMods, Int32InputMods))
1676                     );
1677}
1678
1679class getOpSelMod <ValueType VT> {
1680  Operand ret = !if(!eq(VT.Value, f16.Value), FP16InputMods, IntOpSelMods);
1681}
1682
1683// Return type of input modifiers operand specified input operand for DPP
1684class getSrcModDPP <ValueType VT> {
1685  bit isFP = isFloatType<VT>.ret;
1686  Operand ret = !if(isFP, FPVRegInputMods, IntVRegInputMods);
1687}
1688
1689// Return type of input modifiers operand specified input operand for SDWA
1690class getSrcModSDWA <ValueType VT> {
1691  Operand ret = !if(!eq(VT.Value, f16.Value), FP16SDWAInputMods,
1692                !if(!eq(VT.Value, f32.Value), FP32SDWAInputMods,
1693                !if(!eq(VT.Value, i16.Value), Int16SDWAInputMods,
1694                Int32SDWAInputMods)));
1695}
1696
1697// Returns the input arguments for VOP[12C] instructions for the given SrcVT.
1698class getIns32 <RegisterOperand Src0RC, RegisterClass Src1RC, int NumSrcArgs> {
1699  dag ret = !if(!eq(NumSrcArgs, 1), (ins Src0RC:$src0),               // VOP1
1700            !if(!eq(NumSrcArgs, 2), (ins Src0RC:$src0, Src1RC:$src1), // VOP2
1701                                    (ins)));
1702}
1703
1704// Returns the input arguments for VOP3 instructions for the given SrcVT.
1705class getIns64 <RegisterOperand Src0RC, RegisterOperand Src1RC,
1706                RegisterOperand Src2RC, int NumSrcArgs,
1707                bit HasClamp, bit HasModifiers, bit HasSrc2Mods, bit HasOMod,
1708                Operand Src0Mod, Operand Src1Mod, Operand Src2Mod> {
1709
1710  dag ret =
1711    !if (!eq(NumSrcArgs, 0),
1712      // VOP1 without input operands (V_NOP, V_CLREXCP)
1713      (ins),
1714      /* else */
1715    !if (!eq(NumSrcArgs, 1),
1716      !if (HasModifiers,
1717        // VOP1 with modifiers
1718        !if(HasOMod,
1719          (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1720               clampmod0:$clamp, omod0:$omod),
1721          (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1722               clampmod0:$clamp))
1723      /* else */,
1724        // VOP1 without modifiers
1725        !if (HasClamp,
1726          (ins Src0RC:$src0, clampmod0:$clamp),
1727          (ins Src0RC:$src0))
1728      /* endif */ ),
1729    !if (!eq(NumSrcArgs, 2),
1730      !if (HasModifiers,
1731        // VOP 2 with modifiers
1732        !if(HasOMod,
1733          (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1734               Src1Mod:$src1_modifiers, Src1RC:$src1,
1735               clampmod0:$clamp, omod0:$omod),
1736           (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1737               Src1Mod:$src1_modifiers, Src1RC:$src1,
1738               clampmod0:$clamp))
1739      /* else */,
1740        // VOP2 without modifiers
1741        !if (HasClamp,
1742          (ins Src0RC:$src0, Src1RC:$src1, clampmod0:$clamp),
1743          (ins Src0RC:$src0, Src1RC:$src1))
1744
1745      /* endif */ )
1746    /* NumSrcArgs == 3 */,
1747      !if (HasModifiers,
1748        !if (HasSrc2Mods,
1749          // VOP3 with modifiers
1750          !if (HasOMod,
1751            (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1752                 Src1Mod:$src1_modifiers, Src1RC:$src1,
1753                 Src2Mod:$src2_modifiers, Src2RC:$src2,
1754                 clampmod0:$clamp, omod0:$omod),
1755            !if (HasClamp,
1756              (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1757                   Src1Mod:$src1_modifiers, Src1RC:$src1,
1758                   Src2Mod:$src2_modifiers, Src2RC:$src2,
1759                   clampmod0:$clamp),
1760              (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1761                   Src1Mod:$src1_modifiers, Src1RC:$src1,
1762                   Src2Mod:$src2_modifiers, Src2RC:$src2))),
1763          // VOP3 with modifiers except src2
1764          !if (HasOMod,
1765            (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1766                 Src1Mod:$src1_modifiers, Src1RC:$src1,
1767                 Src2RC:$src2, clampmod0:$clamp, omod0:$omod),
1768            !if (HasClamp,
1769              (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1770                   Src1Mod:$src1_modifiers, Src1RC:$src1,
1771                   Src2RC:$src2, clampmod0:$clamp),
1772              (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1773                   Src1Mod:$src1_modifiers, Src1RC:$src1,
1774                   Src2RC:$src2))))
1775      /* else */,
1776        // VOP3 without modifiers
1777        !if (HasClamp,
1778          (ins Src0RC:$src0, Src1RC:$src1, Src2RC:$src2, clampmod0:$clamp),
1779          (ins Src0RC:$src0, Src1RC:$src1, Src2RC:$src2))
1780      /* endif */ ))));
1781}
1782
1783class getInsVOP3Base<RegisterOperand Src0RC, RegisterOperand Src1RC,
1784                RegisterOperand Src2RC, int NumSrcArgs,
1785                bit HasClamp, bit HasModifiers, bit HasSrc2Mods, bit HasOMod,
1786                Operand Src0Mod, Operand Src1Mod, Operand Src2Mod, bit HasOpSel,
1787                bit IsVOP3P> {
1788  // getInst64 handles clamp and omod. implicit mutex between vop3p and omod
1789  dag base = getIns64 <Src0RC, Src1RC, Src2RC, NumSrcArgs,
1790                HasClamp, HasModifiers, HasSrc2Mods, HasOMod,
1791                Src0Mod, Src1Mod, Src2Mod>.ret;
1792  dag opsel = (ins op_sel0:$op_sel);
1793  dag vop3pFields = (ins op_sel_hi0:$op_sel_hi, neg_lo0:$neg_lo, neg_hi0:$neg_hi);
1794  dag ret = !con(base,
1795                 !if(HasOpSel, opsel,(ins)),
1796                 !if(IsVOP3P, vop3pFields,(ins)));
1797}
1798
1799class getInsVOP3P <RegisterOperand Src0RC, RegisterOperand Src1RC,
1800                   RegisterOperand Src2RC, int NumSrcArgs, bit HasClamp,
1801                   Operand Src0Mod, Operand Src1Mod, Operand Src2Mod> {
1802  dag ret = getInsVOP3Base<Src0RC, Src1RC, Src2RC, NumSrcArgs,
1803                    HasClamp, 1/*HasModifiers*/, 1/*HasSrc2Mods*/,
1804                    0/*HasOMod*/, Src0Mod, Src1Mod, Src2Mod,
1805                    1/*HasOpSel*/, 1/*IsVOP3P*/>.ret;
1806}
1807
1808class getInsVOP3OpSel <RegisterOperand Src0RC, RegisterOperand Src1RC,
1809                       RegisterOperand Src2RC, int NumSrcArgs,
1810                       bit HasClamp, bit HasOMod,
1811                       Operand Src0Mod, Operand Src1Mod, Operand Src2Mod> {
1812  dag ret = getInsVOP3Base<Src0RC, Src1RC,
1813                    Src2RC, NumSrcArgs,
1814                    HasClamp, 1/*HasModifiers*/, 1/*HasSrc2Mods*/, HasOMod,
1815                    Src0Mod, Src1Mod, Src2Mod, 1/*HasOpSel*/, 0>.ret;
1816}
1817
1818class getInsDPPBase <RegisterOperand OldRC, RegisterClass Src0RC, RegisterClass Src1RC,
1819                 int NumSrcArgs, bit HasModifiers,
1820                 Operand Src0Mod, Operand Src1Mod> {
1821
1822  dag ret = !if (!eq(NumSrcArgs, 0),
1823                // VOP1 without input operands (V_NOP)
1824                (ins ),
1825            !if (!eq(NumSrcArgs, 1),
1826              !if (HasModifiers,
1827                // VOP1_DPP with modifiers
1828                (ins OldRC:$old, Src0Mod:$src0_modifiers,
1829                     Src0RC:$src0)
1830              /* else */,
1831                // VOP1_DPP without modifiers
1832                (ins OldRC:$old, Src0RC:$src0)
1833              /* endif */),
1834              !if (HasModifiers,
1835                // VOP2_DPP with modifiers
1836                (ins OldRC:$old,
1837                     Src0Mod:$src0_modifiers, Src0RC:$src0,
1838                     Src1Mod:$src1_modifiers, Src1RC:$src1)
1839              /* else */,
1840                // VOP2_DPP without modifiers
1841                (ins OldRC:$old,
1842                     Src0RC:$src0, Src1RC:$src1)
1843                )));
1844}
1845
1846class getInsDPP <RegisterOperand OldRC, RegisterClass Src0RC, RegisterClass Src1RC,
1847                 int NumSrcArgs, bit HasModifiers,
1848                 Operand Src0Mod, Operand Src1Mod> {
1849  dag ret = !con(getInsDPPBase<OldRC, Src0RC, Src1RC, NumSrcArgs,
1850                               HasModifiers, Src0Mod, Src1Mod>.ret,
1851                 (ins dpp_ctrl:$dpp_ctrl, row_mask:$row_mask,
1852                  bank_mask:$bank_mask, bound_ctrl:$bound_ctrl));
1853}
1854
1855class getInsDPP16 <RegisterOperand OldRC, RegisterClass Src0RC, RegisterClass Src1RC,
1856                 int NumSrcArgs, bit HasModifiers,
1857                 Operand Src0Mod, Operand Src1Mod> {
1858  dag ret = !con(getInsDPP<OldRC, Src0RC, Src1RC, NumSrcArgs,
1859                           HasModifiers, Src0Mod, Src1Mod>.ret,
1860                 (ins FI:$fi));
1861}
1862
1863class getInsDPP8 <RegisterOperand OldRC, RegisterClass Src0RC, RegisterClass Src1RC,
1864                 int NumSrcArgs, bit HasModifiers,
1865                 Operand Src0Mod, Operand Src1Mod> {
1866  dag ret = !con(getInsDPPBase<OldRC, Src0RC, Src1RC, NumSrcArgs,
1867                               HasModifiers, Src0Mod, Src1Mod>.ret,
1868                 (ins dpp8:$dpp8, FI:$fi));
1869}
1870
1871
1872// Ins for SDWA
1873class getInsSDWA <RegisterOperand Src0RC, RegisterOperand Src1RC, int NumSrcArgs,
1874                  bit HasSDWAOMod, Operand Src0Mod, Operand Src1Mod,
1875                  ValueType DstVT> {
1876
1877  dag ret = !if(!eq(NumSrcArgs, 0),
1878               // VOP1 without input operands (V_NOP)
1879               (ins),
1880            !if(!eq(NumSrcArgs, 1),
1881               // VOP1
1882               !if(!not(HasSDWAOMod),
1883                  // VOP1_SDWA without omod
1884                  (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1885                       clampmod:$clamp,
1886                       dst_sel:$dst_sel, dst_unused:$dst_unused,
1887                       src0_sel:$src0_sel),
1888                  // VOP1_SDWA with omod
1889                  (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1890                       clampmod:$clamp, omod:$omod,
1891                       dst_sel:$dst_sel, dst_unused:$dst_unused,
1892                       src0_sel:$src0_sel)),
1893            !if(!eq(NumSrcArgs, 2),
1894               !if(!eq(DstVT.Size, 1),
1895                  // VOPC_SDWA
1896                  (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1897                       Src1Mod:$src1_modifiers, Src1RC:$src1,
1898                       clampmod:$clamp, src0_sel:$src0_sel, src1_sel:$src1_sel),
1899                  // VOP2_SDWA
1900                  !if(!not(HasSDWAOMod),
1901                     // VOP2_SDWA without omod
1902                     (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1903                          Src1Mod:$src1_modifiers, Src1RC:$src1,
1904                          clampmod:$clamp,
1905                          dst_sel:$dst_sel, dst_unused:$dst_unused,
1906                          src0_sel:$src0_sel, src1_sel:$src1_sel),
1907                     // VOP2_SDWA with omod
1908                     (ins Src0Mod:$src0_modifiers, Src0RC:$src0,
1909                          Src1Mod:$src1_modifiers, Src1RC:$src1,
1910                          clampmod:$clamp, omod:$omod,
1911                          dst_sel:$dst_sel, dst_unused:$dst_unused,
1912                          src0_sel:$src0_sel, src1_sel:$src1_sel))),
1913            (ins)/* endif */)));
1914}
1915
1916// Outs for DPP
1917class getOutsDPP <bit HasDst, ValueType DstVT, RegisterOperand DstRCDPP> {
1918  dag ret = !if(HasDst,
1919                !if(!eq(DstVT.Size, 1),
1920                    (outs), // no dst for VOPC, we use "vcc"-token as dst in SDWA VOPC instructions
1921                    (outs DstRCDPP:$vdst)),
1922                (outs)); // V_NOP
1923}
1924
1925// Outs for SDWA
1926class getOutsSDWA <bit HasDst, ValueType DstVT, RegisterOperand DstRCSDWA> {
1927  dag ret = !if(HasDst,
1928                !if(!eq(DstVT.Size, 1),
1929                    (outs DstRCSDWA:$sdst),
1930                    (outs DstRCSDWA:$vdst)),
1931                (outs)); // V_NOP
1932}
1933
1934// Returns the assembly string for the inputs and outputs of a VOP[12C]
1935// instruction.  This does not add the _e32 suffix, so it can be reused
1936// by getAsm64.
1937class getAsm32 <bit HasDst, int NumSrcArgs, ValueType DstVT = i32> {
1938  string dst = !if(!eq(DstVT.Size, 1), "$sdst", "$vdst"); // use $sdst for VOPC
1939  string src0 = ", $src0";
1940  string src1 = ", $src1";
1941  string src2 = ", $src2";
1942  string ret = !if(HasDst, dst, "") #
1943               !if(!eq(NumSrcArgs, 1), src0, "") #
1944               !if(!eq(NumSrcArgs, 2), src0#src1, "") #
1945               !if(!eq(NumSrcArgs, 3), src0#src1#src2, "");
1946}
1947
1948// Returns the assembly string for the inputs and outputs of a VOP3
1949// instruction.
1950class getAsm64 <bit HasDst, int NumSrcArgs, bit HasIntClamp, bit HasModifiers,
1951                bit HasOMod, ValueType DstVT = i32> {
1952  string dst = !if(!eq(DstVT.Size, 1), "$sdst", "$vdst"); // use $sdst for VOPC
1953  string src0 = !if(!eq(NumSrcArgs, 1), "$src0_modifiers", "$src0_modifiers,");
1954  string src1 = !if(!eq(NumSrcArgs, 1), "",
1955                   !if(!eq(NumSrcArgs, 2), " $src1_modifiers",
1956                                           " $src1_modifiers,"));
1957  string src2 = !if(!eq(NumSrcArgs, 3), " $src2_modifiers", "");
1958  string iclamp = !if(HasIntClamp, "$clamp", "");
1959  string ret =
1960  !if(!not(HasModifiers),
1961      getAsm32<HasDst, NumSrcArgs, DstVT>.ret # iclamp,
1962      dst#", "#src0#src1#src2#"$clamp"#!if(HasOMod, "$omod", ""));
1963}
1964
1965// Returns the assembly string for the inputs and outputs of a VOP3P
1966// instruction.
1967class getAsmVOP3P <int NumSrcArgs, bit HasModifiers,
1968                   bit HasClamp> {
1969  string dst = "$vdst";
1970  string src0 = !if(!eq(NumSrcArgs, 1), "$src0", "$src0,");
1971  string src1 = !if(!eq(NumSrcArgs, 1), "",
1972                   !if(!eq(NumSrcArgs, 2), " $src1",
1973                                           " $src1,"));
1974  string src2 = !if(!eq(NumSrcArgs, 3), " $src2", "");
1975
1976  string mods = !if(HasModifiers, "$neg_lo$neg_hi", "");
1977  string clamp = !if(HasClamp, "$clamp", "");
1978
1979  // Each modifier is printed as an array of bits for each operand, so
1980  // all operands are printed as part of src0_modifiers.
1981  string ret = dst#", "#src0#src1#src2#"$op_sel$op_sel_hi"#mods#clamp;
1982}
1983
1984class getAsmVOP3OpSel <int NumSrcArgs,
1985                       bit HasClamp,
1986                       bit Src0HasMods,
1987                       bit Src1HasMods,
1988                       bit Src2HasMods> {
1989  string dst = "$vdst";
1990
1991  string isrc0 = !if(!eq(NumSrcArgs, 1), "$src0", "$src0,");
1992  string isrc1 = !if(!eq(NumSrcArgs, 1), "",
1993                     !if(!eq(NumSrcArgs, 2), " $src1",
1994                                             " $src1,"));
1995  string isrc2 = !if(!eq(NumSrcArgs, 3), " $src2", "");
1996
1997  string fsrc0 = !if(!eq(NumSrcArgs, 1), "$src0_modifiers", "$src0_modifiers,");
1998  string fsrc1 = !if(!eq(NumSrcArgs, 1), "",
1999                     !if(!eq(NumSrcArgs, 2), " $src1_modifiers",
2000                                             " $src1_modifiers,"));
2001  string fsrc2 = !if(!eq(NumSrcArgs, 3), " $src2_modifiers", "");
2002
2003  string src0 = !if(Src0HasMods, fsrc0, isrc0);
2004  string src1 = !if(Src1HasMods, fsrc1, isrc1);
2005  string src2 = !if(Src2HasMods, fsrc2, isrc2);
2006
2007  string clamp = !if(HasClamp, "$clamp", "");
2008
2009  string ret = dst#", "#src0#src1#src2#"$op_sel"#clamp;
2010}
2011
2012class getAsmDPP <bit HasDst, int NumSrcArgs, bit HasModifiers, ValueType DstVT = i32> {
2013  string dst = !if(HasDst,
2014                   !if(!eq(DstVT.Size, 1),
2015                       "$sdst",
2016                       "$vdst"),
2017                    ""); // use $sdst for VOPC
2018  string src0 = !if(!eq(NumSrcArgs, 1), "$src0_modifiers", "$src0_modifiers,");
2019  string src1 = !if(!eq(NumSrcArgs, 1), "",
2020                   !if(!eq(NumSrcArgs, 2), " $src1_modifiers",
2021                                           " $src1_modifiers,"));
2022  string args = !if(!not(HasModifiers),
2023                     getAsm32<0, NumSrcArgs, DstVT>.ret,
2024                     ", "#src0#src1);
2025  string ret = dst#args#" $dpp_ctrl$row_mask$bank_mask$bound_ctrl";
2026}
2027
2028class getAsmDPP16 <bit HasDst, int NumSrcArgs, bit HasModifiers, ValueType DstVT = i32> {
2029  string ret = getAsmDPP<HasDst, NumSrcArgs, HasModifiers, DstVT>.ret#"$fi";
2030}
2031
2032class getAsmDPP8 <bit HasDst, int NumSrcArgs, bit HasModifiers, ValueType DstVT = i32>
2033  : getAsmDPP<HasDst, NumSrcArgs, HasModifiers, DstVT> {
2034  let ret = dst#args#" $dpp8$fi";
2035}
2036
2037
2038class getAsmSDWA <bit HasDst, int NumSrcArgs, ValueType DstVT = i32> {
2039  string dst = !if(HasDst,
2040                   !if(!eq(DstVT.Size, 1),
2041                       " vcc", // use vcc token as dst for VOPC instructions
2042                       "$vdst"),
2043                    "");
2044  string src0 = "$src0_modifiers";
2045  string src1 = "$src1_modifiers";
2046  string args = !if(!eq(NumSrcArgs, 0),
2047                    "",
2048                    !if(!eq(NumSrcArgs, 1),
2049                        ", "#src0#"$clamp",
2050                        ", "#src0#", "#src1#"$clamp"
2051                     )
2052                );
2053  string sdwa = !if(!eq(NumSrcArgs, 0),
2054                    "",
2055                    !if(!eq(NumSrcArgs, 1),
2056                        " $dst_sel $dst_unused $src0_sel",
2057                        !if(!eq(DstVT.Size, 1),
2058                            " $src0_sel $src1_sel", // No dst_sel and dst_unused for VOPC
2059                            " $dst_sel $dst_unused $src0_sel $src1_sel"
2060                        )
2061                    )
2062                );
2063  string ret = dst#args#sdwa;
2064}
2065
2066class getAsmSDWA9 <bit HasDst, bit HasOMod, int NumSrcArgs,
2067                   ValueType DstVT = i32> {
2068  string dst = !if(HasDst,
2069                   !if(!eq(DstVT.Size, 1),
2070                       "$sdst", // VOPC
2071                       "$vdst"), // VOP1/2
2072                    "");
2073  string src0 = "$src0_modifiers";
2074  string src1 = "$src1_modifiers";
2075  string out_mods = !if(!not(HasOMod), "$clamp", "$clamp$omod");
2076  string args = !if(!eq(NumSrcArgs, 0), "",
2077                    !if(!eq(NumSrcArgs, 1),
2078                        ", "#src0,
2079                        ", "#src0#", "#src1
2080                     )
2081                );
2082  string sdwa = !if(!eq(NumSrcArgs, 0), "",
2083                    !if(!eq(NumSrcArgs, 1),
2084                        out_mods#" $dst_sel $dst_unused $src0_sel",
2085                        !if(!eq(DstVT.Size, 1),
2086                            " $src0_sel $src1_sel", // No dst_sel, dst_unused and output modifiers for VOPC
2087                            out_mods#" $dst_sel $dst_unused $src0_sel $src1_sel"
2088                        )
2089                    )
2090                );
2091  string ret = dst#args#sdwa;
2092}
2093
2094class getHas64BitOps <int NumSrcArgs, ValueType DstVT, ValueType Src0VT,
2095                      ValueType Src1VT> {
2096  bit ret = !if(!eq(NumSrcArgs, 3),
2097                0,
2098                !if(!eq(DstVT.Size, 64),
2099                    1,
2100                    !if(!eq(Src0VT.Size, 64),
2101                        1,
2102                        !if(!eq(Src1VT.Size, 64),
2103                            1,
2104                            0
2105                        )
2106                    )
2107                )
2108            );
2109}
2110
2111class getHasSDWA <int NumSrcArgs, ValueType DstVT = i32, ValueType Src0VT = i32,
2112                  ValueType Src1VT = i32> {
2113  bit ret = !if(!eq(NumSrcArgs, 3),
2114                0, // NumSrcArgs == 3 - No SDWA for VOP3
2115                !if(!eq(DstVT.Size, 64),
2116                    0, // 64-bit dst - No SDWA for 64-bit operands
2117                    !if(!eq(Src0VT.Size, 64),
2118                        0, // 64-bit src0
2119                        !if(!eq(Src1VT.Size, 64),
2120                            0, // 64-bit src2
2121                            1
2122                        )
2123                    )
2124                )
2125            );
2126}
2127
2128class getHasDPP <int NumSrcArgs> {
2129  bit ret = !if(!eq(NumSrcArgs, 3),
2130                0, // NumSrcArgs == 3 - No DPP for VOP3
2131                1);
2132}
2133
2134class getHasExt64BitDPP <int NumSrcArgs, ValueType DstVT = i32, ValueType Src0VT = i32,
2135                 ValueType Src1VT = i32> {
2136  bit ret = !and(getHasDPP<NumSrcArgs>.ret,
2137                 getHas64BitOps<NumSrcArgs, DstVT, Src0VT, Src1VT>.ret);
2138}
2139
2140// Function that checks if instruction supports DPP and SDWA
2141class getHasExt <int NumSrcArgs, ValueType DstVT = i32, ValueType Src0VT = i32,
2142                 ValueType Src1VT = i32> {
2143  bit ret = !or(getHasDPP<NumSrcArgs>.ret,
2144                getHasSDWA<NumSrcArgs, DstVT, Src0VT, Src1VT>.ret);
2145}
2146
2147// Return an AGPR+VGPR operand class for the given VGPR register class.
2148class getLdStRegisterOperand<RegisterClass RC> {
2149  RegisterOperand ret =
2150    !if(!eq(RC.Size, 32), AVLdSt_32,
2151      !if(!eq(RC.Size, 64), AVLdSt_64,
2152        !if(!eq(RC.Size, 96), AVLdSt_96,
2153          !if(!eq(RC.Size, 128), AVLdSt_128,
2154            !if(!eq(RC.Size, 160), AVLdSt_160,
2155              RegisterOperand<VReg_1> // invalid register
2156    )))));
2157}
2158
2159class BitOr<bit a, bit b> {
2160  bit ret = !if(a, 1, !if(b, 1, 0));
2161}
2162
2163class BitAnd<bit a, bit b> {
2164  bit ret = !if(a, !if(b, 1, 0), 0);
2165}
2166
2167def PatGenMode {
2168  int NoPattern = 0;
2169  int Pattern   = 1;
2170}
2171
2172class VOPProfile <list<ValueType> _ArgVT, bit _EnableF32SrcMods = 0,
2173                  bit _EnableClamp = 0> {
2174
2175  field list<ValueType> ArgVT = _ArgVT;
2176  field bit EnableF32SrcMods = _EnableF32SrcMods;
2177  field bit EnableClamp = _EnableClamp;
2178
2179  field ValueType DstVT = ArgVT[0];
2180  field ValueType Src0VT = ArgVT[1];
2181  field ValueType Src1VT = ArgVT[2];
2182  field ValueType Src2VT = ArgVT[3];
2183  field RegisterOperand DstRC = getVALUDstForVT<DstVT>.ret;
2184  field RegisterOperand DstRCDPP = getVALUDstForVT<DstVT>.ret;
2185  field RegisterOperand DstRCSDWA = getSDWADstForVT<DstVT>.ret;
2186  field RegisterOperand Src0RC32 = getVOPSrc0ForVT<Src0VT>.ret;
2187  field RegisterClass Src1RC32 = getVregSrcForVT<Src1VT>.ret;
2188  field RegisterOperand Src0RC64 = getVOP3SrcForVT<Src0VT>.ret;
2189  field RegisterOperand Src1RC64 = getVOP3SrcForVT<Src1VT>.ret;
2190  field RegisterOperand Src2RC64 = getVOP3SrcForVT<Src2VT>.ret;
2191  field RegisterClass Src0DPP = getVregSrcForVT<Src0VT>.ret;
2192  field RegisterClass Src1DPP = getVregSrcForVT<Src1VT>.ret;
2193  field RegisterOperand Src0SDWA = getSDWASrcForVT<Src0VT>.ret;
2194  field RegisterOperand Src1SDWA = getSDWASrcForVT<Src0VT>.ret;
2195  field Operand Src0Mod = getSrcMod<Src0VT, EnableF32SrcMods>.ret;
2196  field Operand Src1Mod = getSrcMod<Src1VT, EnableF32SrcMods>.ret;
2197  field Operand Src2Mod = getSrcMod<Src2VT, EnableF32SrcMods>.ret;
2198  field Operand Src0ModDPP = getSrcModDPP<Src0VT>.ret;
2199  field Operand Src1ModDPP = getSrcModDPP<Src1VT>.ret;
2200  field Operand Src0ModSDWA = getSrcModSDWA<Src0VT>.ret;
2201  field Operand Src1ModSDWA = getSrcModSDWA<Src1VT>.ret;
2202
2203
2204  field bit HasDst = !ne(DstVT.Value, untyped.Value);
2205  field bit HasDst32 = HasDst;
2206  field bit EmitDst = HasDst; // force dst encoding, see v_movreld_b32 special case
2207  field bit EmitDstSel = EmitDst;
2208  field int NumSrcArgs = getNumSrcArgs<Src0VT, Src1VT, Src2VT>.ret;
2209  field bit HasSrc0 = !ne(Src0VT.Value, untyped.Value);
2210  field bit HasSrc1 = !ne(Src1VT.Value, untyped.Value);
2211  field bit HasSrc2 = !ne(Src2VT.Value, untyped.Value);
2212
2213  // HasSrc*FloatMods affects the SDWA encoding. We ignore EnableF32SrcMods.
2214  field bit HasSrc0FloatMods = isFloatType<Src0VT>.ret;
2215  field bit HasSrc1FloatMods = isFloatType<Src1VT>.ret;
2216  field bit HasSrc2FloatMods = isFloatType<Src2VT>.ret;
2217
2218  // HasSrc*IntMods affects the SDWA encoding. We ignore EnableF32SrcMods.
2219  field bit HasSrc0IntMods = isIntType<Src0VT>.ret;
2220  field bit HasSrc1IntMods = isIntType<Src1VT>.ret;
2221  field bit HasSrc2IntMods = isIntType<Src2VT>.ret;
2222
2223  field bit HasClamp = !or(isModifierType<Src0VT>.ret, EnableClamp);
2224  field bit HasSDWAClamp = EmitDst;
2225  field bit HasFPClamp = !and(isFloatType<DstVT>.ret, HasClamp);
2226  field bit HasIntClamp = !if(isFloatType<DstVT>.ret, 0, HasClamp);
2227  field bit HasClampLo = HasClamp;
2228  field bit HasClampHi = !and(isPackedType<DstVT>.ret, HasClamp);
2229  field bit HasHigh = 0;
2230
2231  field bit IsPacked = isPackedType<Src0VT>.ret;
2232  field bit HasOpSel = IsPacked;
2233  field bit HasOMod = !if(HasOpSel, 0, isFloatType<DstVT>.ret);
2234  field bit HasSDWAOMod = isFloatType<DstVT>.ret;
2235
2236  field bit HasModifiers = !or(isModifierType<Src0VT>.ret,
2237                               isModifierType<Src1VT>.ret,
2238                               isModifierType<Src2VT>.ret,
2239                               HasOMod,
2240                               EnableF32SrcMods);
2241
2242  field bit HasSrc0Mods = HasModifiers;
2243  field bit HasSrc1Mods = !if(HasModifiers, !or(HasSrc1FloatMods, HasSrc1IntMods), 0);
2244  field bit HasSrc2Mods = !if(HasModifiers, !or(HasSrc2FloatMods, HasSrc2IntMods), 0);
2245
2246  field bit HasExt = getHasExt<NumSrcArgs, DstVT, Src0VT, Src1VT>.ret;
2247  field bit HasExtDPP = getHasDPP<NumSrcArgs>.ret;
2248  field bit HasExt64BitDPP = getHasExt64BitDPP<NumSrcArgs, DstVT, Src0VT, Src1VT>.ret;
2249  field bit HasExtSDWA = getHasSDWA<NumSrcArgs, DstVT, Src0VT, Src1VT>.ret;
2250  field bit HasExtSDWA9 = HasExtSDWA;
2251  field int NeedPatGen = PatGenMode.NoPattern;
2252
2253  field bit IsMAI = 0;
2254  field bit IsDOT = 0;
2255  field bit IsSingle = 0;
2256
2257  field Operand Src0PackedMod = !if(HasSrc0FloatMods, PackedF16InputMods, PackedI16InputMods);
2258  field Operand Src1PackedMod = !if(HasSrc1FloatMods, PackedF16InputMods, PackedI16InputMods);
2259  field Operand Src2PackedMod = !if(HasSrc2FloatMods, PackedF16InputMods, PackedI16InputMods);
2260
2261  field dag Outs = !if(HasDst,(outs DstRC:$vdst),(outs));
2262
2263  // VOP3b instructions are a special case with a second explicit
2264  // output. This is manually overridden for them.
2265  field dag Outs32 = Outs;
2266  field dag Outs64 = Outs;
2267  field dag OutsDPP = getOutsDPP<HasDst, DstVT, DstRCDPP>.ret;
2268  field dag OutsDPP8 = getOutsDPP<HasDst, DstVT, DstRCDPP>.ret;
2269  field dag OutsSDWA = getOutsSDWA<HasDst, DstVT, DstRCSDWA>.ret;
2270
2271  field dag Ins32 = getIns32<Src0RC32, Src1RC32, NumSrcArgs>.ret;
2272  field dag Ins64 = getIns64<Src0RC64, Src1RC64, Src2RC64, NumSrcArgs,
2273                             HasIntClamp, HasModifiers, HasSrc2Mods,
2274                             HasOMod, Src0Mod, Src1Mod, Src2Mod>.ret;
2275  field dag InsVOP3P = getInsVOP3P<Src0RC64, Src1RC64, Src2RC64,
2276                                   NumSrcArgs, HasClamp,
2277                                   Src0PackedMod, Src1PackedMod, Src2PackedMod>.ret;
2278  field dag InsVOP3OpSel = getInsVOP3OpSel<Src0RC64, Src1RC64, Src2RC64,
2279                                NumSrcArgs, HasClamp, HasOMod,
2280                                getOpSelMod<Src0VT>.ret,
2281                                getOpSelMod<Src1VT>.ret,
2282                                getOpSelMod<Src2VT>.ret>.ret;
2283  field dag InsDPP = !if(HasExtDPP,
2284                         getInsDPP<DstRCDPP, Src0DPP, Src1DPP, NumSrcArgs,
2285                                   HasModifiers, Src0ModDPP, Src1ModDPP>.ret,
2286                         (ins));
2287  field dag InsDPP16 = getInsDPP16<DstRCDPP, Src0DPP, Src1DPP, NumSrcArgs,
2288                                   HasModifiers, Src0ModDPP, Src1ModDPP>.ret;
2289  field dag InsDPP8 = getInsDPP8<DstRCDPP, Src0DPP, Src1DPP, NumSrcArgs, 0,
2290                                 Src0ModDPP, Src1ModDPP>.ret;
2291  field dag InsSDWA = getInsSDWA<Src0SDWA, Src1SDWA, NumSrcArgs,
2292                                 HasSDWAOMod, Src0ModSDWA, Src1ModSDWA,
2293                                 DstVT>.ret;
2294
2295
2296  field string Asm32 = getAsm32<HasDst, NumSrcArgs, DstVT>.ret;
2297  field string Asm64 = getAsm64<HasDst, NumSrcArgs, HasIntClamp, HasModifiers, HasOMod, DstVT>.ret;
2298  field string AsmVOP3P = getAsmVOP3P<NumSrcArgs, HasModifiers, HasClamp>.ret;
2299  field string AsmVOP3OpSel = getAsmVOP3OpSel<NumSrcArgs,
2300                                              HasClamp,
2301                                              HasSrc0FloatMods,
2302                                              HasSrc1FloatMods,
2303                                              HasSrc2FloatMods>.ret;
2304  field string AsmDPP = !if(HasExtDPP,
2305                            getAsmDPP<HasDst, NumSrcArgs, HasModifiers, DstVT>.ret, "");
2306  field string AsmDPP16 = getAsmDPP16<HasDst, NumSrcArgs, HasModifiers, DstVT>.ret;
2307  // DPP8 encoding has no fields for modifiers, and it is enforced by setting
2308  // the asm operand name via this HasModifiers flag
2309  field string AsmDPP8 = getAsmDPP8<HasDst, NumSrcArgs, 0 /*HasModifiers*/, DstVT>.ret;
2310  field string AsmSDWA = getAsmSDWA<HasDst, NumSrcArgs, DstVT>.ret;
2311  field string AsmSDWA9 = getAsmSDWA9<HasDst, HasSDWAOMod, NumSrcArgs, DstVT>.ret;
2312
2313  field string TieRegDPP = "$old";
2314}
2315
2316class VOP_NO_EXT <VOPProfile p> : VOPProfile <p.ArgVT> {
2317  let HasExt = 0;
2318  let HasExtDPP = 0;
2319  let HasExt64BitDPP = 0;
2320  let HasExtSDWA = 0;
2321  let HasExtSDWA9 = 0;
2322}
2323
2324class VOP_PAT_GEN <VOPProfile p, int mode=PatGenMode.NoPattern> : VOPProfile <p.ArgVT> {
2325  let NeedPatGen = mode;
2326}
2327
2328def VOP_F16_F16 : VOPProfile <[f16, f16, untyped, untyped]>;
2329def VOP_F16_I16 : VOPProfile <[f16, i16, untyped, untyped]>;
2330def VOP_I16_F16 : VOPProfile <[i16, f16, untyped, untyped]>;
2331
2332def VOP_F16_F16_F16 : VOPProfile <[f16, f16, f16, untyped]>;
2333def VOP_F16_F16_I16 : VOPProfile <[f16, f16, i16, untyped]>;
2334def VOP_F16_F16_I32 : VOPProfile <[f16, f16, i32, untyped]>;
2335def VOP_I16_I16_I16 : VOPProfile <[i16, i16, i16, untyped]>;
2336def VOP_I16_I16_I16_ARITH : VOPProfile <[i16, i16, i16, untyped], 0, /*EnableClamp=*/1>;
2337
2338def VOP_I16_I16_I16_I16 : VOPProfile <[i16, i16, i16, i16, untyped]>;
2339def VOP_F16_F16_F16_F16 : VOPProfile <[f16, f16, f16, f16, untyped]>;
2340
2341def VOP_I32_I16_I16_I32 : VOPProfile <[i32, i16, i16, i32, untyped]>;
2342
2343def VOP_V2F16_V2F16_V2F16 : VOPProfile <[v2f16, v2f16, v2f16, untyped]>;
2344def VOP_V2I16_V2I16_V2I16 : VOPProfile <[v2i16, v2i16, v2i16, untyped]>;
2345def VOP_B32_F16_F16 : VOPProfile <[i32, f16, f16, untyped]>;
2346
2347def VOP_V2F16_V2F16_V2F16_V2F16 : VOPProfile <[v2f16, v2f16, v2f16, v2f16]>;
2348def VOP_V2I16_V2I16_V2I16_V2I16 : VOPProfile <[v2i16, v2i16, v2i16, v2i16]>;
2349def VOP_V2I16_F32_F32 : VOPProfile <[v2i16, f32, f32, untyped]>;
2350def VOP_V2I16_I32_I32 : VOPProfile <[v2i16, i32, i32, untyped]>;
2351
2352def VOP_F32_V2F16_V2F16_V2F16 : VOPProfile <[f32, v2f16, v2f16, v2f16]>;
2353
2354def VOP_NONE : VOPProfile <[untyped, untyped, untyped, untyped]>;
2355
2356def VOP_F32_F32 : VOPProfile <[f32, f32, untyped, untyped]>;
2357def VOP_F32_F64 : VOPProfile <[f32, f64, untyped, untyped]>;
2358def VOP_F32_I32 : VOPProfile <[f32, i32, untyped, untyped]>;
2359def VOP_F64_F32 : VOPProfile <[f64, f32, untyped, untyped]>;
2360def VOP_F64_F64 : VOPProfile <[f64, f64, untyped, untyped]>;
2361def VOP_F64_I32 : VOPProfile <[f64, i32, untyped, untyped]>;
2362def VOP_I32_F32 : VOPProfile <[i32, f32, untyped, untyped]>;
2363def VOP_I32_F64 : VOPProfile <[i32, f64, untyped, untyped]>;
2364def VOP_I32_I32 : VOPProfile <[i32, i32, untyped, untyped]>;
2365def VOP_F16_F32 : VOPProfile <[f16, f32, untyped, untyped]>;
2366def VOP_F32_F16 : VOPProfile <[f32, f16, untyped, untyped]>;
2367def VOP_I64_I64 : VOPProfile <[i64, i64, untyped, untyped]>;
2368
2369def VOP_F32_F32_F16 : VOPProfile <[f32, f32, f16, untyped]>;
2370def VOP_F32_F32_F32 : VOPProfile <[f32, f32, f32, untyped]>;
2371def VOP_F32_F32_I32 : VOPProfile <[f32, f32, i32, untyped]>;
2372def VOP_F64_F64_F64 : VOPProfile <[f64, f64, f64, untyped]>;
2373def VOP_F64_F64_I32 : VOPProfile <[f64, f64, i32, untyped]>;
2374def VOP_I32_F32_F32 : VOPProfile <[i32, f32, f32, untyped]>;
2375def VOP_I32_F32_I32 : VOPProfile <[i32, f32, i32, untyped]>;
2376def VOP_I32_I32_I32 : VOPProfile <[i32, i32, i32, untyped]>;
2377def VOP_I32_I32_I32_ARITH : VOPProfile <[i32, i32, i32, untyped], 0, /*EnableClamp=*/1>;
2378def VOP_V2F16_F32_F32 : VOPProfile <[v2f16, f32, f32, untyped]>;
2379def VOP_F32_F16_F16_F16 : VOPProfile <[f32, f16, f16, f16]>;
2380
2381def VOP_I64_I64_I32 : VOPProfile <[i64, i64, i32, untyped]>;
2382def VOP_I64_I32_I64 : VOPProfile <[i64, i32, i64, untyped]>;
2383def VOP_I64_I64_I64 : VOPProfile <[i64, i64, i64, untyped]>;
2384
2385def VOP_F16_F32_F16_F32 : VOPProfile <[f16, f32, f16, f32]>;
2386def VOP_F32_F32_F16_F16 : VOPProfile <[f32, f32, f16, f16]>;
2387def VOP_F32_F32_F32_F32 : VOPProfile <[f32, f32, f32, f32]>;
2388def VOP_F64_F64_F64_F64 : VOPProfile <[f64, f64, f64, f64]>;
2389def VOP_I32_I32_I32_I32 : VOPProfile <[i32, i32, i32, i32]>;
2390def VOP_I64_I32_I32_I64 : VOPProfile <[i64, i32, i32, i64]>;
2391def VOP_I32_F32_I32_I32 : VOPProfile <[i32, f32, i32, i32]>;
2392def VOP_I64_I64_I32_I64 : VOPProfile <[i64, i64, i32, i64]>;
2393def VOP_V4I32_I64_I32_V4I32 : VOPProfile <[v4i32, i64, i32, v4i32]>;
2394
2395def VOP_F32_V2F16_V2F16_F32 : VOPProfile <[f32, v2f16, v2f16, f32]>;
2396def VOP_I32_V2I16_V2I16_I32 : VOPProfile <[i32, v2i16, v2i16, i32]>;
2397
2398def VOP_V4F32_F32_F32_V4F32       : VOPProfile <[v4f32,  f32,   f32,   v4f32]>;
2399def VOP_V16F32_F32_F32_V16F32     : VOPProfile <[v16f32, f32,   f32,   v16f32]>;
2400def VOP_V32F32_F32_F32_V32F32     : VOPProfile <[v32f32, f32,   f32,   v32f32]>;
2401def VOP_V4F32_V4F16_V4F16_V4F32   : VOPProfile <[v4f32,  v4f16, v4f16, v4f32]>;
2402def VOP_V16F32_V4F16_V4F16_V16F32 : VOPProfile <[v16f32, v4f16, v4f16, v16f32]>;
2403def VOP_V32F32_V4F16_V4F16_V32F32 : VOPProfile <[v32f32, v4f16, v4f16, v32f32]>;
2404def VOP_V4F32_V2I16_V2I16_V4F32   : VOPProfile <[v4f32,  v2i16, v2i16, v4f32]>;
2405def VOP_V16F32_V2I16_V2I16_V16F32 : VOPProfile <[v16f32, v2i16, v2i16, v16f32]>;
2406def VOP_V32F32_V2I16_V2I16_V32F32 : VOPProfile <[v32f32, v2i16, v2i16, v32f32]>;
2407def VOP_V4I32_I32_I32_V4I32       : VOPProfile <[v4i32,  i32,   i32,   v4i32]>;
2408def VOP_V16I32_I32_I32_V16I32     : VOPProfile <[v16i32, i32,   i32,   v16i32]>;
2409def VOP_V32I32_I32_I32_V32I32     : VOPProfile <[v32i32, i32,   i32,   v32i32]>;
2410
2411def VOP_V4F64_F64_F64_V4F64 : VOPProfile <[v4f64, f64, f64, v4f64]>;
2412def VOP_V1F64_F64_F64_V1F64 : VOPProfile <[v1f64, f64, f64, v1f64]>;
2413
2414def VOP_V2F32_V2F32_V2F32_V2F32   : VOPProfile <[v2f32,  v2f32, v2f32, v2f32]>;
2415def VOP_V2F32_V2F32_V2F32         : VOPProfile <[v2f32,  v2f32, v2f32, untyped]>;
2416def VOP_V2I32_V2I32_V2I32         : VOPProfile <[v2i32,  v2i32, v2i32, untyped]>;
2417def VOP_V4F32_V4I16_V4I16_V4F32   : VOPProfile <[v4f32,  v4i16, v4i16, v4f32]>;
2418def VOP_V16F32_V4I16_V4I16_V16F32 : VOPProfile <[v16f32, v4i16, v4i16, v16f32]>;
2419def VOP_V32F32_V4I16_V4I16_V32F32 : VOPProfile <[v32f32, v4i16, v4i16, v32f32]>;
2420
2421def VOP_V4I32_I64_I64_V4I32       : VOPProfile <[v4i32,  i64,   i64,   v4i32]>;
2422def VOP_V16I32_I64_I64_V16I32     : VOPProfile <[v16i32, i64,   i64,   v16i32]>;
2423def VOP_V4F32_V2F32_V2F32_V4F32   : VOPProfile <[v4f32,  v2f32, v2f32, v4f32]>;
2424def VOP_V16F32_V2F32_V2F32_V16F32 : VOPProfile <[v16f32, v2f32, v2f32, v16f32]>;
2425
2426def VOP_V4F32_V4F16_V8F16_I32     : VOPProfile <[v4f32,  v4f16, v8f16, i32]>;
2427def VOP_V16F32_V4F16_V8F16_I32    : VOPProfile <[v16f32, v4f16, v8f16, i32]>;
2428def VOP_V4F32_V4I16_V8I16_I32     : VOPProfile <[v4f32,  v4i16, v8i16, i32]>;
2429def VOP_V16F32_V4I16_V8I16_I32    : VOPProfile <[v16f32, v4i16, v8i16, i32]>;
2430def VOP_V4I32_V2I32_V4I32_I32     : VOPProfile <[v4i32,  v2i32, v4i32, i32]>;
2431def VOP_V16I32_V2I32_V4I32_I32    : VOPProfile <[v16i32, v2i32, v4i32, i32]>;
2432
2433class Commutable_REV <string revOp, bit isOrig> {
2434  string RevOp = revOp;
2435  bit IsOrig = isOrig;
2436}
2437
2438class AtomicNoRet <string noRetOp, bit isRet> {
2439  string NoRetOp = noRetOp;
2440  bit IsRet = isRet;
2441}
2442
2443//===----------------------------------------------------------------------===//
2444// Interpolation opcodes
2445//===----------------------------------------------------------------------===//
2446
2447class VINTRPDstOperand <RegisterClass rc> : RegisterOperand <rc, "printVINTRPDst">;
2448
2449class VINTRP_Pseudo <string opName, dag outs, dag ins, list<dag> pattern> :
2450  VINTRPCommon <outs, ins, "", pattern>,
2451  SIMCInstr<opName, SIEncodingFamily.NONE> {
2452  let isPseudo = 1;
2453  let isCodeGenOnly = 1;
2454}
2455
2456// FIXME-GFX10: WIP.
2457class VINTRP_Real_si <bits <2> op, string opName, dag outs, dag ins,
2458                      string asm, int encodingFamily> :
2459  VINTRPCommon <outs, ins, asm, []>,
2460  VINTRPe <op>,
2461  SIMCInstr<opName, encodingFamily> {
2462}
2463
2464class VINTRP_Real_vi <bits <2> op, string opName, dag outs, dag ins,
2465                      string asm> :
2466  VINTRPCommon <outs, ins, asm, []>,
2467  VINTRPe_vi <op>,
2468  SIMCInstr<opName, SIEncodingFamily.VI> {
2469  let AssemblerPredicate = VIAssemblerPredicate;
2470  let DecoderNamespace = "GFX8";
2471}
2472
2473// FIXME-GFX10: WIP.
2474multiclass VINTRP_m <bits <2> op, dag outs, dag ins, string asm,
2475                     list<dag> pattern = []> {
2476  def "" : VINTRP_Pseudo <NAME, outs, ins, pattern>;
2477
2478  let AssemblerPredicate = isGFX6GFX7, DecoderNamespace = "GFX6GFX7" in {
2479    def _si : VINTRP_Real_si <op, NAME, outs, ins, asm, SIEncodingFamily.SI>;
2480  } // End AssemblerPredicate = isGFX6GFX7, DecoderNamespace = "GFX6GFX7"
2481
2482  def _vi : VINTRP_Real_vi <op, NAME, outs, ins, asm>;
2483
2484  let AssemblerPredicate = isGFX10Plus, DecoderNamespace = "GFX10" in {
2485    def _gfx10 : VINTRP_Real_si<op, NAME, outs, ins, asm, SIEncodingFamily.GFX10>;
2486  } // End AssemblerPredicate = isGFX10Plus, DecoderNamespace = "GFX10"
2487}
2488//===----------------------------------------------------------------------===//
2489// Vector instruction mappings
2490//===----------------------------------------------------------------------===//
2491
2492// Maps an opcode in e32 form to its e64 equivalent
2493def getVOPe64 : InstrMapping {
2494  let FilterClass = "VOP";
2495  let RowFields = ["OpName"];
2496  let ColFields = ["Size", "VOP3"];
2497  let KeyCol = ["4", "0"];
2498  let ValueCols = [["8", "1"]];
2499}
2500
2501// Maps an opcode in e64 form to its e32 equivalent
2502def getVOPe32 : InstrMapping {
2503  let FilterClass = "VOP";
2504  let RowFields = ["OpName"];
2505  let ColFields = ["Size", "VOP3"];
2506  let KeyCol = ["8", "1"];
2507  let ValueCols = [["4", "0"]];
2508}
2509
2510// Maps ordinary instructions to their SDWA counterparts
2511def getSDWAOp : InstrMapping {
2512  let FilterClass = "VOP";
2513  let RowFields = ["OpName"];
2514  let ColFields = ["AsmVariantName"];
2515  let KeyCol = ["Default"];
2516  let ValueCols = [["SDWA"]];
2517}
2518
2519// Maps SDWA instructions to their ordinary counterparts
2520def getBasicFromSDWAOp : InstrMapping {
2521  let FilterClass = "VOP";
2522  let RowFields = ["OpName"];
2523  let ColFields = ["AsmVariantName"];
2524  let KeyCol = ["SDWA"];
2525  let ValueCols = [["Default"]];
2526}
2527
2528// Maps ordinary instructions to their DPP counterparts
2529def getDPPOp32 : InstrMapping {
2530  let FilterClass = "VOP";
2531  let RowFields = ["OpName"];
2532  let ColFields = ["AsmVariantName"];
2533  let KeyCol = ["Default"];
2534  let ValueCols = [["DPP"]];
2535}
2536
2537// Maps an commuted opcode to its original version
2538def getCommuteOrig : InstrMapping {
2539  let FilterClass = "Commutable_REV";
2540  let RowFields = ["RevOp"];
2541  let ColFields = ["IsOrig"];
2542  let KeyCol = ["0"];
2543  let ValueCols = [["1"]];
2544}
2545
2546// Maps an original opcode to its commuted version
2547def getCommuteRev : InstrMapping {
2548  let FilterClass = "Commutable_REV";
2549  let RowFields = ["RevOp"];
2550  let ColFields = ["IsOrig"];
2551  let KeyCol = ["1"];
2552  let ValueCols = [["0"]];
2553}
2554
2555def getMCOpcodeGen : InstrMapping {
2556  let FilterClass = "SIMCInstr";
2557  let RowFields = ["PseudoInstr"];
2558  let ColFields = ["Subtarget"];
2559  let KeyCol = [!cast<string>(SIEncodingFamily.NONE)];
2560  let ValueCols = [[!cast<string>(SIEncodingFamily.SI)],
2561                   [!cast<string>(SIEncodingFamily.VI)],
2562                   [!cast<string>(SIEncodingFamily.SDWA)],
2563                   [!cast<string>(SIEncodingFamily.SDWA9)],
2564                   // GFX80 encoding is added to work around a multiple matching
2565                   // issue for buffer instructions with unpacked d16 data. This
2566                   // does not actually change the encoding, and thus may be
2567                   // removed later.
2568                   [!cast<string>(SIEncodingFamily.GFX80)],
2569                   [!cast<string>(SIEncodingFamily.GFX9)],
2570                   [!cast<string>(SIEncodingFamily.GFX10)],
2571                   [!cast<string>(SIEncodingFamily.SDWA10)],
2572                   [!cast<string>(SIEncodingFamily.GFX90A)],
2573                   [!cast<string>(SIEncodingFamily.GFX940)]];
2574}
2575
2576// Get equivalent SOPK instruction.
2577def getSOPKOp : InstrMapping {
2578  let FilterClass = "SOPKInstTable";
2579  let RowFields = ["BaseCmpOp"];
2580  let ColFields = ["IsSOPK"];
2581  let KeyCol = ["0"];
2582  let ValueCols = [["1"]];
2583}
2584
2585def getAddr64Inst : InstrMapping {
2586  let FilterClass = "MUBUFAddr64Table";
2587  let RowFields = ["OpName"];
2588  let ColFields = ["IsAddr64"];
2589  let KeyCol = ["0"];
2590  let ValueCols = [["1"]];
2591}
2592
2593def getIfAddr64Inst : InstrMapping {
2594  let FilterClass = "MUBUFAddr64Table";
2595  let RowFields = ["OpName"];
2596  let ColFields = ["IsAddr64"];
2597  let KeyCol = ["1"];
2598  let ValueCols = [["1"]];
2599}
2600
2601def getMUBUFNoLdsInst : InstrMapping {
2602  let FilterClass = "MUBUFLdsTable";
2603  let RowFields = ["OpName"];
2604  let ColFields = ["IsLds"];
2605  let KeyCol = ["1"];
2606  let ValueCols = [["0"]];
2607}
2608
2609// Maps an atomic opcode to its returnless version.
2610def getAtomicNoRetOp : InstrMapping {
2611  let FilterClass = "AtomicNoRet";
2612  let RowFields = ["NoRetOp"];
2613  let ColFields = ["IsRet"];
2614  let KeyCol = ["1"];
2615  let ValueCols = [["0"]];
2616}
2617
2618// Maps a GLOBAL to its SADDR form.
2619def getGlobalSaddrOp : InstrMapping {
2620  let FilterClass = "GlobalSaddrTable";
2621  let RowFields = ["SaddrOp"];
2622  let ColFields = ["IsSaddr"];
2623  let KeyCol = ["0"];
2624  let ValueCols = [["1"]];
2625}
2626
2627// Maps a GLOBAL SADDR to its VADDR form.
2628def getGlobalVaddrOp : InstrMapping {
2629  let FilterClass = "GlobalSaddrTable";
2630  let RowFields = ["SaddrOp"];
2631  let ColFields = ["IsSaddr"];
2632  let KeyCol = ["1"];
2633  let ValueCols = [["0"]];
2634}
2635
2636// Maps a v_cmpx opcode with sdst to opcode without sdst.
2637def getVCMPXNoSDstOp : InstrMapping {
2638  let FilterClass = "VCMPXNoSDstTable";
2639  let RowFields = ["NoSDstOp"];
2640  let ColFields = ["HasSDst"];
2641  let KeyCol = ["1"];
2642  let ValueCols = [["0"]];
2643}
2644
2645// Maps a SOPP to a SOPP with S_NOP
2646def getSOPPWithRelaxation : InstrMapping {
2647  let FilterClass = "SOPPRelaxTable";
2648  let RowFields = ["KeyName"];
2649  let ColFields = ["IsRelaxed"];
2650  let KeyCol = ["0"];
2651  let ValueCols = [["1"]];
2652}
2653
2654// Maps flat scratch opcodes by addressing modes
2655def getFlatScratchInstSTfromSS : InstrMapping {
2656  let FilterClass = "FlatScratchInst";
2657  let RowFields = ["SVOp"];
2658  let ColFields = ["Mode"];
2659  let KeyCol = ["SS"];
2660  let ValueCols = [["ST"]];
2661}
2662
2663def getFlatScratchInstSSfromSV : InstrMapping {
2664  let FilterClass = "FlatScratchInst";
2665  let RowFields = ["SVOp"];
2666  let ColFields = ["Mode"];
2667  let KeyCol = ["SV"];
2668  let ValueCols = [["SS"]];
2669}
2670
2671def getFlatScratchInstSVfromSVS : InstrMapping {
2672  let FilterClass = "FlatScratchInst";
2673  let RowFields = ["SVOp"];
2674  let ColFields = ["Mode"];
2675  let KeyCol = ["SVS"];
2676  let ValueCols = [["SV"]];
2677}
2678
2679def getFlatScratchInstSVfromSS : InstrMapping {
2680  let FilterClass = "FlatScratchInst";
2681  let RowFields = ["SVOp"];
2682  let ColFields = ["Mode"];
2683  let KeyCol = ["SS"];
2684  let ValueCols = [["SV"]];
2685}
2686
2687def getMFMAEarlyClobberOp : InstrMapping {
2688  let FilterClass = "MFMATable";
2689  let RowFields = ["FMAOp"];
2690  let ColFields = ["IsMac"];
2691  let KeyCol = ["1"];
2692  let ValueCols = [["0"]];
2693}
2694
2695// Maps an v_cmp instruction to its v_cmpx equivalent.
2696def getVCMPXOpFromVCMP : InstrMapping {
2697  let FilterClass = "VCMPVCMPXTable";
2698  let RowFields = ["VCMPOp"];
2699  let ColFields = ["IsVCMPX"];
2700  let KeyCol = ["0"];
2701  let ValueCols = [["1"]];
2702}
2703
2704include "SIInstructions.td"
2705
2706include "DSInstructions.td"
2707include "MIMGInstructions.td"
2708