1include(GNUInstallDirs)
2
3# Create sphinx target
4if (LLVM_ENABLE_SPHINX)
5  message(STATUS "Sphinx enabled.")
6  find_package(Sphinx REQUIRED)
7  if (LLVM_BUILD_DOCS AND NOT TARGET sphinx)
8    add_custom_target(sphinx ALL)
9  endif()
10else()
11  message(STATUS "Sphinx disabled.")
12endif()
13
14
15# Handy function for creating the different Sphinx targets.
16#
17# ``builder`` should be one of the supported builders used by
18# the sphinx-build command.
19#
20# ``project`` should be the project name
21#
22# Named arguments:
23# ``ENV_VARS`` should be a list of environment variables that should be set when
24#              running Sphinx. Each environment variable should be a string with
25#              the form KEY=VALUE.
26function (add_sphinx_target builder project)
27  cmake_parse_arguments(ARG "" "SOURCE_DIR" "ENV_VARS" ${ARGN})
28  set(SPHINX_BUILD_DIR "${CMAKE_CURRENT_BINARY_DIR}/${builder}")
29  set(SPHINX_DOC_TREE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees-${project}-${builder}")
30  set(SPHINX_TARGET_NAME docs-${project}-${builder})
31
32  if (SPHINX_WARNINGS_AS_ERRORS)
33    set(SPHINX_WARNINGS_AS_ERRORS_FLAG "-W")
34  else()
35    set(SPHINX_WARNINGS_AS_ERRORS_FLAG "")
36  endif()
37
38  if (NOT ARG_SOURCE_DIR)
39    set(ARG_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}")
40  endif()
41
42  add_custom_target(${SPHINX_TARGET_NAME}
43                    COMMAND ${CMAKE_COMMAND} -E env ${ARG_ENV_VARS}
44                            ${SPHINX_EXECUTABLE}
45                            -b ${builder}
46                            -d "${SPHINX_DOC_TREE_DIR}"
47                            -q # Quiet: no output other than errors and warnings.
48                            -t builder-${builder} # tag for builder
49                            ${SPHINX_WARNINGS_AS_ERRORS_FLAG} # Treat warnings as errors if requested
50                            "${ARG_SOURCE_DIR}" # Source
51                            "${SPHINX_BUILD_DIR}" # Output
52                    COMMENT
53                    "Generating ${builder} Sphinx documentation for ${project} into \"${SPHINX_BUILD_DIR}\"")
54
55  # When "clean" target is run, remove the Sphinx build directory
56  set_property(DIRECTORY APPEND PROPERTY
57               ADDITIONAL_MAKE_CLEAN_FILES
58               "${SPHINX_BUILD_DIR}")
59
60  # We need to remove ${SPHINX_DOC_TREE_DIR} when make clean is run
61  # but we should only add this path once
62  get_property(_CURRENT_MAKE_CLEAN_FILES
63               DIRECTORY PROPERTY ADDITIONAL_MAKE_CLEAN_FILES)
64  list(FIND _CURRENT_MAKE_CLEAN_FILES "${SPHINX_DOC_TREE_DIR}" _INDEX)
65  if (_INDEX EQUAL -1)
66    set_property(DIRECTORY APPEND PROPERTY
67                 ADDITIONAL_MAKE_CLEAN_FILES
68                 "${SPHINX_DOC_TREE_DIR}")
69  endif()
70
71  if (LLVM_BUILD_DOCS)
72    add_dependencies(sphinx ${SPHINX_TARGET_NAME})
73
74    # Handle installation
75    if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
76      if (builder STREQUAL man)
77        # FIXME: We might not ship all the tools that these man pages describe
78        install(DIRECTORY "${SPHINX_BUILD_DIR}/" # Slash indicates contents of
79                COMPONENT "${project}-sphinx-man"
80                DESTINATION "${CMAKE_INSTALL_MANDIR}/man1")
81
82        if(NOT LLVM_ENABLE_IDE)
83          add_llvm_install_targets("install-${SPHINX_TARGET_NAME}"
84                                   DEPENDS ${SPHINX_TARGET_NAME}
85                                   COMPONENT "${project}-sphinx-man")
86        endif()
87      elseif (builder STREQUAL html)
88        string(TOUPPER "${project}" project_upper)
89        set(${project_upper}_INSTALL_SPHINX_HTML_DIR "${CMAKE_INSTALL_DOCDIR}/${project}/html"
90            CACHE STRING "HTML documentation install directory for ${project}")
91
92        # '/.' indicates: copy the contents of the directory directly into
93        # the specified destination, without recreating the last component
94        # of ${SPHINX_BUILD_DIR} implicitly.
95        install(DIRECTORY "${SPHINX_BUILD_DIR}/."
96                COMPONENT "${project}-sphinx-html"
97                DESTINATION "${${project_upper}_INSTALL_SPHINX_HTML_DIR}")
98
99        if(NOT LLVM_ENABLE_IDE)
100          add_llvm_install_targets("install-${SPHINX_TARGET_NAME}"
101                                   DEPENDS ${SPHINX_TARGET_NAME}
102                                   COMPONENT "${project}-sphinx-html")
103        endif()
104      else()
105        message(WARNING Installation of ${builder} not supported)
106      endif()
107    endif()
108  endif()
109endfunction()
110