1
2# Create sphinx target
3if (LLVM_ENABLE_SPHINX)
4  message(STATUS "Sphinx enabled.")
5  find_package(Sphinx REQUIRED)
6  if (LLVM_BUILD_DOCS AND NOT TARGET sphinx)
7    add_custom_target(sphinx ALL)
8  endif()
9else()
10  message(STATUS "Sphinx disabled.")
11endif()
12
13
14# Handy function for creating the different Sphinx targets.
15#
16# ``builder`` should be one of the supported builders used by
17# the sphinx-build command.
18#
19# ``project`` should be the project name
20function (add_sphinx_target builder project)
21  cmake_parse_arguments(ARG "" "SOURCE_DIR" "" ${ARGN})
22  set(SPHINX_BUILD_DIR "${CMAKE_CURRENT_BINARY_DIR}/${builder}")
23  set(SPHINX_DOC_TREE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees-${project}-${builder}")
24  set(SPHINX_TARGET_NAME docs-${project}-${builder})
25
26  if (SPHINX_WARNINGS_AS_ERRORS)
27    set(SPHINX_WARNINGS_AS_ERRORS_FLAG "-W")
28  else()
29    set(SPHINX_WARNINGS_AS_ERRORS_FLAG "")
30  endif()
31
32  if (NOT ARG_SOURCE_DIR)
33    set(ARG_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}")
34  endif()
35
36  add_custom_target(${SPHINX_TARGET_NAME}
37                    COMMAND ${SPHINX_EXECUTABLE}
38                            -b ${builder}
39                            -d "${SPHINX_DOC_TREE_DIR}"
40                            -q # Quiet: no output other than errors and warnings.
41                            ${SPHINX_WARNINGS_AS_ERRORS_FLAG} # Treat warnings as errors if requested
42                            "${ARG_SOURCE_DIR}" # Source
43                            "${SPHINX_BUILD_DIR}" # Output
44                    COMMENT
45                    "Generating ${builder} Sphinx documentation for ${project} into \"${SPHINX_BUILD_DIR}\"")
46
47  # When "clean" target is run, remove the Sphinx build directory
48  set_property(DIRECTORY APPEND PROPERTY
49               ADDITIONAL_MAKE_CLEAN_FILES
50               "${SPHINX_BUILD_DIR}")
51
52  # We need to remove ${SPHINX_DOC_TREE_DIR} when make clean is run
53  # but we should only add this path once
54  get_property(_CURRENT_MAKE_CLEAN_FILES
55               DIRECTORY PROPERTY ADDITIONAL_MAKE_CLEAN_FILES)
56  list(FIND _CURRENT_MAKE_CLEAN_FILES "${SPHINX_DOC_TREE_DIR}" _INDEX)
57  if (_INDEX EQUAL -1)
58    set_property(DIRECTORY APPEND PROPERTY
59                 ADDITIONAL_MAKE_CLEAN_FILES
60                 "${SPHINX_DOC_TREE_DIR}")
61  endif()
62
63  if (LLVM_BUILD_DOCS)
64    add_dependencies(sphinx ${SPHINX_TARGET_NAME})
65
66    # Handle installation
67    if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
68      if (builder STREQUAL man)
69        if (CMAKE_INSTALL_MANDIR)
70          set(INSTALL_MANDIR ${CMAKE_INSTALL_MANDIR}/)
71        else()
72          set(INSTALL_MANDIR share/man/)
73        endif()
74        # FIXME: We might not ship all the tools that these man pages describe
75        install(DIRECTORY "${SPHINX_BUILD_DIR}/" # Slash indicates contents of
76                COMPONENT "${project}-sphinx-man"
77                DESTINATION ${INSTALL_MANDIR}man1)
78
79        if(NOT LLVM_ENABLE_IDE)
80          add_llvm_install_targets("install-${SPHINX_TARGET_NAME}"
81                                   DEPENDS ${SPHINX_TARGET_NAME}
82                                   COMPONENT "${project}-sphinx-man")
83        endif()
84      elseif (builder STREQUAL html)
85        string(TOUPPER "${project}" project_upper)
86        set(${project_upper}_INSTALL_SPHINX_HTML_DIR "share/doc/${project}/html"
87            CACHE STRING "HTML documentation install directory for ${project}")
88
89        # '/.' indicates: copy the contents of the directory directly into
90        # the specified destination, without recreating the last component
91        # of ${SPHINX_BUILD_DIR} implicitly.
92        install(DIRECTORY "${SPHINX_BUILD_DIR}/."
93                COMPONENT "${project}-sphinx-html"
94                DESTINATION "${${project_upper}_INSTALL_SPHINX_HTML_DIR}")
95
96        if(NOT LLVM_ENABLE_IDE)
97          add_llvm_install_targets("install-${SPHINX_TARGET_NAME}"
98                                   DEPENDS ${SPHINX_TARGET_NAME}
99                                   COMPONENT "${project}-sphinx-html")
100        endif()
101      else()
102        message(WARNING Installation of ${builder} not supported)
103      endif()
104    endif()
105  endif()
106endfunction()
107