1# LLVM_TARGET_DEFINITIONS must contain the name of the .td file to process.
2# Extra parameters for `tblgen' may come after `ofn' parameter.
3# Adds the name of the generated file to TABLEGEN_OUTPUT.
4
5include(LLVMExternalProjectUtils)
6
7if(LLVM_MAIN_INCLUDE_DIR)
8  set(LLVM_TABLEGEN_FLAGS -I ${LLVM_MAIN_INCLUDE_DIR})
9endif()
10
11function(tablegen project ofn)
12  # Validate calling context.
13  if(NOT ${project}_TABLEGEN_EXE)
14    message(FATAL_ERROR "${project}_TABLEGEN_EXE not set")
15  endif()
16
17  file(GLOB local_tds "*.td")
18  file(GLOB_RECURSE global_tds "${LLVM_MAIN_INCLUDE_DIR}/llvm/*.td")
19
20  if (IS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
21    set(LLVM_TARGET_DEFINITIONS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
22  else()
23    set(LLVM_TARGET_DEFINITIONS_ABSOLUTE
24      ${CMAKE_CURRENT_SOURCE_DIR}/${LLVM_TARGET_DEFINITIONS})
25  endif()
26  add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
27    # Generate tablegen output in a temporary file.
28    COMMAND ${${project}_TABLEGEN_EXE} ${ARGN} -I ${CMAKE_CURRENT_SOURCE_DIR}
29    ${LLVM_TABLEGEN_FLAGS}
30    ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
31    -o ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
32    # The file in LLVM_TARGET_DEFINITIONS may be not in the current
33    # directory and local_tds may not contain it, so we must
34    # explicitly list it here:
35    DEPENDS ${${project}_TABLEGEN_TARGET} ${local_tds} ${global_tds}
36    ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
37    COMMENT "Building ${ofn}..."
38    )
39  add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
40    # Only update the real output file if there are any differences.
41    # This prevents recompilation of all the files depending on it if there
42    # aren't any.
43    COMMAND ${CMAKE_COMMAND} -E copy_if_different
44        ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
45        ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
46    DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
47    COMMENT "Updating ${ofn}..."
48    )
49
50  # `make clean' must remove all those generated files:
51  set_property(DIRECTORY APPEND
52    PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${ofn}.tmp ${ofn})
53
54  set(TABLEGEN_OUTPUT ${TABLEGEN_OUTPUT} ${CMAKE_CURRENT_BINARY_DIR}/${ofn} PARENT_SCOPE)
55  set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/${ofn} PROPERTIES
56    GENERATED 1)
57endfunction()
58
59# Creates a target for publicly exporting tablegen dependencies.
60function(add_public_tablegen_target target)
61  if(NOT TABLEGEN_OUTPUT)
62    message(FATAL_ERROR "Requires tablegen() definitions as TABLEGEN_OUTPUT.")
63  endif()
64  add_custom_target(${target}
65    DEPENDS ${TABLEGEN_OUTPUT})
66  if(LLVM_COMMON_DEPENDS)
67    add_dependencies(${target} ${LLVM_COMMON_DEPENDS})
68  endif()
69  set_target_properties(${target} PROPERTIES FOLDER "Tablegenning")
70  set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${target} PARENT_SCOPE)
71endfunction()
72
73if(LLVM_USE_HOST_TOOLS)
74  llvm_ExternalProject_BuildCmd(tblgen_build_cmd LLVMSupport
75    ${LLVM_NATIVE_BUILD}
76    CONFIGURATION Release)
77  add_custom_command(OUTPUT LIB_LLVMTABLEGEN
78      COMMAND ${tblgen_build_cmd}
79      DEPENDS CONFIGURE_LLVM_NATIVE
80      WORKING_DIRECTORY ${LLVM_NATIVE_BUILD}
81      COMMENT "Building libLLVMTableGen for native TableGen..."
82      USES_TERMINAL)
83  add_custom_target(NATIVE_LIB_LLVMTABLEGEN DEPENDS LIB_LLVMTABLEGEN)
84endif(LLVM_USE_HOST_TOOLS)
85
86macro(add_tablegen target project)
87  set(${target}_OLD_LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS})
88  set(LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS} TableGen)
89
90  if(NOT XCODE)
91    # FIXME: It leaks to user, callee of add_tablegen.
92    set(LLVM_ENABLE_OBJLIB ON)
93  endif()
94
95  add_llvm_utility(${target} ${ARGN})
96  set(LLVM_LINK_COMPONENTS ${${target}_OLD_LLVM_LINK_COMPONENTS})
97
98  set(${project}_TABLEGEN "${target}" CACHE
99      STRING "Native TableGen executable. Saves building one when cross-compiling.")
100
101  # Upgrade existing LLVM_TABLEGEN setting.
102  if(${project} STREQUAL LLVM)
103    if(${LLVM_TABLEGEN} STREQUAL tblgen)
104      set(LLVM_TABLEGEN "${target}" CACHE
105          STRING "Native TableGen executable. Saves building one when cross-compiling."
106          FORCE)
107    endif()
108  endif()
109
110  # Effective tblgen executable to be used:
111  set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN} PARENT_SCOPE)
112  set(${project}_TABLEGEN_TARGET ${${project}_TABLEGEN} PARENT_SCOPE)
113
114  if(LLVM_USE_HOST_TOOLS)
115    if( ${${project}_TABLEGEN} STREQUAL "${target}" )
116      if (NOT CMAKE_CONFIGURATION_TYPES)
117        set(${project}_TABLEGEN_EXE "${LLVM_NATIVE_BUILD}/bin/${target}")
118      else()
119        set(${project}_TABLEGEN_EXE "${LLVM_NATIVE_BUILD}/Release/bin/${target}")
120      endif()
121      set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN_EXE} PARENT_SCOPE)
122
123      llvm_ExternalProject_BuildCmd(tblgen_build_cmd ${target}
124                                    ${LLVM_NATIVE_BUILD}
125                                    CONFIGURATION Release)
126      add_custom_command(OUTPUT ${${project}_TABLEGEN_EXE}
127        COMMAND ${tblgen_build_cmd}
128        DEPENDS ${target} NATIVE_LIB_LLVMTABLEGEN
129        WORKING_DIRECTORY ${LLVM_NATIVE_BUILD}
130        COMMENT "Building native TableGen..."
131        USES_TERMINAL)
132      add_custom_target(${project}-tablegen-host DEPENDS ${${project}_TABLEGEN_EXE})
133      set(${project}_TABLEGEN_TARGET ${project}-tablegen-host PARENT_SCOPE)
134    endif()
135  endif()
136
137  if (${project} STREQUAL LLVM AND NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
138    if(${target} IN_LIST LLVM_DISTRIBUTION_COMPONENTS OR
139        NOT LLVM_DISTRIBUTION_COMPONENTS)
140      set(export_to_llvmexports EXPORT LLVMExports)
141    endif()
142
143    install(TARGETS ${target}
144            ${export_to_llvmexports}
145            RUNTIME DESTINATION ${LLVM_TOOLS_INSTALL_DIR})
146  endif()
147  set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${target})
148endmacro()
149