1include(ExternalProject)
2
3# llvm_ExternalProject_BuildCmd(out_var target)
4#   Utility function for constructing command lines for external project targets
5function(llvm_ExternalProject_BuildCmd out_var target bin_dir)
6  cmake_parse_arguments(ARG "" "CONFIGURATION" "" ${ARGN})
7  if(NOT ARG_CONFIGURATION)
8    set(ARG_CONFIGURATION "$<CONFIG>")
9  endif()
10  if (CMAKE_GENERATOR MATCHES "Make")
11    # Use special command for Makefiles to support parallelism.
12    set(${out_var} "$(MAKE)" "-C" "${bin_dir}" "${target}" PARENT_SCOPE)
13  else()
14    set(${out_var} ${CMAKE_COMMAND} --build ${bin_dir} --target ${target}
15                                    --config ${ARG_CONFIGURATION} PARENT_SCOPE)
16  endif()
17endfunction()
18
19# llvm_ExternalProject_Add(name source_dir ...
20#   USE_TOOLCHAIN
21#     Use just-built tools (see TOOLCHAIN_TOOLS)
22#   EXCLUDE_FROM_ALL
23#     Exclude this project from the all target
24#   NO_INSTALL
25#     Don't generate install targets for this project
26#   ALWAYS_CLEAN
27#     Always clean the sub-project before building
28#   CMAKE_ARGS arguments...
29#     Optional cmake arguments to pass when configuring the project
30#   TOOLCHAIN_TOOLS targets...
31#     Targets for toolchain tools (defaults to clang;lld)
32#   DEPENDS targets...
33#     Targets that this project depends on
34#   EXTRA_TARGETS targets...
35#     Extra targets in the subproject to generate targets for
36#   PASSTHROUGH_PREFIXES prefix...
37#     Extra variable prefixes (name is always included) to pass down
38#   STRIP_TOOL path
39#     Use provided strip tool instead of the default one.
40#   )
41function(llvm_ExternalProject_Add name source_dir)
42  cmake_parse_arguments(ARG
43    "USE_TOOLCHAIN;EXCLUDE_FROM_ALL;NO_INSTALL;ALWAYS_CLEAN"
44    "SOURCE_DIR"
45    "CMAKE_ARGS;TOOLCHAIN_TOOLS;RUNTIME_LIBRARIES;DEPENDS;EXTRA_TARGETS;PASSTHROUGH_PREFIXES;STRIP_TOOL"
46    ${ARGN})
47  canonicalize_tool_name(${name} nameCanon)
48
49  foreach(arg ${ARG_CMAKE_ARGS})
50    if(arg MATCHES "^-DCMAKE_SYSTEM_NAME=")
51      string(REGEX REPLACE "^-DCMAKE_SYSTEM_NAME=(.*)$" "\\1" _cmake_system_name "${arg}")
52    endif()
53  endforeach()
54
55  # If CMAKE_SYSTEM_NAME is not set explicitly in the arguments passed to us,
56  # reflect CMake's own default.
57  if (NOT _cmake_system_name)
58    set(_cmake_system_name "${CMAKE_HOST_SYSTEM_NAME}")
59  endif()
60
61  if(NOT ARG_TOOLCHAIN_TOOLS)
62    set(ARG_TOOLCHAIN_TOOLS clang lld llvm-ar llvm-ranlib llvm-nm llvm-objdump)
63    if(_cmake_system_name STREQUAL Darwin)
64      list(APPEND ARG_TOOLCHAIN_TOOLS llvm-libtool-darwin llvm-lipo)
65    elseif(_cmake_system_name STREQUAL Windows)
66      list(APPEND ARG_TOOLCHAIN_TOOLS llvm-lib)
67    else()
68      # TODO: These tools don't fully support Mach-O format yet.
69      list(APPEND ARG_TOOLCHAIN_TOOLS llvm-objcopy llvm-strip)
70    endif()
71  endif()
72  foreach(tool ${ARG_TOOLCHAIN_TOOLS})
73    if(TARGET ${tool})
74      list(APPEND TOOLCHAIN_TOOLS ${tool})
75
76      # $<TARGET_FILE:tgt> only works on add_executable or add_library targets
77      # The below logic mirrors cmake's own implementation
78      get_target_property(target_type "${tool}" TYPE)
79      if(NOT target_type STREQUAL "OBJECT_LIBRARY" AND
80         NOT target_type STREQUAL "UTILITY" AND
81         NOT target_type STREQUAL "GLOBAL_TARGET" AND
82         NOT target_type STREQUAL "INTERFACE_LIBRARY")
83        list(APPEND TOOLCHAIN_BINS $<TARGET_FILE:${tool}>)
84      endif()
85
86    endif()
87  endforeach()
88
89  if(NOT ARG_RUNTIME_LIBRARIES)
90    set(ARG_RUNTIME_LIBRARIES compiler-rt libcxx)
91  endif()
92  foreach(lib ${ARG_RUNTIME_LIBRARIES})
93    if(TARGET ${lib})
94      list(APPEND RUNTIME_LIBRARIES ${lib})
95    endif()
96  endforeach()
97
98  if(ARG_ALWAYS_CLEAN)
99    set(always_clean clean)
100  endif()
101
102  list(FIND TOOLCHAIN_TOOLS clang FOUND_CLANG)
103  if(FOUND_CLANG GREATER -1)
104    set(CLANG_IN_TOOLCHAIN On)
105  endif()
106
107  if(RUNTIME_LIBRARIES AND CLANG_IN_TOOLCHAIN)
108    list(APPEND TOOLCHAIN_BINS ${RUNTIME_LIBRARIES})
109  endif()
110
111  set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/${name}-stamps/)
112  set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/${name}-bins/)
113
114  add_custom_target(${name}-clear
115    COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
116    COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
117    COMMENT "Clobbering ${name} build and stamp directories"
118    USES_TERMINAL
119    )
120
121  # Find all variables that start with a prefix and propagate them through
122  get_cmake_property(variableNames VARIABLES)
123
124  list(APPEND ARG_PASSTHROUGH_PREFIXES ${nameCanon})
125  foreach(prefix ${ARG_PASSTHROUGH_PREFIXES})
126    foreach(variableName ${variableNames})
127      if(variableName MATCHES "^${prefix}")
128        string(REPLACE ";" "|" value "${${variableName}}")
129        list(APPEND PASSTHROUGH_VARIABLES
130          -D${variableName}=${value})
131      endif()
132    endforeach()
133  endforeach()
134
135  if(ARG_USE_TOOLCHAIN AND NOT CMAKE_CROSSCOMPILING)
136    if(CLANG_IN_TOOLCHAIN)
137      if(_cmake_system_name STREQUAL Windows)
138        set(compiler_args -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang-cl${CMAKE_EXECUTABLE_SUFFIX}
139                          -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang-cl${CMAKE_EXECUTABLE_SUFFIX}
140                          -DCMAKE_ASM_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang-cl${CMAKE_EXECUTABLE_SUFFIX})
141      else()
142        set(compiler_args -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang${CMAKE_EXECUTABLE_SUFFIX}
143                          -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang++${CMAKE_EXECUTABLE_SUFFIX}
144                          -DCMAKE_ASM_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang${CMAKE_EXECUTABLE_SUFFIX})
145      endif()
146    endif()
147    if(lld IN_LIST TOOLCHAIN_TOOLS)
148      if(_cmake_system_name STREQUAL Windows)
149        list(APPEND compiler_args -DCMAKE_LINKER=${LLVM_RUNTIME_OUTPUT_INTDIR}/lld-link${CMAKE_EXECUTABLE_SUFFIX})
150      elseif(NOT _cmake_system_name STREQUAL Darwin)
151        list(APPEND compiler_args -DCMAKE_LINKER=${LLVM_RUNTIME_OUTPUT_INTDIR}/ld.lld${CMAKE_EXECUTABLE_SUFFIX})
152      endif()
153    endif()
154    if(llvm-ar IN_LIST TOOLCHAIN_TOOLS)
155      if(_cmake_system_name STREQUAL Windows)
156        list(APPEND compiler_args -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-lib${CMAKE_EXECUTABLE_SUFFIX})
157      else()
158        list(APPEND compiler_args -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar${CMAKE_EXECUTABLE_SUFFIX})
159      endif()
160    endif()
161    if(llvm-libtool-darwin IN_LIST TOOLCHAIN_TOOLS)
162      list(APPEND compiler_args -DCMAKE_LIBTOOL=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-libtool-darwin${CMAKE_EXECUTABLE_SUFFIX})
163    endif()
164    if(llvm-lipo IN_LIST TOOLCHAIN_TOOLS)
165      list(APPEND compiler_args -DCMAKE_LIPO=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-lipo${CMAKE_EXECUTABLE_SUFFIX})
166    endif()
167    if(llvm-ranlib IN_LIST TOOLCHAIN_TOOLS)
168      list(APPEND compiler_args -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib${CMAKE_EXECUTABLE_SUFFIX})
169    endif()
170    if(llvm-nm IN_LIST TOOLCHAIN_TOOLS)
171      list(APPEND compiler_args -DCMAKE_NM=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-nm${CMAKE_EXECUTABLE_SUFFIX})
172    endif()
173    if(llvm-objdump IN_LIST TOOLCHAIN_TOOLS)
174      list(APPEND compiler_args -DCMAKE_OBJDUMP=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-objdump${CMAKE_EXECUTABLE_SUFFIX})
175    endif()
176    if(llvm-objcopy IN_LIST TOOLCHAIN_TOOLS)
177      list(APPEND compiler_args -DCMAKE_OBJCOPY=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-objcopy${CMAKE_EXECUTABLE_SUFFIX})
178    endif()
179    if(llvm-strip IN_LIST TOOLCHAIN_TOOLS AND NOT ARG_STRIP_TOOL)
180      list(APPEND compiler_args -DCMAKE_STRIP=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-strip${CMAKE_EXECUTABLE_SUFFIX})
181    endif()
182    list(APPEND ARG_DEPENDS ${TOOLCHAIN_TOOLS})
183  endif()
184
185  if(ARG_STRIP_TOOL)
186    list(APPEND compiler_args -DCMAKE_STRIP=${ARG_STRIP_TOOL})
187  endif()
188
189  add_custom_command(
190    OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${name}-clobber-stamp
191    DEPENDS ${ARG_DEPENDS}
192    COMMAND ${CMAKE_COMMAND} -E touch ${BINARY_DIR}/CMakeCache.txt
193    COMMAND ${CMAKE_COMMAND} -E touch ${STAMP_DIR}/${name}-mkdir
194    COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/${name}-clobber-stamp
195    COMMENT "Clobbering bootstrap build and stamp directories"
196    )
197
198  add_custom_target(${name}-clobber
199    DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${name}-clobber-stamp)
200
201  if(ARG_EXCLUDE_FROM_ALL)
202    set(exclude EXCLUDE_FROM_ALL 1)
203  endif()
204
205  if(CMAKE_SYSROOT)
206    set(sysroot_arg -DCMAKE_SYSROOT=${CMAKE_SYSROOT})
207  endif()
208
209  if(CMAKE_CROSSCOMPILING)
210    set(compiler_args -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
211                      -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
212                      -DCMAKE_LINKER=${CMAKE_LINKER}
213                      -DCMAKE_AR=${CMAKE_AR}
214                      -DCMAKE_RANLIB=${CMAKE_RANLIB}
215                      -DCMAKE_NM=${CMAKE_NM}
216                      -DCMAKE_OBJCOPY=${CMAKE_OBJCOPY}
217                      -DCMAKE_OBJDUMP=${CMAKE_OBJDUMP}
218                      -DCMAKE_STRIP=${CMAKE_STRIP})
219    set(llvm_config_path ${LLVM_CONFIG_PATH})
220
221    if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
222      string(REGEX MATCH "[0-9]+\\.[0-9]+(\\.[0-9]+)?" CLANG_VERSION
223             ${PACKAGE_VERSION})
224      set(resource_dir "${LLVM_LIBRARY_DIR}/clang/${CLANG_VERSION}")
225      set(flag_types ASM C CXX MODULE_LINKER SHARED_LINKER EXE_LINKER)
226      foreach(type ${flag_types})
227        set(${type}_flag -DCMAKE_${type}_FLAGS=-resource-dir=${resource_dir})
228      endforeach()
229      string(REPLACE ";" "|" flag_string "${flag_types}")
230      foreach(arg ${ARG_CMAKE_ARGS})
231        if(arg MATCHES "^-DCMAKE_(${flag_string})_FLAGS")
232          foreach(type ${flag_types})
233            if(arg MATCHES "^-DCMAKE_${type}_FLAGS")
234              string(REGEX REPLACE "^-DCMAKE_${type}_FLAGS=(.*)$" "\\1" flag_value "${arg}")
235              set(${type}_flag "${${type}_flag} ${flag_value}")
236            endif()
237          endforeach()
238        else()
239          list(APPEND cmake_args ${arg})
240        endif()
241      endforeach()
242      foreach(type ${flag_types})
243        list(APPEND cmake_args ${${type}_flag})
244      endforeach()
245    endif()
246  else()
247    set(llvm_config_path "$<TARGET_FILE:llvm-config>")
248    set(cmake_args ${ARG_CMAKE_ARGS})
249  endif()
250
251  ExternalProject_Add(${name}
252    DEPENDS ${ARG_DEPENDS} llvm-config
253    ${name}-clobber
254    PREFIX ${CMAKE_BINARY_DIR}/projects/${name}
255    SOURCE_DIR ${source_dir}
256    STAMP_DIR ${STAMP_DIR}
257    BINARY_DIR ${BINARY_DIR}
258    ${exclude}
259    CMAKE_ARGS ${${nameCanon}_CMAKE_ARGS}
260               ${compiler_args}
261               -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
262               ${sysroot_arg}
263               -DLLVM_BINARY_DIR=${PROJECT_BINARY_DIR}
264               -DLLVM_CONFIG_PATH=${llvm_config_path}
265               -DLLVM_ENABLE_WERROR=${LLVM_ENABLE_WERROR}
266               -DLLVM_HOST_TRIPLE=${LLVM_HOST_TRIPLE}
267               -DLLVM_HAVE_LINK_VERSION_SCRIPT=${LLVM_HAVE_LINK_VERSION_SCRIPT}
268               -DLLVM_USE_RELATIVE_PATHS_IN_DEBUG_INFO=${LLVM_USE_RELATIVE_PATHS_IN_DEBUG_INFO}
269               -DLLVM_USE_RELATIVE_PATHS_IN_FILES=${LLVM_USE_RELATIVE_PATHS_IN_FILES}
270               -DLLVM_LIT_ARGS=${LLVM_LIT_ARGS}
271               -DLLVM_SOURCE_PREFIX=${LLVM_SOURCE_PREFIX}
272               -DPACKAGE_VERSION=${PACKAGE_VERSION}
273               -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
274               -DCMAKE_MAKE_PROGRAM=${CMAKE_MAKE_PROGRAM}
275               -DCMAKE_EXPORT_COMPILE_COMMANDS=1
276               ${cmake_args}
277               ${PASSTHROUGH_VARIABLES}
278    INSTALL_COMMAND ""
279    STEP_TARGETS configure build
280    BUILD_ALWAYS 1
281    USES_TERMINAL_CONFIGURE 1
282    USES_TERMINAL_BUILD 1
283    USES_TERMINAL_INSTALL 1
284    LIST_SEPARATOR |
285    )
286
287  if(ARG_USE_TOOLCHAIN)
288    set(force_deps DEPENDS ${TOOLCHAIN_BINS})
289  endif()
290
291  llvm_ExternalProject_BuildCmd(run_clean clean ${BINARY_DIR})
292  ExternalProject_Add_Step(${name} clean
293    COMMAND ${run_clean}
294    COMMENT "Cleaning ${name}..."
295    DEPENDEES configure
296    ${force_deps}
297    WORKING_DIRECTORY ${BINARY_DIR}
298    EXCLUDE_FROM_MAIN 1
299    USES_TERMINAL 1
300    )
301  ExternalProject_Add_StepTargets(${name} clean)
302
303  if(ARG_USE_TOOLCHAIN)
304    add_dependencies(${name}-clean ${name}-clobber)
305    set_target_properties(${name}-clean PROPERTIES
306      SOURCES ${CMAKE_CURRENT_BINARY_DIR}/${name}-clobber-stamp)
307  endif()
308
309  if(NOT ARG_NO_INSTALL)
310    install(CODE "execute_process\(COMMAND \${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=\${CMAKE_INSTALL_PREFIX} -DCMAKE_INSTALL_DO_STRIP=\${CMAKE_INSTALL_DO_STRIP} -P ${BINARY_DIR}/cmake_install.cmake\)"
311      COMPONENT ${name})
312
313    add_llvm_install_targets(install-${name}
314                             DEPENDS ${name}
315                             COMPONENT ${name})
316  endif()
317
318  # Add top-level targets
319  foreach(target ${ARG_EXTRA_TARGETS})
320    if(DEFINED ${target})
321      set(external_target "${${target}}")
322    else()
323      set(external_target "${target}")
324    endif()
325    llvm_ExternalProject_BuildCmd(build_runtime_cmd ${external_target} ${BINARY_DIR})
326    add_custom_target(${target}
327      COMMAND ${build_runtime_cmd}
328      DEPENDS ${name}-configure
329      WORKING_DIRECTORY ${BINARY_DIR}
330      VERBATIM
331      USES_TERMINAL)
332  endforeach()
333endfunction()
334