1add_custom_command(
2  OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
3  OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/lldb.py
4  DEPENDS ${SWIG_SOURCES}
5  DEPENDS ${SWIG_INTERFACES}
6  DEPENDS ${SWIG_HEADERS}
7  COMMAND ${SWIG_EXECUTABLE}
8      ${SWIG_COMMON_FLAGS}
9      -I${CMAKE_CURRENT_SOURCE_DIR}
10      -c++
11      -shadow
12      -python
13      -py3
14      -threads
15      -outdir ${CMAKE_CURRENT_BINARY_DIR}
16      -o ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
17      ${CMAKE_CURRENT_SOURCE_DIR}/python.swig
18  VERBATIM
19  COMMENT "Building LLDB Python wrapper")
20
21add_custom_target(swig_wrapper_python ALL DEPENDS
22  ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
23  ${CMAKE_CURRENT_BINARY_DIR}/lldb.py
24)
25
26if (NOT WIN32)
27add_custom_command(
28  OUTPUT  ${LLVM_RUNTIME_OUTPUT_INTDIR}/lldb-python
29  VERBATIM
30  COMMAND ${CMAKE_COMMAND} -E copy lldb-python ${LLVM_RUNTIME_OUTPUT_INTDIR}/lldb-python
31  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
32)
33add_custom_target(lldb-python-wrapper ALL DEPENDS
34  ${LLVM_RUNTIME_OUTPUT_INTDIR}/lldb-python
35)
36endif()
37
38function(create_python_package swig_target working_dir pkg_dir)
39  cmake_parse_arguments(ARG "NOINIT" "" "FILES" ${ARGN})
40  if(ARG_FILES)
41    set(copy_cmd COMMAND ${CMAKE_COMMAND} -E copy ${ARG_FILES} ${pkg_dir})
42  endif()
43  if(NOT ARG_NOINIT)
44    set(init_cmd COMMAND ${Python3_EXECUTABLE}
45        "${LLDB_SOURCE_DIR}/bindings/python/createPythonInit.py"
46        "${pkg_dir}" ${ARG_FILES})
47  endif()
48  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
49    COMMAND ${CMAKE_COMMAND} -E make_directory ${pkg_dir}
50    ${copy_cmd}
51    ${init_cmd}
52    WORKING_DIRECTORY ${working_dir})
53endfunction()
54
55function(create_relative_symlink swig_target dest_file output_dir output_name)
56  get_filename_component(dest_file ${dest_file} ABSOLUTE)
57  get_filename_component(output_dir ${output_dir} ABSOLUTE)
58  file(RELATIVE_PATH rel_dest_file ${output_dir} ${dest_file})
59  if(CMAKE_HOST_UNIX)
60    set(LLVM_LINK_OR_COPY create_symlink)
61  else()
62    set(LLVM_LINK_OR_COPY copy)
63  endif()
64  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
65    COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} ${rel_dest_file} ${output_name}
66    WORKING_DIRECTORY ${output_dir})
67endfunction()
68
69function(finish_swig_python swig_target lldb_python_bindings_dir lldb_python_target_dir)
70  # Add a Post-Build Event to copy over Python files and create the symlink to
71  # liblldb.so for the Python API(hardlink on Windows).
72  add_custom_target(${swig_target} ALL VERBATIM
73    COMMAND ${CMAKE_COMMAND} -E make_directory ${lldb_python_target_dir}
74    DEPENDS ${lldb_python_bindings_dir}/lldb.py
75    COMMENT "Python script sym-linking LLDB Python API")
76
77  if(NOT LLDB_USE_SYSTEM_SIX)
78    add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
79      COMMAND ${CMAKE_COMMAND} -E copy
80        "${LLDB_SOURCE_DIR}/third_party/Python/module/six/six.py"
81        "${lldb_python_target_dir}/../six.py")
82  endif()
83
84  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
85    COMMAND ${CMAKE_COMMAND} -E copy
86      "${lldb_python_bindings_dir}/lldb.py"
87      "${lldb_python_target_dir}/__init__.py")
88
89  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
90    COMMAND ${CMAKE_COMMAND} -E copy
91      "${LLDB_SOURCE_DIR}/source/Interpreter/embedded_interpreter.py"
92      "${lldb_python_target_dir}")
93
94  # Distribute the examples as python packages.
95  create_python_package(
96    ${swig_target}
97    ${lldb_python_target_dir}
98    "formatters/cpp"
99    FILES "${LLDB_SOURCE_DIR}/examples/synthetic/gnu_libstdcpp.py"
100          "${LLDB_SOURCE_DIR}/examples/synthetic/libcxx.py")
101
102  create_python_package(
103    ${swig_target}
104    ${lldb_python_target_dir}
105    "formatters"
106    FILES "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/cache.py"
107          "${LLDB_SOURCE_DIR}/examples/summaries/synth.py"
108          "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/metrics.py"
109          "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/attrib_fromdict.py"
110          "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/Logger.py")
111
112  create_python_package(
113    ${swig_target}
114    ${lldb_python_target_dir}
115    "utils"
116    FILES "${LLDB_SOURCE_DIR}/examples/python/in_call_stack.py"
117          "${LLDB_SOURCE_DIR}/examples/python/symbolication.py")
118
119  create_python_package(
120    ${swig_target}
121    ${lldb_python_target_dir}
122    "plugins"
123    FILES
124    "${LLDB_SOURCE_DIR}/examples/python/scripted_process/scripted_process.py")
125
126  if(APPLE)
127    create_python_package(
128      ${swig_target}
129      ${lldb_python_target_dir} "macosx"
130      FILES "${LLDB_SOURCE_DIR}/examples/python/crashlog.py"
131            "${LLDB_SOURCE_DIR}/examples/darwin/heap_find/heap.py")
132
133    create_python_package(
134      ${swig_target}
135      ${lldb_python_target_dir} "macosx/heap"
136      FILES "${LLDB_SOURCE_DIR}/examples/darwin/heap_find/heap/heap_find.cpp"
137            "${LLDB_SOURCE_DIR}/examples/darwin/heap_find/heap/Makefile"
138            NOINIT)
139
140    create_python_package(
141      ${swig_target}
142      ${lldb_python_target_dir} "diagnose"
143      FILES "${LLDB_SOURCE_DIR}/examples/python/diagnose_unwind.py"
144            "${LLDB_SOURCE_DIR}/examples/python/diagnose_nsstring.py")
145  endif()
146
147  if(LLDB_BUILD_FRAMEWORK)
148    set(LIBLLDB_SYMLINK_DEST "${LLDB_FRAMEWORK_ABSOLUTE_BUILD_DIR}/LLDB.framework/LLDB")
149  else()
150    set(LIBLLDB_SYMLINK_DEST "${LLVM_SHLIB_OUTPUT_INTDIR}/liblldb${CMAKE_SHARED_LIBRARY_SUFFIX}")
151  endif()
152  if(WIN32)
153    if(CMAKE_BUILD_TYPE STREQUAL Debug)
154      set(LIBLLDB_SYMLINK_OUTPUT_FILE "_lldb_d.pyd")
155    else()
156      set(LIBLLDB_SYMLINK_OUTPUT_FILE "_lldb.pyd")
157    endif()
158  else()
159    set(LIBLLDB_SYMLINK_OUTPUT_FILE "_lldb.so")
160  endif()
161  create_relative_symlink(${swig_target} ${LIBLLDB_SYMLINK_DEST}
162                          ${lldb_python_target_dir} ${LIBLLDB_SYMLINK_OUTPUT_FILE})
163
164
165  if (NOT WIN32)
166  add_dependencies(${swig_target} lldb-python-wrapper)
167  endif()
168
169  if(NOT LLDB_BUILD_FRAMEWORK)
170    set(LLDB_ARGDUMPER_FILENAME "lldb-argdumper${CMAKE_EXECUTABLE_SUFFIX}")
171    create_relative_symlink(${swig_target} "${LLVM_RUNTIME_OUTPUT_INTDIR}/${LLDB_ARGDUMPER_FILENAME}"
172                            ${lldb_python_target_dir} ${LLDB_ARGDUMPER_FILENAME})
173  endif()
174
175  add_dependencies(${swig_target} swig_wrapper_python liblldb lldb-argdumper)
176  set_target_properties(${swig_target} swig_wrapper_python PROPERTIES FOLDER "lldb misc")
177
178  # Ensure we do the python post-build step when building lldb.
179  add_dependencies(lldb ${swig_target})
180
181  # Install the LLDB python module
182  if(LLDB_BUILD_FRAMEWORK)
183    set(LLDB_PYTHON_INSTALL_PATH ${LLDB_FRAMEWORK_INSTALL_DIR}/LLDB.framework/Resources/Python)
184  else()
185    set(LLDB_PYTHON_INSTALL_PATH ${LLDB_PYTHON_RELATIVE_PATH})
186  endif()
187  if (NOT CMAKE_CFG_INTDIR STREQUAL  ".")
188    string(REPLACE ${CMAKE_CFG_INTDIR} "\$\{CMAKE_INSTALL_CONFIG_NAME\}" LLDB_PYTHON_INSTALL_PATH ${LLDB_PYTHON_INSTALL_PATH})
189    string(REPLACE ${CMAKE_CFG_INTDIR} "\$\{CMAKE_INSTALL_CONFIG_NAME\}" lldb_python_target_dir ${lldb_python_target_dir})
190  endif()
191  set(python_scripts_target "${swig_target}-scripts")
192  set(python_scripts_install_target "install-${python_scripts_target}")
193  add_custom_target(${python_scripts_target})
194  add_dependencies(${python_scripts_target} ${swig_target})
195  install(DIRECTORY ${lldb_python_target_dir}/../
196          DESTINATION ${LLDB_PYTHON_INSTALL_PATH}
197          COMPONENT ${python_scripts_target})
198  if (NOT LLVM_ENABLE_IDE)
199    add_llvm_install_targets(${python_scripts_install_target}
200                             COMPONENT ${python_scripts_target}
201                             DEPENDS ${python_scripts_target})
202  endif()
203
204  # Add a Post-Build Event to copy the custom Python DLL to the lldb binaries dir so that Windows can find it when launching
205  # lldb.exe or any other executables that were linked with liblldb.
206  if (WIN32 AND NOT "${PYTHON_DLL}" STREQUAL "")
207    # When using the Visual Studio CMake generator the lldb binaries end up in Release/bin, Debug/bin etc.
208    file(TO_NATIVE_PATH "${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin" LLDB_BIN_DIR)
209    file(TO_NATIVE_PATH "${PYTHON_DLL}" PYTHON_DLL_NATIVE_PATH)
210    add_custom_command(
211      TARGET ${swig_target}
212      POST_BUILD
213      COMMAND ${CMAKE_COMMAND} -E copy ${PYTHON_DLL_NATIVE_PATH} ${LLDB_BIN_DIR} VERBATIM
214      COMMENT "Copying Python DLL to LLDB binaries directory.")
215  endif()
216endfunction()
217