1# Adds version control information to the variable VERS. For
2# determining the Version Control System used (if any) it inspects the
3# existence of certain subdirectories under CMAKE_CURRENT_SOURCE_DIR.
4
5function(add_version_info_from_vcs VERS)
6  string(REPLACE "svn" "" result "${${VERS}}")
7  if( EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/.svn" )
8    set(result "${result}svn")
9    # FindSubversion does not work with symlinks. See PR 8437
10    if( NOT IS_SYMLINK "${CMAKE_CURRENT_SOURCE_DIR}" )
11      find_package(Subversion)
12    endif()
13    if( Subversion_FOUND )
14      subversion_wc_info( ${CMAKE_CURRENT_SOURCE_DIR} Project )
15      if( Project_WC_REVISION )
16        set(SVN_REVISION ${Project_WC_REVISION} PARENT_SCOPE)
17        set(result "${result}-r${Project_WC_REVISION}")
18      endif()
19      if( Project_WC_URL )
20        set(LLVM_REPOSITORY ${Project_WC_URL} PARENT_SCOPE)
21      endif()
22    endif()
23  elseif( EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/.git )
24    set(result "${result}git")
25    # Try to get a ref-id
26    if( EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/.git/svn )
27      find_program(git_executable NAMES git git.exe git.cmd)
28      if( git_executable )
29        set(is_git_svn_rev_exact false)
30        execute_process(COMMAND
31          ${git_executable} svn info
32          WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
33          TIMEOUT 5
34          RESULT_VARIABLE git_result
35          OUTPUT_VARIABLE git_output)
36        if( git_result EQUAL 0 )
37          string(REGEX MATCH "URL: ([^ \n]*)" svn_url ${git_output})
38          if(svn_url)
39            set(LLVM_REPOSITORY ${CMAKE_MATCH_1} PARENT_SCOPE)
40          endif()
41
42          string(REGEX REPLACE "^(.*\n)?Revision: ([^\n]+).*"
43            "\\2" git_svn_rev_number "${git_output}")
44          set(SVN_REVISION ${git_svn_rev_number} PARENT_SCOPE)
45          set(git_svn_rev "-svn-${git_svn_rev}")
46
47          # Determine if the HEAD points directly at a subversion revision.
48          execute_process(COMMAND ${git_executable} svn find-rev HEAD
49            WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
50            TIMEOUT 5
51            RESULT_VARIABLE git_result
52            OUTPUT_VARIABLE git_output)
53          if( git_result EQUAL 0 )
54            string(STRIP "${git_output}" git_head_svn_rev_number)
55            if( git_head_svn_rev_number EQUAL git_svn_rev_number )
56              set(is_git_svn_rev_exact true)
57            endif()
58          endif()
59        else()
60          set(git_svn_rev "")
61        endif()
62        execute_process(COMMAND
63          ${git_executable} rev-parse --short HEAD
64          WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
65          TIMEOUT 5
66          RESULT_VARIABLE git_result
67          OUTPUT_VARIABLE git_output)
68        if( git_result EQUAL 0 AND NOT is_git_svn_rev_exact )
69          string(STRIP "${git_output}" git_ref_id)
70          set(GIT_COMMIT ${git_ref_id} PARENT_SCOPE)
71          set(result "${result}${git_svn_rev}-${git_ref_id}")
72        else()
73          set(result "${result}${git_svn_rev}")
74        endif()
75
76      endif()
77    endif()
78  endif()
79  set(${VERS} ${result} PARENT_SCOPE)
80endfunction(add_version_info_from_vcs)
81